37414
Goto Top

Das Makro wurde nicht gefunden oder wurde deaktiviert wegen Ihrer Makro Schutzeinstellungen

In einem anderen Thread habe ich mit Eurer Hilfe ein Makro erstellt, welches grds. auch gut funktioniert.
Heute habe ich es an 3 Arbeitsplätzen installiert, indem ich den Code einfach in unserem Word 2000 unter "Extras / Makros "...bearbeiten" einkopiert habe.
Bisher ging das meist problemlos.

An einem Arbeitsplatz jedoch erhalte ich folgende Fehlermeldung:

"Das Makro wurde nicht gefunden oder wurde deaktiviert wegen Ihrer Makro Schutzeinstellungen"

Mir fiel dort auf, dass es im VBA-Editor unter "Normal / Module" zwei verschiedene Einträge gibt, die in jeweils einem eigenen Fenster erscheinen... nämlich einmal "NewMacros" und einmal "NewMacros1".
Ich habe dann den gesamten Makro-Code ins andere Fenster kopiert und aus dem ersten Fenster gelöscht.
Mit meinem Test-Dokument (einer Vorlage.dot) lief dann alles korrekt.

Nun wollte der Mitarbeiter jedoch eine andere Word-Vorlage nutzen und erhielt dann die obige Fehlermeldung.

Woran kann das liegen - und wie behebe ich das Problem?

Danke und schöne Grüße,
imebro

Content-Key: 260925

Url: https://administrator.de/contentid/260925

Ausgedruckt am: 28.03.2024 um 21:03 Uhr

Mitglied: 114757
114757 23.01.2015 aktualisiert um 14:59:10 Uhr
Goto Top
Moin,
entweder die Makro-Sicherheitseinstellungen auf Niedrig stellen Extras -> Makros -> Sicherheitseinstellungen oder das Makro-Projekt im VBA Editor mit einer selbst erstellten digitalen Signatur versehen.

Gruß jodel32
Mitglied: colinardo
colinardo 23.01.2015 aktualisiert um 16:06:47 Uhr
Goto Top
Da stimme ich @114757 zu. Entweder Makrosicherheitseinstellungen auf Niedrig stellen oder digital signieren:
http://blog.didierstevens.com/2009/01/05/howto-add-a-digital-signature- ...

Grüße Uwe
Mitglied: 37414
37414 26.01.2015 aktualisiert um 09:08:34 Uhr
Goto Top
Danke Euch.
Den Blog habe ich mir eben angeschaut.
Funktioniert aber so nicht mit dem Word 2000, welches hier im Einsatz ist.

Die Sicherheitseinstellungen standen schon auf "Niedrig". Daran kann es also nicht liegen.
Eine digitale Signatur kann ich nicht wählen, da keine existiert... liegt wohl am Word 2000.

So sieht das bei dem Mitarbeiter übrigens aus:
efe4cb47838eb1df6980fc7967cff486

Habe jetzt einfach die verschiedenen Makros in beide Fenster gespeichert.
Dann gibt es sie zwar über "Extras / Makros" doppelt, aber da nur die beiden Button im Menü genutzt werden, ist das erstmal egal.
Oder sollte ich eines der beiden Module komplett löschen?

Habe den Zusammenhang da irgendwie noch nicht kapiert.
Eigentlich müßte doch jede Dokumentenvorlage (.dot), die genutzt wird, automatisch mit diesen Makros arbeiten können.
Bei mir und einem weiteren Mitarbeiter funktioniert das ja auch. Da gibt´s aber auch nicht diese 2 Fenster (2 Module).

Bei mir sieht das Ganze so aus:
9e0fb2d133df96852ce6ef20ffaf0008

Wie man sieht, erscheint im Visual-Basic-Editor auf der linken Seite viel mehr, als bei dem Mitarbeiter mit dem Problem (siehe vorherigen Screenshot).

Habt Ihr da nochmal nen Tipp? face-wink

Danke und Gruss,
imebro
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 10:13:14 Uhr
Goto Top
Das Projekt unter Normal ist die Standardvorlage von Word (normal.dot). Wenn du dort also dein Makro reinpackst ist es in jedem neuen Dokument das in Word auf dieser Vorlage erstellt wird verfügbar.

Dann gibt es noch ein Projekt für das aktuelle Dokument das auf deiner Vorlage basierend neu angelegt wurde und das Projekt der Vorlage ansich.

Wenn man Vorlagen anpassen will öffnet man sie im Explorer nicht mit einem Doppelklick sondern mit Rechtsklick > Öffnen (der zweite Eintrag unter dem Standard). Damit wird dann nicht ein neues Dokument auf Basis dieser Vorlage erstellt sondern die Vorlage selber geöffnet !! Das ist wichtig !

Zum Thema Signatur, das Feature muss im Office-Setup ausgewählt worden sein, damit du eine Signatur erstellen kannst. Sie ist aber nicht nötig wenn du die Sicherheitseintellungem auf Niedrig gestellt hast.

Also das Makro in das Vorlagen-Projekt kopieren und dann läuft das ! Bei dir scheint das das Projekt TemplateProject zu sein.
Aber bitte wie geschrieben überprüfen wie die die Vorlage öffnest!! mit Doppelklick änderst du nicht die Vorlage sondern erstellst daraus wie schon gesagt ein neues Dokument.

Frage: Wie und womit lässt du dein Makro starten? Das ist auch nicht ganz unwichtig!

Grüße Uwe
Mitglied: 37414
37414 26.01.2015 aktualisiert um 10:19:48 Uhr
Goto Top
OK und danke schonmal...

Das mit dem Öffnen der Dokumenten-Vorlage (.dot) war mir schon klar... Die Screenshots hatte ich der Einfachheit halber einfach mit einem neuen Dokument erstellt, ohne die Vorlage (.dot) zu öffnen.
Ich erkläre mal kurz, wie die Dokumente bei uns entstehen.

Wir nutzen ein Programm, über das dann verschiedene Schreiben erstellt werden können.
Diese Schreiben können über ein Dropdown-Menü über das Programm ausgewählt werden.
Zur Auswahl stehen ca. 15 verschiedene Dokument-Vorlagen (.dot).
All das läuft über Word 2000.

Wenn man sich also nun für eine der 15 Dokumenten-Vorlagen entschieden und diese ausgewählt hat, öffnet sich automatisch Word 2000 und öffnet ein neues Dokument auf der Basis der dazu passende Dokumenten-Vorlage (.dot).

In diesem neu erstellen Dokument wird also dann Text geschrieben und am Ende soll dieses Dokument gedruckt werden.
Zusätzlich soll automatisch unter dem Text "Mit freundlichen Grüßen" dann die Unterschrift des betreffenden Mitarbeiters gesetzt werden inkl. "i. A." und der Abteilung. Das läuft dann über das VBA-Script aus dem vorherigen Thread!!

Der Druckvorgang wird dann über einen im Word-Menü eingesetzten Button ausgelöst, welcher dann das Makro mit dem Script startet.
Dieser Menü-Button erscheint immer im Word-Menü... egal welche Dokumenten-Vorlage man im Programm ausgewählt hat.

Das mal so zum Verständnis face-wink

Daher muß das Makro ja mit jedem dieser neu erstellten Dokumente funktionieren und auf Basis ALLER 15 Dokumenten-Vorlagen (.dot) - egal welche man davon wählt.

Daher ist mir jetzt noch nicht so ganz klar, wo ich für diese Fälle das Makro im VBA-Editor speichern muss, damit es so funktioniert.

Danke und schöne Grüße,
imebro
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 10:26:20 Uhr
Goto Top
OK.
Dann mach dir am besten ein sogenanntes Add-In Dokument welches die Makros beinhaltet, und gebe dieses unter Addins > Vorlagen auf den jeweiligen Rechnern an:
https://support.office.com/de-ch/article/Laden-oder-Entladen-einer-Dokum ...
Dann brauchst du den Code auch nicht bei jedem Client hineinkopieren, sondern hast eine Zentrale Vorlage. Wenn mal Änderungen nötig sind, ist das auch wesentlich einfacher zu warten, da die Änderung zentral geschehen kann.
Mitglied: 37414
37414 26.01.2015 um 10:48:44 Uhr
Goto Top
...danke für den Tipp.

Aber das Problem ist, dass das Makro ja bei jedem Mitarbeiter anders aussieht.
Das Foto, welches die Unterschrift einfügt, habe ich ja bei jedem Mitarbeiter schon mit "Unterschrift.jpg" bezeichnet. Dennoch ist der Pfad zum Desktop des jeweiligen Mitarbeiters ja anders, wo diese JPG-Datei liegt.

Aber der Text unter "i. A." ist bei JEDEM Mitarbeiter anders und auch die Druckerbezeichnungen, welche im Makro auftauchen, sind jeweils unterschiedliche.

Von daher wird es nicht gehen, wenn alle auf die gleichen Makros zugreifen... es wird nur so gehen, dass jeder seine eigenen Makros nutzen kann.

LG
imebro
Mitglied: 114757
114757 26.01.2015 aktualisiert um 10:59:44 Uhr
Goto Top
Von daher wird es nicht gehen, wenn alle auf die gleichen Makros zugreifen... es wird nur so gehen, dass jeder seine eigenen Makros nutzen kann.
Quatsch mit Soße. Grafiken kann man auch an Zentraler Stelle ablegen oder für den Namen oder den Pfad Variablen wie den aktuellen Usernamen heranziehen !! Das ist allemal besser als so ein pro User misst den du da baust. Ebenso die Daten unter der Überschrift lassen sich in einer zentralen Textdatei ablegen die man dann anhand des Usernamens filtert und die jeweiligen Textstellen ausgibt.
So wie du das machst ist das absolut unüblich und du hast wie @colinardo schon sagt erheblichen Aufwand wenn mal Änderungen anstehen...so ist das absoluter Murks, sorry.
Das wird dir hier jeder bestätigen...

Gruß jodel32

P.s. Und wenn du es unbedingt so machen willst kannst du ja für jeden Otto eine angepasste Vorlage erstellen und diese unter Addins einbinden.
Mitglied: 37414
37414 26.01.2015 um 11:05:27 Uhr
Goto Top
OK "jodel32"... leuchtet mir ein mit den Variablen sowie der zentralen Textdatei mit der Filterungsmöglichkeit für die einzelnen User.

Ich nehme an, dass ich die Variable im Script einfach mit %USERNAME% angeben kann für die Fotos, welche dann auf dem jeweiligen Desktop immer den gleichen Namen haben.

Bei der Textdatei mit den Filterungsmöglichkeiten für die einzelnen Mitarbeiter bräuchte ich dann nochmal Eure Hilfe. face-wink

Danke und Gruss,
imebro
Mitglied: 114757
114757 26.01.2015 um 11:14:07 Uhr
Goto Top
Ich nehme an, dass ich die Variable im Script einfach mit %USERNAME% angeben kann für die Fotos, welche dann auf dem jeweiligen Desktop immer den gleichen Namen haben.
Nope, machst du so:
set objShell = CreateObject("wscript.shell")  
strUserprofile = objShell.ExpandEnvironmentStrings("%userprofile%")  
strImagePath = strUserprofile & "\Desktop\unterschrift.jpg"  
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 11:57:01 Uhr
Goto Top
Zitat von @37414:
Bei der Textdatei mit den Filterungsmöglichkeiten für die einzelnen Mitarbeiter bräuchte ich dann nochmal Eure
Hilfe. face-wink
Kein Problem, hier ein Beispiel für das Auslesen aus einer Datei die bspw. so aufgebaut ist:
mmustermann;Zusatztext1;Zusatztext2
smeier;Zusatztext1;Zusatztext2
usw.
Dim objShell,fso,regex,matches,strText1,strText2
'Pfad zur Textdatei   
Const FILEPATH = "\\Server\Share\daten.txt"  
'Objekte  
Set objShell = CreateObject("Wscript.Shell")  
Set fso = CreateObject("Scripting.FileSystemObject")   
Set regex = CreateObject("vbscript.regexp")  
'aktueller angemeldeter User  
strUsername = objShell.ExpandEnvironmentStrings("%username%")  
'Regex Settings  
regex.Global = False: regex.IgnoreCase = True: regex.MultiLine = True
'Regex Pattern für Zeilen (in dem Fall sind es drei Spalten mit Semikolon getrennt Spalte1=Username / Spalte2=Zusatztext1 / Spalte3=Zusatztext2)  
regex.Pattern = "^" & strUsername & ";(.*);(.*)"  

'Regex auf Inhalt der Textdatei anwenden (Usernamen suchen)  
Set matches = regex.Execute(fso.OpenTextFile(FILEPATH,1).ReadAll())
'Wurde ein Treffer gefunden setze die Variablen  
If matches.count > 0 Then
	strText1 = matches(0).Submatches(0)
	strText2 = matches(0).Submatches(1)
Else	'es wurde kein passender User gefunden, in diesem Fall setze die Werte der Variablen z.B. auf Defaultwerte  
	strText1 = ""  
	strText2 = ""  
End If

MsgBox strText1 & " / " & strText2  

Set objShell = Nothing
Set fso = Nothing
Set regex = Nothing
Grüße Uwe
Mitglied: 37414
37414 26.01.2015 um 11:56:07 Uhr
Goto Top
Super... danke!

Würde das auch mit einer Druckerbezeichnung gehen?
Wenn z.B. der Drucker des einen Mitarbeiters"MV_Schmitz_Blanko" heißen würde und der des anderen "MV_Müller_Blanko"... könnte man dann z.B. im Script einfach "MV_%username%_Blanko" angeben?

LG
imebro
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 12:00:27 Uhr
Goto Top
Zitat von @37414:
Würde das auch mit einer Druckerbezeichnung gehen?
Wenn z.B. der Drucker des einen Mitarbeiters"MV_Schmitz_Blanko" heißen würde und der des anderen
"MV_Müller_Blanko"... könnte man dann z.B. im Script einfach "MV_%username%_Blanko" angeben?
Das geht nach dem Schema von oben so:
set objShell = CreateObject("wscript.shell")  
strUsername = objShell.ExpandEnvironmentStrings("%username%")  
strPrintername = "MV_" & strUsername & "_Blanko"  
Mitglied: 37414
37414 26.01.2015 um 12:12:07 Uhr
Goto Top
OK...

Dann müßte ich an meinem jetzigen Script (an dem Du mir ja geholfen hattest), folgendes ändern, wenn ich das so richtig sehe:

1) Eine Text-Datei erstellen, die ich in einem Server-Pfad ablege (z.B. "S:\Daten_MV").
In dieser Datei müßten dann die Namen der Mitarbeiter stehen sowie das "i. A." sowie die jeweilige Bezeichnung (Dienstbezeichnung des Mitarbeiters).
Also z.B. so:

Müller;i. A.;Bezeichnung1
Schmitz;i. A.;Bezeichnung2

2) Das Script, welches Du eben hier eingesetzt hattest, müßte dann irgendwo in mein bestehendes Script eingebaut werden... also wohl da, wo das Foto eingesetzt wird (Unterschrift.jpg) sowie das "i. A." sowie "Abteilung" (also die o.g. Dienstbezeichnung).
Im jetzigen Script wird dies Alles ja hinter dem Text "Mit freundlichen Grüßen" eingesetzt.

3) Das jetzige Script müßte erweitert werden um die folgenden Zeilen:

set objShell = CreateObject("wscript.shell")  
strUserprofile = objShell.ExpandEnvironmentStrings("%userprofile%")  
strImagePath = strUserprofile & "\Desktop\unterschrift.jpg"  
strUsername = objShell.ExpandEnvironmentStrings("%username%")  
strPrintername = "MV_" & strUsername & "_Blanko"  

Müßten diese Zeilen ganz oben stehen?

Hmmm... hoffe, ich habe das jetzt wenigstens annähernd richtig verstanden face-wink

LG
imebro
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 12:22:49 Uhr
Goto Top
Zitat von @37414:
Hmmm... hoffe, ich habe das jetzt wenigstens annähernd richtig verstanden face-wink
Ja soweit hast du das richtig interpretiert. Damit das hier jetzt nicht wieder so ein ellenlanger Thread wie letztes mal wird, und wir einen VBA Kurs machen müssen face-wink, anhand deines Codes aus dem letzten Thread, das ganze mal zusammengesetzt:
Sub Foto_und_Druck()
'  
    Dim img As InlineShape, posImage As Range, posAbteilung As Range, posImAuftrag As Range
    Dim objShell As Object,fso As Object,regex As Object,matches,strText1 As String,strText2 As String
	'Pfad zur Textdatei   
	Const FILEPATH = "S:\Daten_MV\daten.txt"  
	'Objekte  
	Set objShell = CreateObject("Wscript.Shell")  
	Set fso = CreateObject("Scripting.FileSystemObject")   
	Set regex = CreateObject("vbscript.regexp")  

	strUsername = objShell.ExpandEnvironmentStrings("%username%")  
	strUserprofile = objShell.ExpandEnvironmentStrings("%userprofile%")  
	strImagePath = strUserprofile & "\Desktop\Unterschrift.jpg"  
	
	'Druckername  
	strPrintername = "MV_" & strUsername & "_Blanko"  
	'Regex Settings  
	regex.Global = False: regex.IgnoreCase = True: regex.MultiLine = True
	'Regex Pattern für Zeilen  
	regex.Pattern = "^" & strUsername & ";(.*);(.*)"  
	
	'Regex auf Inhalt der Textdatei anwenden (Usernamen suchen)  
	Set matches = regex.Execute(fso.OpenTextFile(FILEPATH,1).ReadAll())
	'Wurde ein Treffer gefunden setze die Variablen  
	If matches.count > 0 Then
		strText1 = matches(0).Submatches(0)
		strText2 = matches(0).Submatches(1)
	Else	'es wurde kein passender User gefunden, in diesem Fall setze die Werte der Variablen z.B. auf Defaultwerte  
		strText1 = ""  
		strText2 = ""  
	End If
    
    
    Selection.GoTo wdGoToPage, wdGoToFirst
    With ActiveDocument.Content.Find
        .Text = "Mit freundlichen Grüßen"  
        .Forward = True
        .Wrap = wdFindContinue
        .MatchWildcards = True
        .Execute
        If .Found Then
            .Parent.InsertParagraphAfter
            .Parent.InsertParagraphAfter
            .Parent.InsertParagraphAfter
            .Parent.InsertParagraphAfter
            Set posImage = .Parent.GoTo(wdGoToLine, wdGoToNext, 1)
            posImage.ParagraphFormat.LineSpacingRule = wdLineSpaceSingle
            Set img = posImage.InlineShapes.AddPicture(strImagePath)
            Set posImAuftrag = posImage.GoTo(wdGoToLine, wdGoToNext, 1)
            With posImAuftrag
                .End = .Paragraphs(1).Range.End
                .Font.Name = "Arial"  
                .Font.Size = 11
                .Text = strText1
            End With
            
            Set posAbteilung = posImAuftrag.GoTo(wdGoToLine, wdGoToNext, 1)
            With posAbteilung
                .End = .Paragraphs(1).Range.End
                .Font.Name = "Arial"  
                .Font.Size = 9
                .Text = strText2
            End With
        End If
    End With
    
    Set objShell = Nothing
	Set fso = Nothing
	Set regex = Nothing
    
    Call drucken
End Sub
Viel Erfolg
Grüße Uwe
Mitglied: 37414
37414 26.01.2015 um 12:39:19 Uhr
Goto Top
WOW danke Dir... das ist ja perfekt face-wink

Nur zum Verständnis:

Mit "strText1" und "strText2" werden i. A. und die Dienstbezeichnung eingesetzt.

Diese Angaben, sowie die Namen hatte ich ja in meinem obigen Vorschlag so in die Textdatei "daten.txt" eingetragen:

Müller;i. A.;Bezeichnung1
Schmitz;i. A.;Bezeichnung2

Ich kapiere dabei nicht, wie die Namen aufgespürt werden?
Im Code finde ich an der entspr. Stelle kein "strUsername", womit z.B. "Müller" oder "Schmitz" identifiziert werden können...

LG
imebro
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 13:09:21 Uhr
Goto Top
Zitat von @37414:
Mit "strText1" und "strText2" werden i. A. und die Dienstbezeichnung eingesetzt.
Ja in diesen Variablen sind die jeweiligen Texte des Mitarbeiters enthalten
Diese Angaben, sowie die Namen hatte ich ja in meinem obigen Vorschlag so in die Textdatei "daten.txt" eingetragen:
genau
Ich kapiere dabei nicht, wie die Namen aufgespürt werden?
Die werden mit Regular Expressions extrahiert (das geht fixer als Zeile für Zeile zu überprüfen ob ein User vorhanden ist oder nicht):
Folgende Zeile definiert einen RegEx Pattern mit dem die Textdatei nachher überprüft wird
regex.Pattern = "^" & strUsername & ";(.*);(.*)" 
Genauer gesagt macht der Pattern folgendes: Er findet Zeilen bei denen am Zeilenanfang (^) der Username steht welcher vorher ja schon ausgelesen wird (strUsername). Der Rest trennt die Spalten auf und verteilt diese auf Subpatterns (durch die Klammern).
Die Suche wird dann hier auf den Inhalt der Textdatei angewendet:
Set matches = regex.Execute(fso.OpenTextFile(FILEPATH,1).ReadAll()) 
und hier werden die Subpatterns (welche oben in den Klammern stehen) ausgelesen und den Variablen zugeordnet:
strText1 = matches(0).Submatches(0)
strText2 = matches(0).Submatches(1) 
Regular Expressions Tutorial

Grüße Uwe
Mitglied: 37414
37414 26.01.2015 aktualisiert um 15:06:35 Uhr
Goto Top
OK...
Habe es jetzt mal bei mir getestet und es funktioniert wunderbar!

Danke nochmal für Deine Mühe an dieser Stelle! face-wink

Habe mir eben mal Deinen Link bezüglich AddIn laden... angeschaut.
Was ich dabei noch nicht verstehe, ist der Vorgang, wie ich

1) dieses Makro nun zu einem AddIn mache (im Text wird nur von Dokumentenvorlagen geschrieben... aber ich habe ja 15 verschiedene Vorlagen...)

2) was genau muss ich nun in den jeweiligen Autostart-Ordner des jeweiligen Mitarbeiters legen... oder ist das so gemeint, dass ich dieses AddIn (bzw. das aus Punkt 1) dann auch irgendwo zentral (z.B. auf einem Serverpfad) ablege?

Zur Info:
- Wir arbeiten alle auf einem Terminalserver (Windows Server 2008) und greifen alle auf die gleichen 15 Word-Vorlagen zu.
- Bei uns heißt der AutoStart-Ordner: "C:\Users\username\AppData\Roaming\Microsoft\Word\StartUp"

Danke und Gruss,
imebro
Mitglied: colinardo
colinardo 26.01.2015 aktualisiert um 15:19:04 Uhr
Goto Top
dieses Makro nun zu einem AddIn mache
Garnicht, du erstellst ein normales *.dot-Dokument in welches du deine Makros packst speicherst und dann im Dialog unter Extras > Vorlagen und Addins öffnest.

fb8185c7877a5d7699b261cc1940df8c

Dann ist diese Vorlage im Hintergrund für Word immer verfügbar. Fertsch ...
Mitglied: 37414
37414 26.01.2015 aktualisiert um 15:44:02 Uhr
Goto Top
...ahaaa...

Und das wird dann zu der Dokumentenvorlage "Normal" hinzugefügt?

Hmmm... glaube ich raffe das nicht face-sad

Bei mir z.B. habe ich die Makros einfach mit einem neuen Dokument erstellt und sie sind dann in jeder Vorlage automatisch nutzbar.
So richtig blicke ich da nicht durch, warum ein Add In wann und wo gespeichert werden muss, damit man es jederzeit nutzen kann.

Logisch wäre das für mich nur dann, wenn dieses Dokument... oder von mir aus auch diese Vorlage ZENTRAL auf dem Server gespeichert würde und alle Mitarbeiter würden AUTOMATISCH auf diese Vorlage mit den Makros zugreifen.

Das ganze Problem tauchte ja auch erst auf, nachdem es bei dem einen Mitarbeiter nicht automatisch funktionierte...

Nun ja...

Jedenfalls nochmals danke und schöne Grüße & bis morgen face-wink

imebro
Mitglied: colinardo
Lösung colinardo 26.01.2015, aktualisiert am 28.01.2015 um 10:02:00 Uhr
Goto Top
Und das wird dann zu der Dokumentenvorlage "Normal" hinzugefügt?
Nein, die Vorlage wird einfach zusätzlich im Hintergrund dazugeladen. Das kannst du auch im VBAEditor bei jedem neu erzeugten Dokument in der Baumansicht nachvollziehen ...