Frage ist gelöst
Per Autostart unter XP - Zufallsdateien (jpg-Bilder aus verschiedenen Unterordnern) von Laufwerk C nach D kopieren

leertaste
Level 1 - Frischling
11.10.2007
15:46:45 Uhr
2114 Aufrufe
5 Antworten
ID: 70718

Noch nicht bewertet

Hallo Forumsleute face-smile

Hoff' mal das ich für diese Frage hier im richtigen Forumsbereich gelandet bin ;)

Ich suche ein Programm, natürlich möglichst Freeware :D das in den 'Autostart-Ordner' unter XP kommt...

...möchte per Zufall Dateien (jpg-Bilder aus verschiedenen Unterordnern) von Laufwerk C nach D kopieren. Wobei das Laufwerk D eine Ramdisk ist und ich die Dateien auf eine bestimmte Anzahl oder Megabytemenge begrenzen möchte.

Gibt es da ein Tool/Utility mit dem sich das bewerkstelligen lässt? Ich habe geGOOGLEd aber leider nichts brauchbares gefunden face-sad

FreundlichFragenderGruss
von der Leertaste face-smile

Diskussionsverlauf (5 Antworten)

bastla schreibt am 11.10.2007 um 20:51:25 Uhr
- leertaste schreibt am 11.10.2007 um 22:23:39 Uhr
  - bastla schreibt am 11.10.2007 um 23:02:52 Uhr
    - bastla schreibt am 11.10.2007 um 23:28:58 Uhr
      - leertaste schreibt am 12.10.2007 um 00:39:50 Uhr

Top

bastla schreibt am 11.10.2007 um 20:51:25 Uhr

Hallo leertaste!

Wenn es auch ein Batch sein dürfte, könntest Du es so versuchen:

@echo off & setlocal
set "Quelle=C:\Bilder"
set "Typ=*.jpg"
set "Ziel=D:"
set /a Grenze=5000000

set /a Bytes=0
set Done=
for /f %%i in ('dir "%Quelle%\%Typ%"^|findstr "Datei(en)"') do set /a Anzahl=%%i

:Loop
set /a Nr=%random%*%Anzahl%/32768+1
for /f "tokens=1* delims=:" %%i in ('dir /b "%Quelle%\%Typ%"^|findstr /n .^|findstr /b "%Nr%"') do call :ProcessFile "%Quelle%\%%j"
if not defined Done goto :Loop
goto :eof

:ProcessFile
if exist "%Ziel%\%~nx1" goto :eof
set /a Bytes+=%~z1
if %Bytes% lss %Grenze% (
	copy %1 "%Ziel%" >nul
) else (
	set Done=True
)01.
@echo off & setlocal 
02.
set "Quelle=C:\Bilder" 
03.
set "Typ=*.jpg" 
04.
set "Ziel=D:" 
05.
set /a Grenze=5000000 
06.
 
07.
set /a Bytes=0 
08.
set Done= 
09.
for /f %%i in ('dir "%Quelle%\%Typ%"^|findstr "Datei(en)"') do set /a Anzahl=%%i 
10.
 
11.
:Loop 
12.
set /a Nr=%random%*%Anzahl%/32768+1 
13.
for /f "tokens=1* delims=:" %%i in ('dir /b "%Quelle%\%Typ%"^|findstr /n .^|findstr /b "%Nr%"') do call :ProcessFile "%Quelle%\%%j" 
14.
if not defined Done goto :Loop 
15.
goto :eof 
16.
 
17.
:ProcessFile 
18.
if exist "%Ziel%\%~nx1" goto :eof 
19.
set /a Bytes+=%~z1 
20.
if %Bytes% lss %Grenze% ( 
21.
	copy %1 "%Ziel%" >nul 
22.
) else ( 
23.
	set Done=True 
24.
)

Im dargestellten Beispiel werden jpg-Bilder aus dem Ordner "C:\Bilder" nach "D:\" kopiert - bitte bei den Pfadangaben keinen "\" an das Ende setzen (daher nur "D:").

Anmerkung: Für das Kopieren gilt eine Speicherplatz-Obergrenze (im Beispiel 5.000.000 Bytes), aber keine -Untergrenze.

Das bedeutet: Es werden solange Bilder kopiert, bis mit dem nächsten zu kopierenden Bild die Grenze (in Bytes angegeben) überschritten würde - Beispiel: Wenn bereits Bilder mit einer Gesamtgröße von 4.620.000 Bytes kopiert wurden, wird ein weiteres Bild mit 500.000 Bytes nicht mehr kopiert, während ein solches mit 300.000 Bytes noch unter die Grenze passt und daher noch kopiert würde. Damit wird sicher gestellt, dass die angegebene Kapazität keinesfalls überschritten wird. Dennoch sollte noch eine Reserve eingeplant werden, da der tatsächliche Platzbedarf einer Datei höher ist als ihre exakte Größe in Bytes.

Bitte auch zu beachten: Wenn die Grenze zu hoch angesetzt wird (also die Größe aller Bilder zusammen den Grenzwert nicht überschreitet), läuft der Batch in eine Endlosschleife.

Grüße
bastla

Top

leertaste schreibt am 11.10.2007 um 22:23:39 Uhr

Hallo bastla face-smile

und alle anderen Mitleser face-big-smile

Es darf auch ein Batch sein face-smile

Aber ich hätte auch gerne (diverse) UnterOrdner mit einbezogen, wenn das nicht geht... ...na dann müsste ich eine Vorauswahl in einen Ordner kopieren und dann per zufall einen Teil der Bilder mit'te Batch in'ne RamDisk (Laufwerk D) kopieren. Unterordner wäre wie gesagt schön, aber zur Not kann/werde/muss ich mir dann anders behelfen... ...ansonsten ist diese kleine Routine schon echt SPITZE !!!

Wenn in der obigen Routine was "schief läuft" (z.B. zu wenig Bilder in einem Verzeichnis) läuft sie echt endloooos face-smile

könnte man nicht der kompletten Routine "sagen" - laufe nur 10x, 20x oder wie oft auch immer(?) durch und beende dich dann selbst...

Freundlicher"Vordankes"Gruss
von der Leertaste face-smile

Top

bastla schreibt am 11.10.2007 um 23:02:52 Uhr

Hallo leertaste!

Aber ich hätte auch gerne (diverse) UnterOrdner mit einbezogen

Da hatte ich einfach drübergelesen ... face-sad

laufe nur 10x, 20x oder wie oft auch immer(?) durch und beende dich dann selbst...

Eine solche Festlegung würde darauf hinauslaufen, dass (je nachdem, was früher eintritt), bei max 10, 20 oder "wieviel auch immer" Bildern oder beim Erreichen der Speichergrenze Schluss ist.

Die folgende Version sollte höchstens 20 Bilder (auch aus Unterordnern) kopieren:

@echo off & setlocal
set "Quelle=C:\Bilder"
set "Typ=*.jpg"
set "Ziel=D:"
set /a Grenze=5000000
set /a Max=20

set /a Bytes=0
set Done=
for /f %%i in ('dir /s "%Quelle%\%Typ%"^|findstr "Datei(en)"') do set /a Anzahl=%%i

:Loop
set /a Nr=%random%*%Anzahl%/32768+1
for /f "tokens=1* delims=[]" %%i in ('dir /s /b "%Quelle%\%Typ%"^|find /v /n "::"^|find "[%Nr%]"') do call :ProcessFile "%%j"
if %Max% lss 1 goto :eof
if not defined Done goto :Loop
goto :eof

:ProcessFile
set /a Max-=1
if exist "%Ziel%\%~nx1" goto :eof
set /a Bytes+=%~z1
if %Bytes% lss %Grenze% (
	copy %1 "%Ziel%" >nul
) else (
	set Done=True
)01.
@echo off & setlocal 
02.
set "Quelle=C:\Bilder" 
03.
set "Typ=*.jpg" 
04.
set "Ziel=D:" 
05.
set /a Grenze=5000000 
06.
set /a Max=20 
07.
 
08.
set /a Bytes=0 
09.
set Done= 
10.
for /f %%i in ('dir /s "%Quelle%\%Typ%"^|findstr "Datei(en)"') do set /a Anzahl=%%i 
11.
 
12.
:Loop 
13.
set /a Nr=%random%*%Anzahl%/32768+1 
14.
for /f "tokens=1* delims=[]" %%i in ('dir /s /b "%Quelle%\%Typ%"^|find /v /n "::"^|find "[%Nr%]"') do call :ProcessFile "%%j" 
15.
if %Max% lss 1 goto :eof 
16.
if not defined Done goto :Loop 
17.
goto :eof 
18.
 
19.
:ProcessFile 
20.
set /a Max-=1 
21.
if exist "%Ziel%\%~nx1" goto :eof 
22.
set /a Bytes+=%~z1 
23.
if %Bytes% lss %Grenze% ( 
24.
	copy %1 "%Ziel%" >nul 
25.
) else ( 
26.
	set Done=True 
27.
)

Anmerkung: Da auch "Fehlversuche" (wenn das Bild bereits in einem früheren Durchlauf kopiert wurde) mitgezählt werden, wird zumeist die angegebene Maximalanzahl nicht erreicht werden - daher also vielleicht etwas höher ansetzen (oder zB gleich auf 200, um tatsächlich nur der Gefahr einer Endlosschleife vorzubeugen).

Grüße
bastla

[Edit] Zweite "for"-Zeile gekürzt. [/Edit]

Top

bastla schreibt am 11.10.2007 um 23:28:58 Uhr

... und um den Ablauf vielleicht ein wenig zu beschleunigen, noch eine Variante mit Verwendung einer Temporärdatei für die Bilderliste:

@echo off & setlocal
set "Quelle=C:\Bilder"
set "Typ=*.jpg"
set "Ziel=D:"
set /a Grenze=5000000
set /a Max=20

set "Liste=%Temp%\Bilderliste.txt"
set /a Bytes=0
set Done=
for /f %%i in ('dir /s "%Quelle%\%Typ%"^|findstr "Datei(en)"') do set /a Anzahl=%%i
dir /s /b "%Quelle%\%Typ%"|find /v /n "::">"%Liste%"

:Loop
set /a Nr=%random%*%Anzahl%/32768+1
for /f "tokens=1* delims=[]" %%i in ('find "[%Nr%]"^<"%Liste%"') do call :ProcessFile "%%j"
if %Max% lss 1 goto :eof
if not defined Done goto :Loop
goto :eof

:ProcessFile
set /a Max-=1
if exist "%Ziel%\%~nx1" goto :eof
set /a Bytes+=%~z1
if %Bytes% lss %Grenze% (
	copy %1 "%Ziel%" >nul
) else (
	set Done=True
)01.
@echo off & setlocal 
02.
set "Quelle=C:\Bilder" 
03.
set "Typ=*.jpg" 
04.
set "Ziel=D:" 
05.
set /a Grenze=5000000 
06.
set /a Max=20 
07.
 
08.
set "Liste=%Temp%\Bilderliste.txt" 
09.
set /a Bytes=0 
10.
set Done= 
11.
for /f %%i in ('dir /s "%Quelle%\%Typ%"^|findstr "Datei(en)"') do set /a Anzahl=%%i 
12.
dir /s /b "%Quelle%\%Typ%"|find /v /n "::">"%Liste%" 
13.
 
14.
:Loop 
15.
set /a Nr=%random%*%Anzahl%/32768+1 
16.
for /f "tokens=1* delims=[]" %%i in ('find "[%Nr%]"^<"%Liste%"') do call :ProcessFile "%%j" 
17.
if %Max% lss 1 goto :eof 
18.
if not defined Done goto :Loop 
19.
goto :eof 
20.
 
21.
:ProcessFile 
22.
set /a Max-=1 
23.
if exist "%Ziel%\%~nx1" goto :eof 
24.
set /a Bytes+=%~z1 
25.
if %Bytes% lss %Grenze% ( 
26.
	copy %1 "%Ziel%" >nul 
27.
) else ( 
28.
	set Done=True 
29.
)

Grüße
bastla

Top

leertaste schreibt am 12.10.2007 um 00:39:50 Uhr

Ich wollt' mal gaaaaanz dringend etwas loswerden...

.

..

...

....

.....

......

....... face-smile

......

.....

....

...

..

.

Daaaaaaaaaaaaaaaaaaanke, es läuft SUPER KLASSE - Lokal auf der Platte oder via Netzwerk.
Einfach mal wieder coole Batchbastladateien

NiceBatchGruss
von MarCus mit ZEH

Ps.: Wo kann mich eigentlich so einen genialen 'BatchUmsetzungkopf' kaufen face-big-smile

mehr ...Ähnliche Beiträge

Frage ist gelöstPer Autostart unter XP - Zufallsdateien (jpg-Bilder aus verschiedenen Unterordnern) von Laufwerk C nach D kopieren

leertasteLevel 1 - Frischling11.10.200715:46:45 Uhr2114 Aufrufe5 AntwortenID: 70718

Frage ist gelöst
Per Autostart unter XP - Zufallsdateien (jpg-Bilder aus verschiedenen Unterordnern) von Laufwerk C nach D kopieren

leertaste
Level 1 - Frischling
11.10.2007
15:46:45 Uhr
2114 Aufrufe
5 Antworten
ID: 70718