Frage ist gelöst

Mit VBScript Zeilen mit bestimmten Werten aus TXT-Datei auslesen und in neuer TXT-Datei speichern

Suchbegriffe = Array(";0004", "; 0004") 'Alle Zeilen, welche zumindest einen dieser Begriffe enthalten, werden in die "Gefunden"-Datei geschrieben 

If WScript.Arguments.Count > 0 Then 'Falls ein Dateipfad beim Aufruf übergeben wurde, ... 

    Ein = WScript.Arguments(0) '... diesen in der Variablen "Ein" speichern. 

Else 'Wurde kein Pfad übergeben, eine Dateiauswahl anbieten (nur für XP) 

    Set Dialog = CreateObject("UserAccounts.CommonDialog")  

    Dialog.Filter = "Textdateien|*.txt|Alle Dateien|*.*" 

    Dialog.ShowOpen  

    Ein = Dialog.FileName  

End If 

Set fso = CreateObject("Scripting.FileSystemObject") 'Dateisystemobjekt (für das Arbeiten mit Dateien) erzeugen 

If Not fso.FileExists(Ein) Then 'Pfad überprüfen und ... 

    MsgBox "Keine gültige Datei gewählt!", vbCritical, "Dateifehler!" '... bei ungültigem Pfad Meldung ausgeben sowie ... 

    WScript.Quit '... Script beenden. 

End If 

'Pfad der Originaldatei zerlegen 

Dateipfad = fso.GetParentFolderName(Ein) 

If Right(Dateipfad, 1) <> "\" Then Dateipfad = Dateipfad & "\" 'sicher stellen, dass Pfad mit "\" endet 

Dateiname = fso.GetBaseName(Ein) 

Dateityp =  fso.GetExtensionName(Ein) 

Zeit = Now 'Zeitpunkt festhalten 

ZeitFormatiert = _ 

Year(Zeit) & _ 

Right("0" & Month(Zeit), 2) & _ 

Right("0" & Day(Zeit), 2) & _ 

"-" & _ 

Right("0" & Hour(Zeit), 2) & _ 

Right("0" & Minute(Zeit), 2) 

Gefunden = Dateipfad & Dateiname & "_G_" & ZeitFormatiert & "." & DateiTyp      'Dateiname der "Gefunden"-Datei 

NichtGefunden = Dateipfad & Dateiname & "_N_" & ZeitFormatiert & "." & DateiTyp 'Dateiname der "Nicht gefunden"-Datei 

Set G = fso.CreateTextFile(Gefunden, True)      '"Gefunden"-Datei erzeugen 

Set N = fso.CreateTextFile(NichtGefunden, True) '"Nicht gefunden"-Datei erzeugen 

T = Split(fso.OpenTextFile(Ein).ReadAll, vbCrLF) 'gesamten Inhalt der Originaldatei zeilenweise in ein Array einlesen 

U = Ubound(T) 'höchsten Index des Arrays ermitteln 

G.WriteLine T(0) 'erste Zeile in "Gefunden"-Datei schreiben 

N.WriteLine T(0) 'erste Zeile in "Nicht gefunden"-Datei schreiben 

For i = 1 To U 'ab Zeile 2 (= Index 1) alle Zeilen der Originaldatei durchgehen 

    Geschrieben = False 'Schalter, um festzuhalten, ob die Zeile bereits geschrieben wurde 

    For Each Begriff In Suchbegriffe 'alle angegebenen Suchbegriffe durchgehen 

        If InStr(1, T(i), Begriff, vbTextCompare) > 0 Then 'Wenn ein Suchbegriff in der Zeile gefunden wurde, ... 

            G.WriteLine T(i) '... diese in die "Gefunden"-Datei schreiben und ... 

            Geschrieben = True '... die Tatsache, dass die Zeile geschrieben wurde, festhalten sowie ... 

            Exit For '... die Überprüfung auf weitere Suchbegriffe unter- und dazu die Schleife verlassen. 

        End If 

    Next 

    If Not Geschrieben Then N.WriteLine T(i) ' Falls die Zeile noch nicht geschrieben wurde, dann in "Nicht gefunden"-Datei schreiben 

Next 

G.Close '"Gefunden"-Datei schließen 

N.Close '"Nicht gefunden"-Datei schließen 

MsgBox "Fertig."