borob14
Goto Top

Batch Datei durchsuchen und nach String eine zusätzliche Zeile einfügen

Hi zusammen habe schon einiges in der Richtung in diesen und anderen Foren durchgelesen, verstehe den Syntax aber nicht ganz.

mein derzeitiger Code:

@echo off & setlocal 
set "Zusatz=ShowCCWatchAndPrintButton=true"   
set "Nach=ShowAllCCWatchInfos"   
set "Datei=c:\bat\cadcom\cc_run.ini"   
set "DateiTmp=%temp%\Textfile.tmp"   

move "%Datei%" "%DateiTmp%"   
for /f "delims=" %%i in (%DateiTmp%) do (   
    >>"%Datei%" echo %%i   
    echo %%i|findstr /b "%Nach%">nul && >>"%Datei%" echo %Zusatz%   
)

der macht seine Arbeit ganz gut, nur kopiert er leider nicht alles in die "neue Datei"
Es Fehlen leere Zeilen und Kommentare aus der alten Datei.

Die Kommentare fangen alle mit ; an und beinhalten teilweise nur Wörter teilweise aber auch - _ ( ) | \ / . ! ,
Ich benötige leider eine 1 zu 1 Kopie der alten Datei nur das eine Zeile halt hinzugefügt werden muss. Die Konfig Dateien unterscheiden sich von Client zu Client leider.

Wie muss man das in die obige Batch mit einbauen damit er diese Zeichen nicht falsch interpretiert?

danke

Mit freundlichen Grüßen Rob

Content-Key: 252612

Url: https://administrator.de/contentid/252612

Ausgedruckt am: 28.03.2024 um 21:03 Uhr

Mitglied: 114757
114757 21.10.2014 aktualisiert um 13:52:41 Uhr
Goto Top
Hallo Rob,
ich mach sowas mit der Powershell:
$suche = 'ShowAllCCWatchInfos'  
$ersatz = 'ShowCCWatchAndPrintButton=true'  
$file = 'c:\bat\cadcom\cc_run.ini'  
(gc $file) -replace "^($([regex]::Escape($suche)).*)",('$1' + "`r`n$ersatz") | Set-Content $file -Force  
Gruß
jodel32
Mitglied: rubberman
Lösung rubberman 21.10.2014, aktualisiert am 23.10.2014 um 07:10:30 Uhr
Goto Top
Hallo Borob14,

ungetestet etwa so:
@echo off &setlocal 
set "Zusatz=ShowCCWatchAndPrintButton=true"   
set "Nach=ShowAllCCWatchInfos"   
set "Datei=c:\bat\cadcom\cc_run.ini"   
set "DateiTmp=%temp%\Textfile.tmp"   

setlocal EnableDelayedExpansion
<"!Datei!" >"!DateiTmp!" (  
  for /f %%i in ('type "!Datei!"^|find /c /v ""') do for /l %%j in (1 1 %%i) do (  
    set "line=" &set /p "line="  
    if not defined line (
      echo(
    ) else for /f "delims=" %%k in ("!nach!") do if "!line!"=="!line:%%k=!" (  
      echo(!line!
    ) else (
      echo(!line!
      echo(!Zusatz!
    )
  )
)
move "!DateiTmp!" "!Datei!"  
Grüße
rubberman
Mitglied: Borob14
Borob14 22.10.2014 aktualisiert um 17:57:20 Uhr
Goto Top
Danke für die 2 Tips, werde ich morgen testen.

@114757: ist interessant mit PS aber benötige das in ner bat.

@rubberman: sieht vielversprechend aus, werde ich morgen gleich mal testen, heute komm ich leider nicht mehr dazu.

Mit freundlichen Grüßen Rob


EDIT doch noch schnell Zeit gehabt:
FM: "="!line:%k=!"" kann syntaktisch an dieser Stelle nicht verwendet werden
Mitglied: rubberman
Lösung rubberman 22.10.2014, aktualisiert am 23.10.2014 um 07:10:35 Uhr
Goto Top
Hallo Rob,

sorry Schreibfehler. Der Vergleichsoperator ist == und nicht =. Hab's oben korrigiert,

Grüße
rubberman
Mitglied: Borob14
Borob14 23.10.2014 um 07:10:16 Uhr
Goto Top
Danke Rubberman,

hat geklappt und Config Datei wurde ordnungsgemäß übertragen!

Damit hat sich das hier erledigt.

mfg Rob