Bereiche

Heiß diskutierte Fragen

Auswertung bzw. Verwendung von Übergabeparametern.

ahe
Level 1 - Frischling
07.01.2009
14:26:53 Uhr
5343 Aufrufe
5 Antworten
ID: 105396

Noch nicht bewertet

Problem:
Auswertung von Übergabeparametern.
(OS = Windows XP)

Ein Programm benötigt beim Start einige Parameter, die mit Hilfe eine Batch auf Vorhandensein und Gültigkeit geprüft werden müssen.

Auswertung bzw. Verwendung von Übergabeparametern. (OS = Windows XP)

Ein Programm benötigt beim Start einige Parameter, die mit Hilfe eine Batch auf Vorhandensein und Gültigkeit geprüft werden müssen.

MeineProgramm.exe -Parameter1 -Parameter2 -OptionalerParameter3

Werte der Parameter:

Parameter1: AUTO oder BUS oder ZUG -> Parametergruppe: Fahrzeug
Parameter2: BLOND oder ROTHAARIG -> Parametergruppe: Haarfarbe
OptionalerParameter3: ASSISTENTIN -> Opt. Parameter: Biber's Wunsch face-smile

Jeder Parameter kann/darf nur einen Wert haben, die Parameter 1 und 2 müssen gefüllt sein, der Parameter 3 ist optional.

Gültige Aufrufe wären:

MeinProgramm.exe -AUTO -ROTHAARIG -ASSISTENTIN
MeinProgramm.exe -BUS -BLOND
MeinProgramm.exe -ZUG -BLOND -ASSISTENTIN
. . .

Ungültige Aufrufe wären:
MeinProgramm.exe -AUTO -BUS -ASSISTENTIN
MeinProgramm.exe -ZUG -BLOND -ROTHAARIG
MeinProgramm.exe -BLOND -ROTHAARIG -ASSISTENTIN

Aufgabe

Die zu erstellende Batch soll verhindern, dass ungültige Parameter beim Aufruf der EXE verwendet werden, es sollen daher

auch vergessene Minuszeichen "-" erkannt werden
die Reihenfolge der angegebenen Parameter soll so sortiert werden, dass sie für die EXE gültig sind, z. B.:

StartMeinProgramm.cmd -BLOND -ASSISTENTIN -ZUG -> führt zu dem Aufruf der EXE: MeinProgramm.exe -ZUG -BLOND -ASSISTENTIN
StartMeinProgramm.cmd -ROTHAARIG -AUTO -> führt zu dem Aufruf der EXE: MeinProgramm.exe -AUTO -ROTHAARIG

die Anzahl der Parameter geprüft werden, da mehr als drei Parameter falsch sind
jeder Parameter höchstens einmal vorkommen
die ersten beiden Parameter müssen gefüllt sein

Erster Schritt: Ermittlung der Parameteranzahl

@echo off & setlocal enabledelayedexpansion
set /a mycount=0

rem Get the number of parameters
@for %%a in (%*) do (
	set /a mycount=!mycount! + 1
)
echo Number of Parameters: %mycount%

if [%mycount%] GTR [3] GOTO :COUNTERR

GOTO :END

:COUNTERR
Echo Too many parameters ...
GOTO :END

:END01.
@echo off & setlocal enabledelayedexpansion 
02.
set /a mycount=0 
03.
 
04.
rem Get the number of parameters 
05.
@for %%a in (%*) do ( 
06.
	set /a mycount=!mycount! + 1 
07.
) 
08.
echo Number of Parameters: %mycount% 
09.
 
10.
if [%mycount%] GTR [3] GOTO :COUNTERR 
11.
 
12.
GOTO :END 
13.
 
14.
:COUNTERR 
15.
Echo Too many parameters ... 
16.
GOTO :END 
17.
 
18.
:END

Zweiter Schritt: Prüfen, ob vor jedem Parameter auch ein Minus sitzt.

@echo off & setlocal enabledelayedexpansion
set /a mycount=0
set /a myminuscount=0

rem Get the number of parameters
@for %%a in (%*) do (
	set /a mycount=!mycount! + 1
	set minuscheck=%%a
	if ["!minuscheck:~0,1!"] == ["-"] set /a myminuscount=!myminuscount! + 1
)
echo Number of Parameters: %mycount%
echo Number of Minus: %myminuscount%


if [%mycount%] GTR [3] GOTO :COUNTERR
if [%myminuscount%] NEQ [%mycount%] GOTO :MINUSERR
goto :END

:COUNTERR
Echo Too many parameters ...
GOTO :END

:MINUSERR
Echo Forgotton Minus "-" ...
GOTO :END

:END01.
@echo off & setlocal enabledelayedexpansion 
02.
set /a mycount=0 
03.
set /a myminuscount=0 
04.
 
05.
rem Get the number of parameters 
06.
@for %%a in (%*) do ( 
07.
	set /a mycount=!mycount! + 1 
08.
	set minuscheck=%%a 
09.
	if ["!minuscheck:~0,1!"] == ["-"] set /a myminuscount=!myminuscount! + 1 
10.
) 
11.
echo Number of Parameters: %mycount% 
12.
echo Number of Minus: %myminuscount% 
13.
 
14.
 
15.
if [%mycount%] GTR [3] GOTO :COUNTERR 
16.
if [%myminuscount%] NEQ [%mycount%] GOTO :MINUSERR 
17.
goto :END 
18.
 
19.
:COUNTERR 
20.
Echo Too many parameters ... 
21.
GOTO :END 
22.
 
23.
:MINUSERR 
24.
Echo Forgotton Minus "-" ... 
25.
GOTO :END 
26.
 
27.
:END

Allerdings wird ein einzelnes Minus jetzt auch als Parameter gewertet und bringt ein positives Ergebnis:

StartMeinProgramm.cmd -ROTHAARIG -AUTO -

Number of Parameters: 3
Number of Minus: 301.
StartMeinProgramm.cmd -ROTHAARIG -AUTO - 
02.
 
03.
Number of Parameters: 3 
04.
Number of Minus: 3

Dies kann man verhindern, in dem man in der for-Schleife die If-Abfrage folgendermaßen anpasst:

	if ["!minuscheck:~0,1!"] == ["-"] (
		if not ["!minuscheck:~1,2!"] == [""] set /a myminuscount=!myminuscount! + 1)01.
	if ["!minuscheck:~0,1!"] == ["-"] ( 
02.
		if not ["!minuscheck:~1,2!"] == [""] set /a myminuscount=!myminuscount! + 1)

Danach erscheint dann die folgende Ausgabe:

StartMeinProgramm.cmd -ROTHAARIG -AUTO -

Number of Parameters: 3
Number of Minus: 2
Forgotton Minus "-" ...01.
StartMeinProgramm.cmd -ROTHAARIG -AUTO - 
02.
 
03.
Number of Parameters: 3 
04.
Number of Minus: 2 
05.
Forgotton Minus "-" ...

Dritter Schritt: Prüfen, ob für jeden der ersten beiden Parameter auch nur ein Wert gesetzt wurde.

A: Ist jede Gruppe in der Parameterliste vertreten?
B: Ist aus jeder Gruppe maximal ein Vertreter vorhanden?

Hinzufügen der folgenden Zeilen setzt jeweils einen Zähler hoch

set "FAHRZEUGE=AUTO BUS ZUG"
set "HAARFARBE=BLOND ROTHAARIG"
set "OPTIONAL=ASSISTENTIN"

set /a FAHRZEUGE_Count=0
set /a HAARFARBE_Count=0
...
for %%i in (%FAHRZEUGE%) do (
	for %%m in (%*) do (
		rem To compare the string, add the minus as first letter for %%i
		if /i "-%%i"=="%%m" (set /a FAHRZEUGE_Count=!FAHRZEUGE_Count! + 1)
	)
)
for %%i in (%HAARFARBE%) do (
	for %%m in (%*) do (
		rem To compare the string, add the minus as first letter for %%i
		echo m: %%m; i: %%i
		if /i "-%%i"=="%%m" (set /a HAARFARBE_Count=!HAARFARBE_Count! + 1)
	)
)
if %FAHRZEUGE_Count% LSS 1 (set msg=No parameter for Fahrzeuge & GOTO :PARAMCOUNTERR) 
if %HAARFARBE_Count% LSS 1 (set msg=No parameter for Haarfarbe & GOTO :PARAMCOUNTERR)
if %FAHRZEUGE_Count% GTR 1 (set msg=To many parameters for Fahrzeuge & GOTO :PARAMCOUNTERR) 
if %HAARFARBE_Count% GTR 1 (set msg=To many parameters for Haarfarbe & GOTO :PARAMCOUNTERR)
...
:PARAMCOUNTERR
ECHO %msg%
GOTO :END01.
set "FAHRZEUGE=AUTO BUS ZUG" 
02.
set "HAARFARBE=BLOND ROTHAARIG" 
03.
set "OPTIONAL=ASSISTENTIN" 
04.
 
05.
set /a FAHRZEUGE_Count=0 
06.
set /a HAARFARBE_Count=0 
07.
... 
08.
for %%i in (%FAHRZEUGE%) do ( 
09.
	for %%m in (%*) do ( 
10.
		rem To compare the string, add the minus as first letter for %%i 
11.
		if /i "-%%i"=="%%m" (set /a FAHRZEUGE_Count=!FAHRZEUGE_Count! + 1) 
12.
	) 
13.
) 
14.
for %%i in (%HAARFARBE%) do ( 
15.
	for %%m in (%*) do ( 
16.
		rem To compare the string, add the minus as first letter for %%i 
17.
		echo m: %%m; i: %%i 
18.
		if /i "-%%i"=="%%m" (set /a HAARFARBE_Count=!HAARFARBE_Count! + 1) 
19.
	) 
20.
) 
21.
if %FAHRZEUGE_Count% LSS 1 (set msg=No parameter for Fahrzeuge & GOTO :PARAMCOUNTERR)  
22.
if %HAARFARBE_Count% LSS 1 (set msg=No parameter for Haarfarbe & GOTO :PARAMCOUNTERR) 
23.
if %FAHRZEUGE_Count% GTR 1 (set msg=To many parameters for Fahrzeuge & GOTO :PARAMCOUNTERR)  
24.
if %HAARFARBE_Count% GTR 1 (set msg=To many parameters for Haarfarbe & GOTO :PARAMCOUNTERR) 
25.
... 
26.
:PARAMCOUNTERR 
27.
ECHO %msg% 
28.
GOTO :END

Jetzt sind zwar alle Anzahlen bestimmt und das Vorhandensein verifiziert, allerdings welche gültigen Werte eingegeben wurden ist noch nicht bekannt.

Durch Einfügen jeweils einer weiteren Zeile in der obigen If-Abfrage wird das dann auch gelöst:

...
		if /i "-%%i"=="%%m" (
			set /a FAHRZEUGE_Count=!FAHRZEUGE_Count! + 1
			set parmFahrzeug=%%m)
...
		if /i "-%%i"=="%%m" (
			set /a HAARFARBE_Count=!HAARFARBE_Count! + 1
			set parmHaarfarbe=%%m)
...
echo Fahrzeug: %parmFahrzeug%; Haarfarbe: %parmHaarfarbe%01.
... 
02.
		if /i "-%%i"=="%%m" ( 
03.
			set /a FAHRZEUGE_Count=!FAHRZEUGE_Count! + 1 
04.
			set parmFahrzeug=%%m) 
05.
... 
06.
		if /i "-%%i"=="%%m" ( 
07.
			set /a HAARFARBE_Count=!HAARFARBE_Count! + 1 
08.
			set parmHaarfarbe=%%m) 
09.
... 
10.
echo Fahrzeug: %parmFahrzeug%; Haarfarbe: %parmHaarfarbe%

Doch da war noch was, der optionale dritte Parameter...

for %%m in (%*) do (
	rem To compare the string, add the minus as first letter for %%i
	if /i "-%OPTIONAL%"=="%%m" (set parmOptional=%%m)
)
echo Fahrzeug: %parmFahrzeug%; Haarfarbe: %parmHaarfarbe%; Optional: %parmOptional%01.
for %%m in (%*) do ( 
02.
	rem To compare the string, add the minus as first letter for %%i 
03.
	if /i "-%OPTIONAL%"=="%%m" (set parmOptional=%%m) 
04.
) 
05.
echo Fahrzeug: %parmFahrzeug%; Haarfarbe: %parmHaarfarbe%; Optional: %parmOptional%

Vierter Schritt: Zusammenfügen der Kommandozeile.

start /wait MeinProgramm.exe %parmFahrzeug% %parmFahrzeug% %parmOptional%01.
start /wait MeinProgramm.exe %parmFahrzeug% %parmFahrzeug% %parmOptional%

Tja, eigentlich wollte ich ja eine Frage stellen, nun, so wie es aussieht, funktioniert es jetzt, aber es gibt sicherlich noch etwas Optimierungspotential...

mfg
Axel

Der vollständige Code:

@echo off & setlocal enabledelayedexpansion
set /a mycount=0
set /a myminuscount=0
set msg=

set "FAHRZEUGE=AUTO BUS ZUG"
set "HAARFARBE=BLOND ROTHAARIG"
set "OPTIONAL=ASSISTENTIN"

set /a FAHRZEUGE_Count=0
set /a HAARFARBE_Count=0

rem Get the number of parameters
for %%a in (%*) do (
	set /a mycount=!mycount! + 1
	set minuscheck=%%a
	if ["!minuscheck:~0,1!"] == ["-"] (
		if not ["!minuscheck:~1,2!"] == [""] set /a myminuscount=!myminuscount! + 1)
)
echo Number of Parameters: %mycount%
echo Number of Minus: %myminuscount%

if [%mycount%] GTR [3] GOTO :COUNTERR
if [%myminuscount%] NEQ [%mycount%] GOTO :MINUSERR

for %%i in (%FAHRZEUGE%) do (
	for %%m in (%*) do (
		rem To compare the string, add the minus as first letter for %%i
		if /i "-%%i"=="%%m" (
			set /a FAHRZEUGE_Count=!FAHRZEUGE_Count! + 1
			set parmFahrzeug=%%m)
	)
)
for %%i in (%HAARFARBE%) do (
	for %%m in (%*) do (
		rem To compare the string, add the minus as first letter for %%i
		if /i "-%%i"=="%%m" (
			set /a HAARFARBE_Count=!HAARFARBE_Count! + 1
			set parmHaarfarbe=%%m)
	)
)

if %FAHRZEUGE_Count% LSS 1 (set msg=No parameter for Fahrzeuge & GOTO :PARAMCOUNTERR) 
if %HAARFARBE_Count% LSS 1 (set msg=No parameter for Haarfarbe & GOTO :PARAMCOUNTERR)
if %FAHRZEUGE_Count% GTR 1 (set msg=To many parameters for Fahrzeuge & GOTO :PARAMCOUNTERR) 
if %HAARFARBE_Count% GTR 1 (set msg=To many parameters for Haarfarbe & GOTO :PARAMCOUNTERR)

for %%m in (%*) do (
	rem To compare the string, add the minus as first letter for %%i
	if /i "-%OPTIONAL%"=="%%m" (set parmOptional=%%m)
)

echo Fahrzeug: %parmFahrzeug%; Haarfarbe: %parmHaarfarbe%; Optional: %parmOptional%
GOTO :END

:COUNTERR
Echo Too many parameters ...
GOTO :END

:MINUSERR
Echo Forgotton Minus "-" ...
GOTO :END

:PARAMCOUNTERR
ECHO %msg%
GOTO :END

:END01.
@echo off & setlocal enabledelayedexpansion 
02.
set /a mycount=0 
03.
set /a myminuscount=0 
04.
set msg= 
05.
 
06.
set "FAHRZEUGE=AUTO BUS ZUG" 
07.
set "HAARFARBE=BLOND ROTHAARIG" 
08.
set "OPTIONAL=ASSISTENTIN" 
09.
 
10.
set /a FAHRZEUGE_Count=0 
11.
set /a HAARFARBE_Count=0 
12.
 
13.
rem Get the number of parameters 
14.
for %%a in (%*) do ( 
15.
	set /a mycount=!mycount! + 1 
16.
	set minuscheck=%%a 
17.
	if ["!minuscheck:~0,1!"] == ["-"] ( 
18.
		if not ["!minuscheck:~1,2!"] == [""] set /a myminuscount=!myminuscount! + 1) 
19.
) 
20.
echo Number of Parameters: %mycount% 
21.
echo Number of Minus: %myminuscount% 
22.
 
23.
if [%mycount%] GTR [3] GOTO :COUNTERR 
24.
if [%myminuscount%] NEQ [%mycount%] GOTO :MINUSERR 
25.
 
26.
for %%i in (%FAHRZEUGE%) do ( 
27.
	for %%m in (%*) do ( 
28.
		rem To compare the string, add the minus as first letter for %%i 
29.
		if /i "-%%i"=="%%m" ( 
30.
			set /a FAHRZEUGE_Count=!FAHRZEUGE_Count! + 1 
31.
			set parmFahrzeug=%%m) 
32.
	) 
33.
) 
34.
for %%i in (%HAARFARBE%) do ( 
35.
	for %%m in (%*) do ( 
36.
		rem To compare the string, add the minus as first letter for %%i 
37.
		if /i "-%%i"=="%%m" ( 
38.
			set /a HAARFARBE_Count=!HAARFARBE_Count! + 1 
39.
			set parmHaarfarbe=%%m) 
40.
	) 
41.
) 
42.
 
43.
if %FAHRZEUGE_Count% LSS 1 (set msg=No parameter for Fahrzeuge & GOTO :PARAMCOUNTERR)  
44.
if %HAARFARBE_Count% LSS 1 (set msg=No parameter for Haarfarbe & GOTO :PARAMCOUNTERR) 
45.
if %FAHRZEUGE_Count% GTR 1 (set msg=To many parameters for Fahrzeuge & GOTO :PARAMCOUNTERR)  
46.
if %HAARFARBE_Count% GTR 1 (set msg=To many parameters for Haarfarbe & GOTO :PARAMCOUNTERR) 
47.
 
48.
for %%m in (%*) do ( 
49.
	rem To compare the string, add the minus as first letter for %%i 
50.
	if /i "-%OPTIONAL%"=="%%m" (set parmOptional=%%m) 
51.
) 
52.
 
53.
echo Fahrzeug: %parmFahrzeug%; Haarfarbe: %parmHaarfarbe%; Optional: %parmOptional% 
54.
GOTO :END 
55.
 
56.
:COUNTERR 
57.
Echo Too many parameters ... 
58.
GOTO :END 
59.
 
60.
:MINUSERR 
61.
Echo Forgotton Minus "-" ... 
62.
GOTO :END 
63.
 
64.
:PARAMCOUNTERR 
65.
ECHO %msg% 
66.
GOTO :END 
67.
 
68.
:END

Diskussionsverlauf (5 Antworten)

bastla schreibt am 07.01.2009 um 15:12:17 Uhr
- ahe schreibt am 07.01.2009 um 15:26:10 Uhr
Biber schreibt am 07.01.2009 um 16:13:35 Uhr
- ahe schreibt am 07.01.2009 um 16:19:21 Uhr
- bastla schreibt am 07.01.2009 um 17:02:21 Uhr

Top

bastla schreibt am 07.01.2009 um 15:12:17 Uhr

Hallo ahe!

Hab' zwar nur kurz drübergeschaut - sieht aber für mich sehr gut aus ... face-smile

2 Kleinigkeiten:
- Falls die Varaiable %allparameters% überhaupt benötigt wird, sollte als Ersatz der Zeilen 27 und 28

set "allparameters=%*"

genügen.

- Ich tendiere eher zur Schreibweise

set /a mycount+=1

erspart - zumindest dafür - die "delayedExpansion", ist hier aber eher Geschmackssache.

Grüße
bastla

Top

ahe schreibt am 07.01.2009 um 15:26:10 Uhr

Hallo bastla,

"allparameters" wird tatsächlich nicht gebraucht, war beim Entstehen wichtig, doch dann nicht mehr... (ist oben jetzt gelöscht!)

Nun die kurze Schreibweise des Hochzählens kam mir dann auch später in den Sinn, nur hatte ich es da bereits geschrieben... face-smile

mfg
Axel

Top

Biber schreibt am 07.01.2009 um 16:13:35 Uhr

Moin ahe,

also hömma - Du kannst Doch hier nicht einfach ein Tutorial als normalen Beitrag ins Forum stellen. face-wink

Ich habe es für Dich mal umgestuft von "Beitrag" auf "Anleitung".

Heute morgen habe ich in einem anderen Beitrag ein Negativ-Beispiel für unleserlichen, unwartbaren und nicht nachvollziehbaren Code angemeckert.
Nun möchte nun auch das Lob für einen sauber hergeleiteten Skriptschnipsel nicht unter den Tisch falllen lassen..

Vielen Dank für Deine Mühe und Sorgfalt
Biber

Top

ahe schreibt am 07.01.2009 um 16:19:21 Uhr

Danke für die Blumen,

nachdem ich meine erste, nicht funktionierende Version hatte und nicht mehr durchblickte, habe ich mir erst einmal aufgeschrieben, was ich machen wollte und so ergab sich das Ganze fast von selbst. Außerdem habe ich dabei auch an Dich gedacht face-smile

(s. a. der optionale Parameter...)

mfg
Axel

Top

bastla schreibt am 07.01.2009 um 17:02:21 Uhr

@Biber

also hömma - Du kannst Doch hier nicht einfach ein Tutorial als normalen Beitrag ins Forum stellen. face-wink

Annähernd

so hatte ich es auch schon in meinem obigen Kommentar formuliert, mir aber dann gedacht: "Das ist Chefsache." und den Teil wieder rausgeschmissen ...

Grüße
bastla

mehr ...Ähnliche Beiträge