rem der Code funktioniert und während der Laufzei kommt viel "unnützer" Text, also darf das @echo off hier gerne stehen 

@echo off 

rem um alle Rechner in seinem Subnetz zu finden, sollte man mal das "Netz" suchen - das Gateway wäre da doch ein Ansatzpunkt 

rem anstatt - wie beim "alten" Script das Netzwerk als Variable zu nehmen, lassen wir das den Rechner rausfinden 

rem es gibt ja auch inaktive NICs, die "erkennt" man aber beim Ipconfig 

rem und zwar "so" (endlich mal "Quelltext") 

for /f "tokens=2 delims=:" %%a in ('"ipconfig|find "gateway""') do (for /f "tokens=1,2,3 delims=." %%b in ("%%a") do if not "%%b"==" " call :netz %%b.%%c.%%d.) 

rem verstanden, was die zwei Schleifchen, die sogar verschachtelt sind - machen - nein - dann ein rem vors @echo off schreiben und for das goto end eine Pause  ;-) 

goto end 

rem ein Class C Netzwerk hat ja 254 nutzbare Adressen, und mit dem Gateway kennen wir ja die ersten 3 oktette 

rem und mit einer simplen Schleife hängen wir alle 254 Adressen als letztes Oktett an die vorher gefundenen ersten 3 Oktette dran. 

rem Und weil 254 sekunden und ein paar zerquetschte ganz schön lang werden können, mit einer "Fortschrittsanzeige im Fenstertitel"   

:netz 

for /l %%i IN (1,1,254) DO (title %1%%i && call :host %1%%i) 

goto:eof 

:host 

rem der Horst hat ja auch einen Namen, nur welchen? 

for /f "tokens=2 delims= " %%A in ('ping -a %1 -n 1 ^| FIND "[%1]"') DO ECHO.%%A;%1>>mein_netz.log 

goto:eof 

:end

rem dieser Ansatz ist eigentlich viel kürzer, denn das sind nur zwei Schleifen. 

rem natürlich hat der aber auch wieder einen Haken, man findet so nur die Rechner, die in der Domain angemeldet sind - keine Drucker / Swutche usw. 

rem aber weil die (noch) nicht verschachtelt sind mit einer "temporären" log Datei "aktive_systeme.log" die am Ende gelöscht wird 

rem erstmal per Net view alle Systeme in eine Liste packen 

rem besonderheit bei der Ausgabe von Net view - ist ja - der Rechnername steht hinter zwei \ (daher delims=\) 

rem gefolgt von einer evtuellen Beschreibung - daher (delims=\ ) und das "Tokens=1,2" 

rem die ersten drei Zeilen sind überschriften im großen Netz nur z.B durch ein Net view|more ersichtlich. 

rem daher skip 3 

rem und auch hier - das dauert und man will sehen, wo er gerade ist - daher ein Title in der Schleife  

:script_start 

@echo off 

for /f "skip=3 tokens=1,2 delims=\ " %%a in ('"net view"') do ( 

title %%a 

ping %%a -n 1 |find "[">>aktive_systeme.log 

) 

rem jetzt die eben erstellte Liste um die "nutzlosen" Spalten bereinigen den Computername und dessen IP als CSV ausgeben  

for /f "tokens=2,3 delims=[] " %%a in (aktive_systeme.log) do echo %%a,%%b>>mein_netz.csv 

rem die temoräre log Datei löschen 

del aktive_systeme.log

for /f "tokens=2 delims=[]" %%a in ('"ping %computername% -n 1|find "[""') do echo %%a

nbtstat -a Rechnername |find "MAC Adress" 

rem bzw. 

nbtstat -A IP.A.dre.sse |find "MAC Adress" 

rem und wie das dann "schön" für alle Systeme und sortiert in einer Liste landet -siehe oben