Heiß diskutierte Inhalte

Im Wonnemonat Mai dreht sich im IT-Administrator Magazin alles rund um den Schwerpunkt “Systemmanagement”. So lesen Sie in der Ausgabe, wie Sie Ihre IT-Umgebung mit dem Microsoft System Center Operations Manager 2012 sowie mit der Open Source-Software Pandora FMS im Auge behalten. Außerdem zeigt Ihnen die Redaktion die besten Tricks für das Active Directory. In den Produkttest müssen unter anderem Aruba Networks ClearPass und Brainware ... mehr

Erreichbare Netzwerkcomputer auf Desktop anzeigen

Hallo Leute,

ich habe hier ein Netzwerk mit einem "Server", der gleichzeitig als Desktopstation genutzt wird und 5 Clients, welche entweder per LAN oder WLAN an das Netzwerk angeschlossen sind.
Jeder Rechner hat eine Fest zugewiesene IP im Netzwerk.

Um jetzt die Arbeit zu erleichtern hätte ich gerne auf dem "Server" eine Übersicht (z.B. rote und grüne Punkte) welche IPs (192.168.178.11 + 192.168.178.12 + 192.168.178.13 + 192.168.178.14 + 192.168.178.15) im Netzwerk erreichbar sind.

Ich hatte überlegt es mit einer Homepage zu machen, die auf dem Server liegt und sich alle 15 Min aktualisiert und halt immer die IPs irgendwie anpingt, ich habe nur noch keine genaue Idee, wie ich es verwirklichen soll.

Hat jemand eine Lösung? Gerne auch eine andere als mit der Homepage!

Vielen Dank!

MfG Rocky

6 Kommentare Diskussionsverlauf

dieseyer schreibt am 18.11.2009 um 21:06:52 Uhr
palmiii schreibt am 18.11.2009 um 21:38:18 Uhr
Pimpermann schreibt am 19.11.2009 um 07:28:31 Uhr
- Janno100 schreibt am 19.11.2009 um 23:11:21 Uhr
dog schreibt am 20.11.2009 um 00:57:53 Uhr
Rocky112 schreibt am 20.11.2009 um 19:19:35 Uhr

Top

dieseyer am 18.11.2009 um 21:06 Uhr

Hab' ich schon immer mal gebraucht . . .und jetzt gemacht:

http://dieseyer.de/scr/pclistetesten.hta

Im gleichen Verzeichnis, in dem das pclistetesten.hta liegt, wird eine pclistetesten.ini gesucht, mit je einer IP-Adr. je Zeile.

</html>
<head>

<!--

'*** v9.B *** www.dieseyer.de ******************************
'
' Datei:  pclistetesten.hta
' Autor:  dieseyer@gmx.de
' Auf:    www.dieseyer.de
'
'***********************************************************

	SHOWINTASKBAR="no"
	WINDOWSTATE="maximize"
	BORDER="none"
	INNERBORDER="no"
	SCROLL="No"
	NAVIGABLE="no"
	ICON="dieseyer.ico"

-->
  <HTA:APPLICATION ID="oHTA"
	APPLICATIONNAME="PC Liste testen"
	SINGLEINSTANCE="yes"
	MAXIMIZEBUTTON="no"
  >

  <title>PC Liste testen</title>

<style type="text/css">

html, body {	background-color: #116;	color: #ec0;	font-weight: normal;	font-size: 9pt; font-family: verdana, arial, sans-serif }

</style>

</head>


<script language="VBscript">

  Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl
  
  Dim arrTst, arrZeilen(), Titel, HtaSelbst, HtaDatum
  Dim fso		: Set fso		= CreateObject("Scripting.FileSystemObject")
  Dim AktVerz		: AktVerz		= fso.GetParentFolderName( HtaSelbst )	' : MsgBox "AktVerz: " & AktVerz, , "046 :: "

'***********************************************************
Function BeimLaden() ' ruft einige Routinen auf
'***********************************************************
  On Error Resume Next
	window.moveto 0, 0
  On Error Goto 0
  Dim fso		: Set fso		= CreateObject("Scripting.FileSystemObject")
  Dim Tst

  Titel		= oHTA.APPLICATIONNAME

  HtaSelbst	= oHTA.CommandLine


' Auf Vorhandensein der Datei mit IP-Adr. in Array einlesen
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  Tst = AktVerz & "pclistetesten.ini"
  If not fso.FileExists( Tst ) Then
	MsgBox "Datei mit IP-Adr. fehlt:" & vbCRLF & vbCRLF & Tst, vbCritical, "066 :: " & Titel
  Exit Function
  End If
  
  
' Datei mit IP-Adr. in Array einlesen
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  arrTst = DateiInhalt( Tst )

  Tst = "075 :: UBound( arrTst ) = " & UBound( arrTst )
' MsgBox Tst, , "076 :: " ' Anzahl der Zeilen anzeigen


  ReDim Preserve arrZeilen( UBound( arrTst ) )
  Tst = "080 :: UBound( arrZeilen ) = " & UBound( arrZeilen )
' MsgBox Tst, , "081 :: " ' Anzahl der Zeilen anzeigen


' ArrayZeigen( arrTst )
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


' Array mit IP-Adr. schnell sortieren - ein 'Quicky'
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  QuickSort arrTst, LBound( arrTst ), UBound( arrTst )
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


' ArrayZeigen( arrTst )
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


  call pclistetesten( 0 )

  window.setInterval "ErgebnZeigen()", 333

End Function ' BeimLaden()

'***********************************************************
Sub ErgebnZeigen()
'***********************************************************
  Dim t, i

	t = t & "<table border=""1"" width=""100%"">"
	t = t & "  <colgroup>"
	t = t & "    <col width=""300*"">"
	t = t & "    <col >"
	t = t & "  </colgroup>"
  For i = LBound( arrTst ) to UBound( arrTst )
	t = t & "  <tr>"
	t = t & "    <td>" & arrZeilen( i ) & "</td>"
	t = t & "    <td>" & arrTst( i ) & "</td>"
	t = t & "  </tr>"
  Next
	t = t & "</table>"
	t = t & "<br>"
	t = t & "<center>"
	t = t & "  " & now() & " - " & Timer()
	t = t & "  <br>"
	t = t & "  <br>"
	t = t & "  Neu starten mit [F5]"
	t = t & "  <br>"
	t = t & "  <br>"
	t = t & "</center>"

  T = T &	"<center style="" font-size:7Pt; "">"
  T = T &	"<a href=""http://dieseyer.de/scr/pclistetesten.hta"" ><b>pclistetesten.hta</b></a>"
  T = T &	"<a href=""http://dieseyer.de/dse-impressum.html"" >&#160;&#8226;&#160;&copy;&#160;2009&#160;by&#160;dieseyer&#160;&#8226;&#160;all&#160;rights&#160;reserved&#160;&#8226;&#160;</a>"
  T = T &	"<a href=""http://dieseyer.de"" ><b><b>www.dieseyer.de</b></b></a>"
  T = T &	"</center>"

  On Error Resume Next
	document.all.Anzeige.innerHTML = t
  On Error Goto 0
End Sub ' ErgebnZeigen()

'***********************************************************
Sub pclistetesten( Nr )
'***********************************************************
' MsgBox "Nr.: '" & Nr & "'" & vbCRLF & arrTst( Nr )

  
  If WMIpingOK( arrTst( Nr ) ) Then
	arrZeilen( Nr ) = "<span style=""color:green"">OK " & Time() & "</span>"
  Else
	arrZeilen( Nr ) = "<span style=""color:red""><strike>OK</strike> " & Time() & "</span>"
  End If
  Nr = Nr + 1
  If Nr > UBound( arrTst ) Then Nr = LBound( arrTst )

  window.setTimeout "pclistetesten('" & Nr & "')", 1 * 1000

End Sub ' pclistetesten( Nr )

'*** v9.3 *** www.dieseyer.de ******************************
Function WMIpingOK( PCName )
'***********************************************************
' Aufruf z.B.: If not WMIpingOK( ZielPC ) Then MsgBox ZielPC & " ist nicht erreichbar." : WScript.Quit
  Dim Tst, objPing, objStatus
  On Error Resume Next
  err.Clear
  Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery("select * from Win32_PingStatus where address = '" & PCName & "'")
  Tst = err.Number & " - " & err.Description
  On Error Goto 0
  If Len( Tst ) > 4 Then : WMIpingOK = "Fehler: " & Tst : Exit Function

  WMIpingOK = True
  For Each objStatus in objPing
	If IsNull(objStatus.StatusCode) or objStatus.StatusCode<>0 Then
'	  WScript.Echo("PCName " & PCName & " is not reachable")
	  WMIpingOK = False
	End If
  Next
  Set objPing = Nothing
End Function ' WMIpingOK( PCName )

'*** v8.3 *** www.dieseyer.de *******************************
Function QuickSort( vntArray, intVon, intBis )
'************************************************************

' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
' http://www.heise.de/ct/ftp/listings.shtml
' Der gute, alte QuickSort-Algorithmus als Windows-Script. c't 5/2002
' Copyright Ralf Nebelo/c't

'	QuickSort arrTest, LBound(arrTest), UBound(arrTest)  ' Array "arrTest" wird sortiert
'	~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

  Dim i, j
  Dim vntTestWert, intMitte, vntTemp

	If intVon < intBis Then
	  intMitte = (intVon + intBis) \ 2
	  vntTestWert = vntArray(intMitte)
	  i = intVon
	  j = intBis

	  Do
		Do While UCase( vntArray(i) ) < Ucase( vntTestWert )
'		Do While        vntArray(i)   <        vntTestWert
		  i = i + 1
		Loop

		Do While UCase( vntArray(j) ) > Ucase( vntTestWert )
'		Do While        vntArray(j)   >        vntTestWert
		  j = j - 1
		Loop

                If i <= j Then
                  vntTemp = vntArray(j)
                  vntArray(j) = vntArray(i)
                  vntArray(i) = vntTemp
                  i = i + 1
                  j = j - 1
		End If
	  Loop Until i > j

	  If j <= intMitte Then
		Call QuickSort(vntArray, intVon, j)
		Call QuickSort(vntArray, i, intBis)
	  Else
		Call QuickSort(vntArray, i, intBis)
		Call QuickSort(vntArray, intVon, j)
	  End If
	End If

End Function ' QuickSort( vntArray, intVon, intBis )

'*** v7.C *** www.dieseyer.de ****************************
Function DateiInhalt( DateiX )
'*********************************************************
  Dim fso         	: Set fso       	= CreateObject("Scripting.FileSystemObject")
  Dim FileIn		: Set FileIn		= fso.OpenTextFile( DateiX, 1 )
  Dim i
	ReDim Preserve Zeile(i)

  Do While Not ( FileIn.atEndOfStream )
	ReDim Preserve Zeile(i)
	Zeile(i) = FileIn.Readline
	i = i + 1
  Loop

  If UBound( Zeile ) < 1 Then
	Zeile(i) = "Leerdatei"
  End If

  FileIn.Close
  Set FileIn  = nothing
  DateiInhalt = Zeile
End Function ' DateiInhalt( DateiX )

'*** v7.C *** www.dieseyer.de ****************************
Function ArrayZeigen( InArray )
'*********************************************************
' Durch die Prozedur
'    ArrayZeigen( InArray )
' werden von einem Array nur die ersten
' und letzten Elemente angezeigt. Da die MsgBox nur 1024
' Zeichen anzeigen kann, ist die Anzahl der angezeigten
' Elemente von der Länge der einzelnen Elemente abhängig.

  Dim TxtOben, TxtUnten, Tst, i, n, o, u
  Dim Kopf ' für Tests
  ' Kopf = "LBound( InArray )=" & LBound( InArray ) & "   UBound( InArray )=" & UBound( InArray ) & vbCRLF & vbCRLF & Kopf
  ' Kopf = "O=00000" & "   U=00000" & "   Len( TxtOben )=00000" & vbCRLF & Kopf

  For i = LBound( InArray ) to UBound( InArray )

    n = UBound( InArray ) - i
    Tst = Len( TxtOben ) + Len( TxtUnten ) + Len( InArray( i ) ) + Len( Kopf )
    If Tst < 1000 AND n >= i Then
'		TxtOben  = TxtOben  & "i = " & i & vbTab & "n = " & n & vbTab & Tst & vbTab & InArray( i ) & vbCRLF
		TxtOben  = TxtOben  &          i &                                    vbTab & InArray( i ) & vbCRLF
		o = i
    End If

    n = UBound( InArray ) - i
    Tst = Len( TxtOben ) + Len( TxtUnten ) + Len( InArray( n ) )
    Tst = Len( TxtOben ) + Len( TxtUnten ) + Len( InArray( i ) ) + Len( Kopf )
    If Tst < 1000 AND n > i Then
'		TxtUnten  = "n = " & n & vbTab & "i = " & i & vbTab & Tst & vbTab & InArray( n ) & vbCRLF & TxtUnten
		TxtUnten  =          n                                    & vbTab & InArray( n ) & vbCRLF & TxtUnten
		u = n
    End If
    If n <=i then Exit For

  Next

  Tst = ""
  If o <> u AND o + 1 <> u Then Tst = "." & vbCRLF & "." & vbCRLF

  Kopf = Replace( Kopf, "O=00000", "O=" & o )
  Kopf = Replace( Kopf, "U=00000", "U=" & u )
  Kopf = Replace( Kopf, ")=00000", ")=" & Len( Kopf & TxtOben & Tst & TxtUnten ) )

  TxtOben = Kopf & TxtOben & Tst & TxtUnten

' LogEintrag "303 :: " & vbCRLF & TxtOben
  MsgBox TxtOben , , "304 :: " & Titel

End Function ' ArrayZeigen( InArray )

'**************************************************************
Sub document_onKeyDown
'************************************************************** 
' TastTaste = window.event.keyCode
' Trace32Log "312 :: Betätigte Taste: '" & TastTaste & "'", 1
' If TastTaste = 13 Then Call neuesEnde()
End Sub


</script>

<body onLoad="BeimLaden()">

<span id="Anzeige"></span><br>
<!--
<span id="InfoTxt" style="text-align: center; width: 642px; height: 3em; position: absolute; top: 478px; left: 11px; border: 2px solid red; background-color: #00d;"></span>
-->

</body>
</html>
01.
</html> 
02.
<head> 
03.
 
04.
<!-- 
05.
 
06.
'*** v9.B *** www.dieseyer.de ****************************** 
07.
' 
08.
' Datei:  pclistetesten.hta 
09.
' Autor:  dieseyer@gmx.de 
10.
' Auf:    www.dieseyer.de 
11.
' 
12.
'*********************************************************** 
13.
 
14.
	SHOWINTASKBAR="no" 
15.
	WINDOWSTATE="maximize" 
16.
	BORDER="none" 
17.
	INNERBORDER="no" 
18.
	SCROLL="No" 
19.
	NAVIGABLE="no" 
20.
	ICON="dieseyer.ico" 
21.
 
22.
--> 
23.
  <HTA:APPLICATION ID="oHTA" 
24.
	APPLICATIONNAME="PC Liste testen" 
25.
	SINGLEINSTANCE="yes" 
26.
	MAXIMIZEBUTTON="no" 
27.
  > 
28.
 
29.
  <title>PC Liste testen</title> 
30.
 
31.
<style type="text/css"> 
32.
 
33.
html, body {	background-color: #116;	color: #ec0;	font-weight: normal;	font-size: 9pt; font-family: verdana, arial, sans-serif } 
34.
 
35.
</style> 
36.
 
37.
</head> 
38.
 
39.
 
40.
<script language="VBscript"> 
41.
 
42.
  Option Explicit ' Siehe http://dieseyer.de/dse-wsh-lernen.html#OptionExpl 
43.
   
44.
  Dim arrTst, arrZeilen(), Titel, HtaSelbst, HtaDatum 
45.
  Dim fso		: Set fso		= CreateObject("Scripting.FileSystemObject") 
46.
  Dim AktVerz		: AktVerz		= fso.GetParentFolderName( HtaSelbst )	' : MsgBox "AktVerz: " & AktVerz, , "046 :: " 
47.
 
48.
'*********************************************************** 
49.
Function BeimLaden() ' ruft einige Routinen auf 
50.
'*********************************************************** 
51.
  On Error Resume Next 
52.
	window.moveto 0, 0 
53.
  On Error Goto 0 
54.
  Dim fso		: Set fso		= CreateObject("Scripting.FileSystemObject") 
55.
  Dim Tst 
56.
 
57.
  Titel		= oHTA.APPLICATIONNAME 
58.
 
59.
  HtaSelbst	= oHTA.CommandLine 
60.
 
61.
 
62.
' Auf Vorhandensein der Datei mit IP-Adr. in Array einlesen 
63.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
64.
  Tst = AktVerz & "pclistetesten.ini" 
65.
  If not fso.FileExists( Tst ) Then 
66.
	MsgBox "Datei mit IP-Adr. fehlt:" & vbCRLF & vbCRLF & Tst, vbCritical, "066 :: " & Titel 
67.
  Exit Function 
68.
  End If 
69.
   
70.
   
71.
' Datei mit IP-Adr. in Array einlesen 
72.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
73.
  arrTst = DateiInhalt( Tst ) 
74.
 
75.
  Tst = "075 :: UBound( arrTst ) = " & UBound( arrTst ) 
76.
' MsgBox Tst, , "076 :: " ' Anzahl der Zeilen anzeigen 
77.
 
78.
 
79.
  ReDim Preserve arrZeilen( UBound( arrTst ) ) 
80.
  Tst = "080 :: UBound( arrZeilen ) = " & UBound( arrZeilen ) 
81.
' MsgBox Tst, , "081 :: " ' Anzahl der Zeilen anzeigen 
82.
 
83.
 
84.
' ArrayZeigen( arrTst ) 
85.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
86.
 
87.
 
88.
' Array mit IP-Adr. schnell sortieren - ein 'Quicky' 
89.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
90.
  QuickSort arrTst, LBound( arrTst ), UBound( arrTst ) 
91.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
92.
 
93.
 
94.
' ArrayZeigen( arrTst ) 
95.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
96.
 
97.
 
98.
  call pclistetesten( 0 ) 
99.
 
100.
  window.setInterval "ErgebnZeigen()", 333 
101.
 
102.
End Function ' BeimLaden() 
103.
 
104.
'*********************************************************** 
105.
Sub ErgebnZeigen() 
106.
'*********************************************************** 
107.
  Dim t, i 
108.
 
109.
	t = t & "<table border=""1"" width=""100%"">" 
110.
	t = t & "  <colgroup>" 
111.
	t = t & "    <col width=""300*"">" 
112.
	t = t & "    <col >" 
113.
	t = t & "  </colgroup>" 
114.
  For i = LBound( arrTst ) to UBound( arrTst ) 
115.
	t = t & "  <tr>" 
116.
	t = t & "    <td>" & arrZeilen( i ) & "</td>" 
117.
	t = t & "    <td>" & arrTst( i ) & "</td>" 
118.
	t = t & "  </tr>" 
119.
  Next 
120.
	t = t & "</table>" 
121.
	t = t & "<br>" 
122.
	t = t & "<center>" 
123.
	t = t & "  " & now() & " - " & Timer() 
124.
	t = t & "  <br>" 
125.
	t = t & "  <br>" 
126.
	t = t & "  Neu starten mit [F5]" 
127.
	t = t & "  <br>" 
128.
	t = t & "  <br>" 
129.
	t = t & "</center>" 
130.
 
131.
  T = T &	"<center style="" font-size:7Pt; "">" 
132.
  T = T &	"<a href=""http://dieseyer.de/scr/pclistetesten.hta"" ><b>pclistetesten.hta</b></a>" 
133.
  T = T &	"<a href=""http://dieseyer.de/dse-impressum.html"" >&#160;&#8226;&#160;&copy;&#160;2009&#160;by&#160;dieseyer&#160;&#8226;&#160;all&#160;rights&#160;reserved&#160;&#8226;&#160;</a>" 
134.
  T = T &	"<a href=""http://dieseyer.de"" ><b><b>www.dieseyer.de</b></b></a>" 
135.
  T = T &	"</center>" 
136.
 
137.
  On Error Resume Next 
138.
	document.all.Anzeige.innerHTML = t 
139.
  On Error Goto 0 
140.
End Sub ' ErgebnZeigen() 
141.
 
142.
'*********************************************************** 
143.
Sub pclistetesten( Nr ) 
144.
'*********************************************************** 
145.
' MsgBox "Nr.: '" & Nr & "'" & vbCRLF & arrTst( Nr ) 
146.
 
147.
   
148.
  If WMIpingOK( arrTst( Nr ) ) Then 
149.
	arrZeilen( Nr ) = "<span style=""color:green"">OK " & Time() & "</span>" 
150.
  Else 
151.
	arrZeilen( Nr ) = "<span style=""color:red""><strike>OK</strike> " & Time() & "</span>" 
152.
  End If 
153.
  Nr = Nr + 1 
154.
  If Nr > UBound( arrTst ) Then Nr = LBound( arrTst ) 
155.
 
156.
  window.setTimeout "pclistetesten('" & Nr & "')", 1 * 1000 
157.
 
158.
End Sub ' pclistetesten( Nr ) 
159.
 
160.
'*** v9.3 *** www.dieseyer.de ****************************** 
161.
Function WMIpingOK( PCName ) 
162.
'*********************************************************** 
163.
' Aufruf z.B.: If not WMIpingOK( ZielPC ) Then MsgBox ZielPC & " ist nicht erreichbar." : WScript.Quit 
164.
  Dim Tst, objPing, objStatus 
165.
  On Error Resume Next 
166.
  err.Clear 
167.
  Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}").ExecQuery("select * from Win32_PingStatus where address = '" & PCName & "'") 
168.
  Tst = err.Number & " - " & err.Description 
169.
  On Error Goto 0 
170.
  If Len( Tst ) > 4 Then : WMIpingOK = "Fehler: " & Tst : Exit Function 
171.
 
172.
  WMIpingOK = True 
173.
  For Each objStatus in objPing 
174.
	If IsNull(objStatus.StatusCode) or objStatus.StatusCode<>0 Then 
175.
'	  WScript.Echo("PCName " & PCName & " is not reachable") 
176.
	  WMIpingOK = False 
177.
	End If 
178.
  Next 
179.
  Set objPing = Nothing 
180.
End Function ' WMIpingOK( PCName ) 
181.
 
182.
'*** v8.3 *** www.dieseyer.de ******************************* 
183.
Function QuickSort( vntArray, intVon, intBis ) 
184.
'************************************************************ 
185.
 
186.
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
187.
' http://www.heise.de/ct/ftp/listings.shtml 
188.
' Der gute, alte QuickSort-Algorithmus als Windows-Script. c't 5/2002 
189.
' Copyright Ralf Nebelo/c't 
190.
 
191.
'	QuickSort arrTest, LBound(arrTest), UBound(arrTest)  ' Array "arrTest" wird sortiert 
192.
'	~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
193.
 
194.
  Dim i, j 
195.
  Dim vntTestWert, intMitte, vntTemp 
196.
 
197.
	If intVon < intBis Then 
198.
	  intMitte = (intVon + intBis) \ 2 
199.
	  vntTestWert = vntArray(intMitte) 
200.
	  i = intVon 
201.
	  j = intBis 
202.
 
203.
	  Do 
204.
		Do While UCase( vntArray(i) ) < Ucase( vntTestWert ) 
205.
'		Do While        vntArray(i)   <        vntTestWert 
206.
		  i = i + 1 
207.
		Loop 
208.
 
209.
		Do While UCase( vntArray(j) ) > Ucase( vntTestWert ) 
210.
'		Do While        vntArray(j)   >        vntTestWert 
211.
		  j = j - 1 
212.
		Loop 
213.
 
214.
                If i <= j Then 
215.
                  vntTemp = vntArray(j) 
216.
                  vntArray(j) = vntArray(i) 
217.
                  vntArray(i) = vntTemp 
218.
                  i = i + 1 
219.
                  j = j - 1 
220.
		End If 
221.
	  Loop Until i > j 
222.
 
223.
	  If j <= intMitte Then 
224.
		Call QuickSort(vntArray, intVon, j) 
225.
		Call QuickSort(vntArray, i, intBis) 
226.
	  Else 
227.
		Call QuickSort(vntArray, i, intBis) 
228.
		Call QuickSort(vntArray, intVon, j) 
229.
	  End If 
230.
	End If 
231.
 
232.
End Function ' QuickSort( vntArray, intVon, intBis ) 
233.
 
234.
'*** v7.C *** www.dieseyer.de **************************** 
235.
Function DateiInhalt( DateiX ) 
236.
'********************************************************* 
237.
  Dim fso         	: Set fso       	= CreateObject("Scripting.FileSystemObject") 
238.
  Dim FileIn		: Set FileIn		= fso.OpenTextFile( DateiX, 1 ) 
239.
  Dim i 
240.
	ReDim Preserve Zeile(i) 
241.
 
242.
  Do While Not ( FileIn.atEndOfStream ) 
243.
	ReDim Preserve Zeile(i) 
244.
	Zeile(i) = FileIn.Readline 
245.
	i = i + 1 
246.
  Loop 
247.
 
248.
  If UBound( Zeile ) < 1 Then 
249.
	Zeile(i) = "Leerdatei" 
250.
  End If 
251.
 
252.
  FileIn.Close 
253.
  Set FileIn  = nothing 
254.
  DateiInhalt = Zeile 
255.
End Function ' DateiInhalt( DateiX ) 
256.
 
257.
'*** v7.C *** www.dieseyer.de **************************** 
258.
Function ArrayZeigen( InArray ) 
259.
'********************************************************* 
260.
' Durch die Prozedur 
261.
'    ArrayZeigen( InArray ) 
262.
' werden von einem Array nur die ersten 
263.
' und letzten Elemente angezeigt. Da die MsgBox nur 1024 
264.
' Zeichen anzeigen kann, ist die Anzahl der angezeigten 
265.
' Elemente von der Länge der einzelnen Elemente abhängig. 
266.
 
267.
  Dim TxtOben, TxtUnten, Tst, i, n, o, u 
268.
  Dim Kopf ' für Tests 
269.
  ' Kopf = "LBound( InArray )=" & LBound( InArray ) & "   UBound( InArray )=" & UBound( InArray ) & vbCRLF & vbCRLF & Kopf 
270.
  ' Kopf = "O=00000" & "   U=00000" & "   Len( TxtOben )=00000" & vbCRLF & Kopf 
271.
 
272.
  For i = LBound( InArray ) to UBound( InArray ) 
273.
 
274.
    n = UBound( InArray ) - i 
275.
    Tst = Len( TxtOben ) + Len( TxtUnten ) + Len( InArray( i ) ) + Len( Kopf ) 
276.
    If Tst < 1000 AND n >= i Then 
277.
'		TxtOben  = TxtOben  & "i = " & i & vbTab & "n = " & n & vbTab & Tst & vbTab & InArray( i ) & vbCRLF 
278.
		TxtOben  = TxtOben  &          i &                                    vbTab & InArray( i ) & vbCRLF 
279.
		o = i 
280.
    End If 
281.
 
282.
    n = UBound( InArray ) - i 
283.
    Tst = Len( TxtOben ) + Len( TxtUnten ) + Len( InArray( n ) ) 
284.
    Tst = Len( TxtOben ) + Len( TxtUnten ) + Len( InArray( i ) ) + Len( Kopf ) 
285.
    If Tst < 1000 AND n > i Then 
286.
'		TxtUnten  = "n = " & n & vbTab & "i = " & i & vbTab & Tst & vbTab & InArray( n ) & vbCRLF & TxtUnten 
287.
		TxtUnten  =          n                                    & vbTab & InArray( n ) & vbCRLF & TxtUnten 
288.
		u = n 
289.
    End If 
290.
    If n <=i then Exit For 
291.
 
292.
  Next 
293.
 
294.
  Tst = "" 
295.
  If o <> u AND o + 1 <> u Then Tst = "." & vbCRLF & "." & vbCRLF 
296.
 
297.
  Kopf = Replace( Kopf, "O=00000", "O=" & o ) 
298.
  Kopf = Replace( Kopf, "U=00000", "U=" & u ) 
299.
  Kopf = Replace( Kopf, ")=00000", ")=" & Len( Kopf & TxtOben & Tst & TxtUnten ) ) 
300.
 
301.
  TxtOben = Kopf & TxtOben & Tst & TxtUnten 
302.
 
303.
' LogEintrag "303 :: " & vbCRLF & TxtOben 
304.
  MsgBox TxtOben , , "304 :: " & Titel 
305.
 
306.
End Function ' ArrayZeigen( InArray ) 
307.
 
308.
'************************************************************** 
309.
Sub document_onKeyDown 
310.
'**************************************************************  
311.
' TastTaste = window.event.keyCode 
312.
' Trace32Log "312 :: Betätigte Taste: '" & TastTaste & "'", 1 
313.
' If TastTaste = 13 Then Call neuesEnde() 
314.
End Sub 
315.
 
316.
 
317.
</script> 
318.
 
319.
<body onLoad="BeimLaden()"> 
320.
 
321.
<span id="Anzeige"></span><br> 
322.
<!-- 
323.
<span id="InfoTxt" style="text-align: center; width: 642px; height: 3em; position: absolute; top: 478px; left: 11px; border: 2px solid red; background-color: #00d;"></span> 
324.
--> 
325.
 
326.
</body> 
327.
</html> 
328.
 

Top

palmiii am 18.11.2009 um 21:38 Uhr

Hallo Rocky,
schau mal nach Look@Lan eine simple einfache Software zeigt dir im Netz alle Ip Adressen an die On/ Offline sind.
Sprache engl. , ital. Kostenlos

Gruß

Palmiii

Top

Pimpermann am 19.11.2009 um 07:28 Uhr

Schau dir mal das Programm Freeping an

Top

Janno100 am 19.11.2009 um 23:11 Uhr

Ich verwende Hamachi. (LogInMe)

Du kannst hiermit sozusagen gleich noch einmal ein virtuelles Netzwerk im Netzwerk erzeugen und bestimmen was der Client auf dem einzelnen PC darf und was nicht.
Damit siehst du genau sofort, auch ausserhalb des Netzwerks, welcher PC gerade an ist. Vorraussetzung ist Internet. Das kleine Tool kann man auch auf den PCs nach der Installation aus dem Startmenü entfernen, hast sehr schnellen Zugriff auf jeden PC in diesem Netzwerk (eigene virtuelle IP, brauchst nicht mehr nach Passwörtern und Adressen rumsuchen). Kannst auch mehrere Netzwerke gleichzeitig betreuen, ohne das ein Netzwerk was mit dem anderen zu tun hat natürlich.
Bis zu 16 PC´s ist es kostenlos. Mit Lizens 256 Rechner (Preis ist lächerlich). Die Rechner kann man aber auch jederzeit einzeln stellen und später einbinden oder ausschliessen. Du kannst es so einstellen das es keine Möglichkeit gibt das hier Fremde das Netzwerk betreten können. Es ist nirgens gelistet und die Sicherheit kannst du sogar extrem hochschrauben. Es gibt eine Art Tanliste zum einloggen, verändern und so weiter.

Lediglich der Anbieter selber könnte durch eine Veränderung am Clienten etwas verändern. Die haben aber wiederum auch die Datenschutzbestimmungen, die sehr klar ausgedrückt sind bei sich auf der HP hinterlegt. Solange es sich nicht um ein Bankennetzwerk handelt denke ich mal kann man hier auch vertrauen. Die Verbindung ist ja getunnelt und verschlüsselt.

Ich kann mich noch erinnern das ich das mal vor 3 Jahren zum spielen nutzen wollte. Da war es noch Schrott. Jetzt nicht mehr. Habe 80 Systeme und einige Server drinnen ; XP, Vista, W7. Noch nie nen Fehler oder Problem gehabt. Portfreigaben an Router und Firewall entfallen komplett. So.., genug Werbung vor Begeisterung ;) . Die haben auf ihrer Seite einfach zu wenig dazu geschrieben finde ich. Die Installation auf den Clients sind nach der Einrichtung des Accounts auf deren Seite nur noch 2 Klicks bei Vista da alles automatisch geht. Kann man lustig via Link (auch zeitgültig) +eMail verteilen.

Gruß Janno

Bei Notebook´s auch gleich noch nen Effekt von Diebstahlschutz weil ein normaler Anwender das nicht so schnell checken wird wenn er damit ans Netz gehen würde.

Top

dog am 20.11.2009 um 00:57 Uhr

The Dude von Mikrotik - Kostenloses Monitoring Tool mit zusätzlichem Webinterface.

Grüße

Max

Top

Rocky112 am 20.11.2009 um 19:19 Uhr

Hallo Leute,

vielen Dank für Eure Antworten. Also das Lock@LAN habe ich schon getestet und muss es leider als "nicht funktionstüchtig" ablegen.

Ich habe nicht alle direkt am ROUTER angeschlossen, sondern evtl. über weitere Router oder dLAN Adapter. Dadurch versagt Look@LAN.

Die Anderen werde ich die kommenden Tage testen und euch dann meine Erfahren schreiben.

Vielen Dank nochmal.

MfG Rocky

mehr ...Ähnliche Inhalte

Apple

Entwicklung

Hardware

Internet

Linux

Microsoft

Multimedia

Netzwerke

Off Topic

Sicherheit

Sonstige Betriebssysteme

Virtualisierung

Weiterbildung

Erreichbare Netzwerkcomputer auf Desktop anzeigen

Hallo Leute,

ich habe hier ein Netzwerk mit einem "Server", der gleichzeitig als Desktopstation genutzt wird und 5 Clients, welche entweder per LAN oder WLAN an das Netzwerk angeschlossen sind.
Jeder Rechner hat eine Fest zugewiesene IP im Netzwerk.

ÜBER UNS

SERVICE

KONTAKT

Erreichbare Netzwerkcomputer auf Desktop anzeigen

Hallo Leute, ich habe hier ein Netzwerk mit einem "Server", der gleichzeitig als Desktopstation genutzt wird und 5 Clients, welche entweder per LAN oder WLAN an das Netzwerk angeschlossen sind. Jeder Rechner hat eine Fest zugewiesene IP im Netzwerk.

ÜBER UNS

SERVICE

KONTAKT

Hallo Leute,

ich habe hier ein Netzwerk mit einem "Server", der gleichzeitig als Desktopstation genutzt wird und 5 Clients, welche entweder per LAN oder WLAN an das Netzwerk angeschlossen sind.
Jeder Rechner hat eine Fest zugewiesene IP im Netzwerk.