zunaras
Goto Top

Outlook 2010 Weiterleiten Makro, Betreff ergänzen, Adresse anpassen

Schönen guten Tag,

ich habe hier ein Makro zum Weiterleiten von eMails. Hier kann ich diese dann per Knopfdruck aus der Symbolleiste/Ribbon direkt an den Empfänger schicken und aus meinem Posteingang löschen. Funktioniert soweit prima.

Frage 1: Kann man in die vorhandene Betreffzeile noch Zeichen hinzufügen (z.B. "wl.")?
Das soll einer Regel helfen zu erkennen, welche Nachrichten ich weitergeleitet habe um diese in einen anderen Ordner zu verschieben.

Frage 2: Kann man etwas an der Absenderadresse drehen? Meine Mitarbeiter bekommen meine weitergeleiteten Mails. Leider steht dann bei denen im Posteingang in der Spalte "Von" immer meine Adresse drin. Kann da der tatsächliche Originalabsender stehen? Das wäre viel übersichtlicher. Als Antwortadresse ist per Code ja schon mal der richtige Absender eingetragen.

Viele Grüße
Zunaras

Function GetCurrentItem() As Object
Dim objApp As Outlook.Application
Set objApp = Application
On Error Resume Next
Select Case TypeName(objApp.ActiveWindow)
Case "Explorer"  
Set GetCurrentItem = _
objApp.ActiveExplorer.Selection.Item(1)
Case "Inspector"  
Set GetCurrentItem = _
objApp.ActiveInspector.CurrentItem
Case Else
End Select
End Function

Sub User1()

Dim objMail As Outlook.MailItem

Set objItem = GetCurrentItem()
Set objMail = objItem.Forward
objMail.ReplyRecipients.Add objItem.SenderEmailAddress
objMail.To = "User1@mail.de"  
objMail.Send
objItem.Delete
Set objItem = Nothing
Set objMail = Nothing

End Sub

Sub User2()

Dim objMail As Outlook.MailItem

Set objItem = GetCurrentItem()
Set objMail = objItem.Forward
objMail.ReplyRecipients.Add objItem.SenderEmailAddress
objMail.To = "User2@mail.de"  
objMail.Send
objItem.Delete
Set objItem = Nothing
Set objMail = Nothing

End Sub

Content-Key: 218036

Url: https://administrator.de/contentid/218036

Ausgedruckt am: 29.03.2024 um 12:03 Uhr

Mitglied: Bitboy
Bitboy 27.09.2013 um 13:30:05 Uhr
Goto Top
Hi

so vllt?
1.
objMail.Subject = "wl" & objItem.Subject

2.
Könntest mal mit den Sender Funktionen / Eigenschaften versuchen ob du die ändern kannst
http://msdn.microsoft.com/en-us/library/office/ff869598.aspx
Mitglied: colinardo
colinardo 27.09.2013 um 14:02:29 Uhr
Goto Top
Hallo Zunaras,
um eine Mail mit dem ursprünglichen Absender "weiterzuleiten" musst du folgenden Umweg nehmen:
http://www.jpsoftwaretech.com/outlook-vba/resend-this-message/
Dieser Code bedient sich der Funktion "Diese Nachricht erneut senden" im Ribbon Nachricht > Verschieben einer Nachricht.

@Bitboy
.Könntest mal mit den Sender Funktionen / Eigenschaften versuchen ob du die ändern kannst
http://msdn.microsoft.com/en-us/library/office/ff869598.aspx
diese Eigenschaft ist schreibgeschützt !

Grüße Uwe
Mitglied: Zunaras
Zunaras 27.09.2013 um 20:26:03 Uhr
Goto Top
Hallo ihr beiden,

vielen Dank für die Hilfe.
Ich kann es allerdings erst Montag ausprobieren. Ich melde mich dann wieder.

Viele Grüße
Zunaras
Mitglied: Zunaras
Zunaras 30.09.2013 um 14:05:05 Uhr
Goto Top
Hallo Bitboy,

objMail.Subject = "wl" & objItem.Subject funktioniert prima.

Leider gibt es das Problem, das automatische Regeln bei IMAP-Konten nicht funktionieren. Man kann sie nur manuell anstoßen.
Habe schon so viele Seiten durchgeforstet, aber keiner hatte eine Lösung.

Aber das hilft mir schon mal weiter. Muss ich nur einmal die Woche selbst dran denken.

Viele Grüße
Zunaras
Mitglied: Zunaras
Zunaras 30.09.2013 um 14:15:58 Uhr
Goto Top
Zitat von @colinardo:
Hallo Zunaras,
um eine Mail mit dem ursprünglichen Absender "weiterzuleiten" musst du folgenden Umweg nehmen:
http://www.jpsoftwaretech.com/outlook-vba/resend-this-message/
Dieser Code bedient sich der Funktion "Diese Nachricht erneut senden" im Ribbon Nachricht > Verschieben einer
Nachricht.


Hallo colinardo,

lässt sich der Code soweit anpassen,
das nicht immer der Hinweis kommt, das ich nicht der ursprüngliche Absender zu sein scheine,
gleich einen festen Empfänger bei "An" hinterlegen?
und nach dem Senden aus meinem Posteingang gelöscht wird?

Oder gibt es da Einschränkungen seitens Microsoft?

Viele Grüße
Zunaras
Mitglied: colinardo
colinardo 30.09.2013, aktualisiert am 01.10.2013 um 12:13:50 Uhr
Goto Top
Zitat von @Zunaras:
lässt sich der Code soweit anpassen,
das nicht immer der Hinweis kommt, das ich nicht der ursprüngliche Absender zu sein scheine,
Das Problem hier ist, das der Dialog kommt wenn du nicht der erste warst der die Mail gesendet hat. Ausblenden lässt sich dieser nicht.
Wenn du den Dialog bestätigst und die Mail absendest, wird beim Empfänger immer solch eine Absenderzeile stehen:
Sepp Meier <sepp@meier.de> im Auftrag von Herbert Tester <test@test.de>
Dies ist nicht zu vermeiden, das gute aber ist, wenn jemand auf diese Mail antwortet wird automatisch der ursprüngliche Sender als Empfänger verwendet.
Solch eine Mail muss man aber nicht über "Erneut senden" erstellen, sondern man kann sie einfacher erzeugen und dann erscheint dieser Dialog nicht mehr. Siehe Code u,
gleich einen festen Empfänger bei "An" hinterlegen?
kein Problem, siehe Zeile 23 im Code
und nach dem Senden aus meinem Posteingang gelöscht wird?
ja, siehe den angepassten Code:
Sub ResendMsg()
    Dim myItem As Outlook.MailItem
    Dim olNewMailItem As Outlook.MailItem
    
    ' get valid ref to current item  
    On Error Resume Next
    Select Case TypeName(Application.ActiveWindow)
        Case "Explorer"  
            Set myItem = ActiveExplorer.Selection.Item(1)
        Case "Inspector"  
            Set myItem = ActiveInspector.CurrentItem
        Case Else
    End Select
    On Error GoTo 0

    If myItem Is Nothing Then
        MsgBox "Konnte kein aktuelles Mailitem finden!", vbExclamation  
        GoTo exitproc
    End If

    Set olNewMailItem = myItem.Forward
    olNewMailItem.Subject = "WL: " & myItem.Subject  
    olNewMailItem.To = "User1@mail.de"  
    olNewMailItem.SentOnBehalfOfName = myItem.SenderEmailAddress
    olNewMailItem.Display
    'Nächste Zeile auskommentieren wenn die Nachricht direkt gesendet werden soll  
    'olNewMailItem.Send  
    myItem.Delete

exitproc:
Set myItem = Nothing
Set olNewMailItem = Nothing
End Sub

Probiers halt mal aus...
Grüße Uwe
Mitglied: Zunaras
Zunaras 30.09.2013 um 15:48:28 Uhr
Goto Top
Hallo colinardo,

ich bin immer wieder erstaunt, was Du so alles zauberst.

Beim Testen ist mir aufgefallen, das im Text eingebettete Bilder nicht mehr da sind, sowie die Anhänge.
"Das verknüpfte Bild kann nicht angezeigt werden. Möglicherweise wurde die Datei verschoben....."

Viele Grüße
Zunaras
Mitglied: colinardo
colinardo 30.09.2013 aktualisiert um 16:11:44 Uhr
Goto Top
Zitat von @Zunaras:
Beim Testen ist mir aufgefallen, das im Text eingebettete Bilder nicht mehr da sind, sowie die Anhänge.
"Das verknüpfte Bild kann nicht angezeigt werden. Möglicherweise wurde die Datei verschoben....."
sorry da war ich zu schnell, ist oben gefixt ...
Mitglied: Zunaras
Zunaras 30.09.2013 um 16:41:30 Uhr
Goto Top
Viel besser als der Code, den ich seit Jahren benutze. Deiner ist perfekt!

Ich danke Dir wieder einmal für die tolle Hilfe!

Viele liebe Grüße
Zunaras
Mitglied: Zunaras
Zunaras 01.10.2013 um 12:10:38 Uhr
Goto Top
Hallo nochmal,

ab und zu wird mir diese Meldung angezeigt. Scheinbar stimmt etwas an der eMail-Adresse nicht.
Dadurch wird die Mail nicht weitergeleitet.

Kannst Du erkennen woran es liegen könnte?

edf38c7d3d7c5a8563f1a73ff2e87348


Viele Grüße
Zunaras
Mitglied: colinardo
colinardo 01.10.2013 um 12:14:39 Uhr
Goto Top
Ah OK verstehe, hab es oben korrigiert, sollte dann nicht mehr auftreten...
Grüße Uwe
Mitglied: Zunaras
Zunaras 01.10.2013 um 12:28:28 Uhr
Goto Top
Viele Dank!
Gruß
Zunaras