whippi
Feb 18, 2011, updated at Feb 21, 2011 (UTC)
view3789
view4
0
Goto Top

Vorkommen von Dateitypen ermitteln (z.B. mehr als 2 .exe)

GermansolvedQuestionBatch, ShellDevelopment

Hallo, ich habe mich soeben angemeldet. Ich begrüße alle Fachleute, und hoffe zunächst einmal, daß mir hier der ein oder andere Tipp gegeben werden kann.
Ich meinerseits hoffe, wenn ich die anderen Themenbereiche näher studiert habe, das ebenfalls tun zu können.

Ich möchte einen Batchjob erstellen, mit dem ich beispielsweise im Ordner Windows und in allen seinen Unterordnern ermitteln kann, wo mehr als 2 Dateien eines Typs vorhanden sind. Zum Beispiel alle Ordner wo mehr als 2 .exe Dateien vorkommen. Die Ergebnisse möchte ich dann in eine txt-Datei ausgeben. Es wäre schön, wenn ich da Hilfe bekommen würde. Erstmal Danke Whippi
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 161104

Url: https://administrator.de/contentid/161104

Printed on: April 19, 2024 at 11:04 o'clock

4 Comments
Latest comment
Goto Top
Member: bastla
bastla Feb 18, 2011 at 16:57:27 (UTC)
Goto Top
Hallo whippi und willkommen im Forum!

Das könnte (oberflächlich getestet) etwa so gehen:
@echo off & setlocal
set "Log=D:\Ordner mit mehreren %Typ%-Dateien.txt"  
set "Basis=C:\Windows"  
set "Typ=exe"  
set "Min=2"  

del "%Log%" 2>nul  
for /r "%Basis%" %%i in (.) do call :ProcessDir "%%~fi"  
goto :eof

:ProcessDir
echo Untersuche: %~1
set /a Anz=0
for /f %%a in ('dir "%~1\*.%Typ%" 2^>nul^|findstr /c:"Datei(en)"') do set /a Anz=%%a  
if %Anz% gtr %Min% >>"%Log%" echo %~1  
goto :eof
Die Werte in den Zeilen 2 bis 5 musst Du Deinen Bedürfnissen anpassen - derzeit entsprechen sie Deinem Beispiel "mehr als 2 exe-Dateien in der Ordnerstruktur unterhalb von C:\Windows".

Falls Dich ev auch die Anzahl der Dateien interessieren sollte, verwende die folgende Zeile 15:
if %Anz% gtr %Min% >>"%Log%" echo %Anz%	%~1
Zwischen %Anz% und %~1 befindet sich übrigens ein TAB ...

Grüße
bastla

P.S.: Das kann dauern ... face-wink
Member: bastla
bastla Feb 18, 2011 at 17:29:14 (UTC)
Goto Top
... wenn übrigens die genaue Anzahl der Dateien nicht benötigt wird, ginge das etwas face-wink schneller (wobei hier die Angabe der gesuchten Anzahl mit >= erfolgen muss, daher 3 für "mehr als 2")::
@echo off & setlocal
set "Log=D:\Ordner mit mehreren %Typ%-Dateien.txt"  
set "Basis=C:\Windows"  
set "Typ=exe"  
set "Min=3"  

del "%Log%" 2>nul  
set /a Anz=0
set "Ordner="  
for /f "delims=" %%i in ('dir /s /b /a-d "%Basis%\*.%Typ%"') do call :ProcessDir "%%~dpi"  
goto :eof

:ProcessDir
echo Gefunden in: %~1
if "%~1" neq "%Ordner%" set /a Anz=0  
set "Ordner=%~1"  
set /a Anz+=1
if %Anz%==%Min% >>"%Log%" echo %Ordner:~,-1%  
goto :eof
Anstelle des sturen Abklapperns sämtlicher Unterordner und Auswertung des jeweiligen "dir" werden in dieser Version vorweg alle der Vorgabe entsprechenden Dateien gesucht und jeweils nur deren Pfad (=Elternordner) an das Auswertungsunterprogramm übergeben, wo per Gruppenverarbeitung gezählt wird. Wenn der Zähler dem gesuchten Minimalwert entspricht (durch den Vergleich mit = anstelle von > lässt sich erreichen, dass jeder Pfad nur einmal erfasst wird), erfolgt die Ausgabe des Ordners in die Log-Datei .
Eine Variante, sodass doch auch die Anzahl der Dateien mit ausgegeben werden kann, hätte ich dann auch noch (jetzt wieder mit >-Angabe face-wink):
@echo off & setlocal
set "Log=D:\Ordner mit mehreren %Typ%-Dateien.txt"  
set "Basis=C:\Windows"  
set "Typ=exe"  
set "Min=2"  

del "%Log%" 2>nul  
set /a Anz=0
set "Ordner="  
for /f "delims=" %%i in ('dir /s /b /a-d "%Basis%\*.%Typ%"') do call :ProcessDir "%%~dpi"  
if %Anz% gtr %Min% >>"%Log%" echo %Anz%	%Ordner:~,-1%  
goto :eof

:ProcessDir
echo Gefunden in: %~1
if "%~1" neq "%Ordner%" (  
    if %Anz% gtr %Min% >>"%Log%" echo %Anz%	%Ordner:~,-1%  
    set /a Anz=0
)
set "Ordner=%~1"  
set /a Anz+=1
goto :eof
Hier wird das Schreiben in die Datei verzögert, bis ein Gruppenwechsel (= ein anderer Elternordner) auftritt und dann anhand der Anzahl entschieden, ob der Ordner in das Log geschrieben werden soll.

Grüße
bastla
Member: whippi
whippi Feb 18, 2011 at 20:58:47 (UTC)
Goto Top
Hallo bastla, man, ich bin überwältigt. In so einer affenartigen Geschwindigkeit so ausführlich und sogar mit Altenativen.
Am Montag werde ich das alles mal ausprobieren. Danke erstmal - Ich melde dann Vollzug... whippi
Member: whippi
whippi Feb 21, 2011 at 12:57:31 (UTC)
Goto Top
Hallo bastla,
so... jetzt habe ich Deine Vorschläge getestet. Erstmal danke dafür.
Alle 3 Vorschläge lieferten genau das, was ich mir vorgestellt hatte.
Ich habe bei allen Varianten eine Startzeit und eine Endzeit mit ausgegeben, mit folgenden Werten:
Variante-1 ohne Anzahl 0,42 sec
Variante-1 mit Anzahl 5,75 sec
Variante-2 ohne Anzahl 0,42 sec
Variante-3 mit Anzahl 0.39 sec
Ich werde Variante-3 nehmen.
Gruß whippi

hoffentlich finde ich den Haken "als gelöst melden" o.ä. wieder
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
gleixnerdCheck of ZFW Firewallgleixnerd - 3 CommentsAlexWishaHow to set up and configure a Linux GRE tunnelAlexWisha - 3 CommentsjstrickerWIREGUARD VPN ON UDM PRO BEHIND FRITZBOX - HANDSHAKE DID NOT COMPLETEjstricker - 3 CommentsDaniEnd of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment