NumberMe Nummerieren, Denummerieren, Leerzeilen entfernen, Zeilen zählen,Trennzeichen(satz)auswahl ... die Aktuellste mit Beschreibung.

027. :: if infile contains ASCII 172 then exit with errorlevel 3 

028. findstr ¬ %1 >nul && ( 

029.   >&2 echo/Error: Input file cannot be reliably numbered/de-numbered 

030.   >&2 echo/by this script because it contains ASCII character 172. 

031.   con:: 2>nul & goto :EOF 

032. )

@echo off & setlocal 

::NumberMe.bat Version 1.2 ... put line numbers into Files or delete Numering if found  

::Version 0.03 Placed into the Public Domain by Biber3@hotmail.de 15.08.2004, 

::modified to Version 1.0 - 1.2 by pieh-ejdsch 13.-17.06.2009, thanks to bastla 

::last Versions 0.03; 1.0 thanks to bastla; 1.0b; 1.1 

::supportet by www.administrator.de; changes: removed delayedexpansion (+!); 

::[/?] add Help; [/n:1] (1 Means: number have onedigit)add Automated PreZeroNumbering (1-7;0001-4702); 

::[/n:0] add setting for without PreZero; [/n:-] add delete Numbering if found it; 

::(without[/n:]) Auto Nubering with less than twodigits; (with[/n:]) add setting for withoutNumbering; 

::add Spaces for Path- and Files-name or additional characters between quotation marks; 

:: without target-path-filename only output on Screen; 

::additional characters only displayed  false on Screen;  

::no Support for brackets in targetPathnames and targetFilenames, but Support in source path/file-names 

if "%~1"=="" echo            Syntaxfehler! Bitte Quelldateinamen angeben! & set b=1 & goto :help 

if "%~1"=="/?"  goto :help 

set umbenamsen= 

echo "%~2" | find "(" 1>nul 

if not %errorlevel% == 1 set umbenamsen=1 

echo "%~2" | find ")" 1>nul 

if not %errorlevel% == 1 set umbenamsen=1 

if defined umbenamsen echo. & echo Fehler! ^( ^) in ZielPfad/Dateiname! ZielPfad wechseln oder ZielDatei umbenennen! & exit /b 3 

goto :next 

:help 

echo Listet Dateien ^(mit Nummerierung^) zeilenweise ohne Leerzeilen auf den 

echo Bildschirm oder in eine Datei. Oder Entfernt die Nummerierung. & echo. 

echo %~n0 ["][Pfad]Quelldatei["] [["][Pfad]Zieldatei["]] [/n:[Nummerierung]] & echo. 

echo Wenn Quelldatei, Zieldatei und Pfad gleich werden in Quelldatei alle Leerzeilen 

echo entfernt. In Quelldatei wird NUR bei Eingabe von [/n:[Nummerierung]] Nummeriert. 

echo  Quelldatei        Wird immer benoetigt. 

echo  Zieldatei         Wird die Zieldatei nicht angegeben wird der Inhalt auf dem 

echo                    Bildschirm ausgegeben. Existiert diese wird sie geleoscht. 

echo  " "               Vollstaendige Unterstuetzung von Umgebenden Anfuehrungs- 

echo                    zeichen bei Leerzeichen im Pfad und Dateimanen. 

echo  /n:               Gibt die Art der Nummerierung an. 

echo                    Wird die Art nicht Angegeben erfolgt die Nummerierung mit 

echo                    Automatischen Vornullen und Mindestens zweistellig. 

echo     Nummerierung   Wird Nummerierung NICHT angegeben wird NICHT Nummeriert! & echo. 

echo     -              Wird eine Nummerierung gefunden wird diese Entfernt. 

echo     0              Es wird ohne Vornullen Numeriert. 

echo     1              Ab der Zahl 1 wird Automatisch mit sovielen Vornullen 

echo                    Nummeriert wie noetig sind. Ansonsten gibt Diese Zahl die 

echo                    Stellenanzahl inklusive Vornullen an mit wecher 

echo                    Mindestens Nummeriert wird. 

echo Besonderheiten: Sonderzeichen werden nur auf dem Bildschirm falsch ausgegeben! 

echo                 Klammern im ZielDateinamen und Pfad werden nicht unterstuetzt! 

if defined b (exit /b 1) else goto :eof 

:next 

if not exist "%~1" (echo. & echo Fehler! Quelldatei "%~1" nicht gefunden! & exit /b 2) else (set yes=0 & set "orig=" & set "pN=" & set "vpn=") 

for %%i in ( "con:" "/n:2" "%~2" "%3") do if not %%i == "" call :setting "%%~i" 

if "%pOut%%put%" == "%~f1" set orig=%random% 

if defined orig (if %yes% equ 1 (echo. & echo    Leerzeilen in "%~nx1" werden enfernt! & set pN=N) else (if %pN% == D (echo. & echo    Nummerierung wird aus "%~nx1" enfernt!) else (echo. & echo    "%~nx1" wird Nummeriert!))) 

if not ["%pOut%%orig%%put%"]==["con:"] if exist "%pOut%%orig%%put%" del "%pOut%%orig%%put%" 

if %pN% == N ((For /F "usebackq delims=" %%i in ("%~1") do echo %%i>>"%pOut%%orig%%put%") & goto :end) else ((if exist %temp%\tmp del %temp%\tmp) && for /f "usebackq delims=" %%i in ("%~1") do (set /a LL + = 1 & @echo %%i>>%temp%\tmp)) 

::,for /f  "usebackq" %%i in ("%~1") do set /a LL + = 1 

if "%LL%" == "" ( echo. & echo             Datei ist leer! & exit /b 4) else set NL=9 

if %pN% == D (set "D=1" & set "NN=0" & goto :noZero) else if %pN% lss 1 (set "NN=0" & goto :noZero) else set "NN=1" 

:testZero 

if %NL% lss %LL% (set "NL=%NL%9" & set /a NN + = 1 & goto :testZero) 

if %NN% gtr %pN% (set pN=%NN%) else set NN=%pN% 

set NL=9 

:withZero 

if not %pN% == 1 (set "vpn=%vpN%0" & set /a pN - = 1 & goto :withZero) 

:noZero 

set /a pN = 0 

:read 

if defined nodel (echo  "%~nx1" enthaelt keine Nummerierung! & goto :eof) 

if defined D (if %pN% == %LL% (if not defined delNR (set "delNR=1" & goto :noZero) else goto :end) else (set /a pN + = 1 , N = 0)) else if %pN% == %LL% (goto :end) else (set /a pN + = 1 , N = 0) 

set /a N + = 1 & set /a FN = %pN% & call :setline %pN% 

if %NN% gtr 0 if %NL% == %pN% (set "NL=%NL%9" & set /a NN - = 1 & set "vpN=%vpN:~1%") 

goto :read 

:setline 

if 1 == %1 goto :write 

set /a skip = %1 - 1 

set skip=Skip=%skip% 

:write 

if defined D (if not defined delNR (for /f "%skip% delims=0 " %%i in (%temp%\tmp) do (if not "%%i" == "%FN:0=%" set nodel=1) & goto :eof) else (for /f "%skip% tokens=1,* " %%i in (%temp%\tmp) do echo %%j>>"%pOut%%orig%%put%" & goto :eof)) 

for /f "%skip% delims=" %%i in (%temp%\tmp) do echo %vpN%%pN% %%i>>"%pOut%%orig%%put%" & goto :eof 

:setting 

set pX=%~1 

if /i "%pX:~0,3%"=="/n:" (set /a yes + = 1 & (if "%pX:~3%" == "-" (set "pN=D") else (if "%pX:~3%" gtr "0" (set /a pN = %pX:~3%) else (if "%pX:~3%" == "0" (set "pN=0") else set "pN=N")))) else if not defined pOut (set "pOut=%~1") else goto :setOtPt 

goto :eof 

:setOtPt 

set "pOut=%~dp1" 

set "put=%~nx1" 

goto :eof 

:end 

if not defined orig goto :noren 

del "%~f1" /f /q 

ren "%pOut%%orig%%put%" "%~nx1" 

:noren 

echo. & echo            Fertig! & if exist %temp%\tmp del %temp%\tmp 

goto :eof

:: -------------------schnipp------NumberMe.bat------------ 

::: ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 

::: #NumberMe.bat Version 1.3 .. put line numbers into Files or delete Numbering if 

::: #found and/only delete all emty lines!; help and progress of batch in german; 

::: #[/?en] english short guide, bevor code in batch one line behind :: [/?] Help ; 

::: #Version 0.03 Placed into the Public Domain by Biber3@hotmail.de 15.08.2004,  

::: #modified to Version 1.0 - 1.3 by pieh-ejdsch@o2online.de 13.06.-30.08.2009, 

::: #last Versions: 0.03, 1.0, 1.0b thanks to bastla, 1.1, 1.2; 

::: #supportet by www.administrator.de ; Bugs or Updates? Please feedback! 

::: #---For install on Win System: press [WIN]+[R] , then type: %windir%\system32 

::: #---press Enter and put in this File to ExplorerWindow which has opened up 

::: #---now this Application works in Batch; CMD or [WIN]+[R] by typing this 

::: #---BatchName(.cmd) with or without Extension.--------------------------------- 

::: #for next Update projected: if you substitute [/N:] by [/L:] NumberMe will 

::: #not be delete all empty lines, syntax behind dubble dot takes 

::: #effekt like than [/N:]; 

::: #------------------------------------------------------------------------------ 

::: Suorcefilename must be the first Option. All other Options from second till 

::: sixth can be in much differrent array. 

::: [changes:] removed delayedexpansion for exclamation point;  

::: [/?] Help german only, but here is an english short guide for you; 

::: sourcefilename for working batch always be needed, without target-path-filename only output on Screen; 

::: [/n:1] one-figure numbering with Automated PreZeroNumbering (1-7, 0001-4702) 

::: (for example: [/n:5] not less than five-figure numbering-> 00001-00120); 

::: [/n:0] setting for without PreZero (1-245); 

::: [/n:-] deletes a numbered consecutively if found it or is it used to test for   -> gives exitcode 5; 

::: without [/n:] Auto PreZeroNumbering with not less than two-figure number just   like [/n:2]; 

::: -with [/n:] setting for without Numbering; 

::: [/Z:] change delimiter: space by point; or behind : Input other Delimiter(s) 

::: to include Spaces or additional characters after delimiter ->Syntax must insert 

::: between quotation marks for denumbering and incluce string to remove for, 

::: ->be sure in string the last sign exists once; 

::: [/Q] Quit modus: no Program message; been related works with E  

::: [/E] Quit modus: no Error message; been related works with Q 

::: > Spaces for Path- and Files-name or additional characters must insert between  quotation marks; 

::: > if source(path)name is equal to target(path)name NumberMe will be effect all  in sourcefile; 

::: > additional characters only displayed  false on Screen;  

::: > no Support for brackets in targetPathnames and targetFilenames but Support    in source path/file-names; 

::: output from sourcefile: number of all Lines and all empty Lines; 

::: exitcodes: [0] successful; [1] put in filename; [2] sourcefile not found; 

::: [3] bracket in targetname not allowed; [4] file is empty or empty lines only; 

::: [5] file is not numbered consecutively; [6] input incorrect Syntax; 

::: [7] file is without empty lines only 

::; ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 

@echo off & setlocal 

set "b=" &  set "E=" & set "Q=" & set "noempty=0" & set Full=0 & set umbenamsen= 

for %%i in ("" "\" "." ".." "..." "....") do if "%~1"=="%%~i" (echo Syntaxfehler! Bitte Quelldateinamen angeben! & set b=1 & goto :help ) 

for %%i in ("/" "/help" ) do if /i "%~1"=="%%~i" goto :help 

if "%~1"=="/?" goto :help 

if "%~1"=="/?en" for /f "usebackq tokens=1,*" %%i in ("%~f0") do if "%%i" == "::;" (echo %%j& exit /b 0) else if "%%i" == ":::" echo %%j 

if not exist "%~1" set b2=1 & goto :end 

for /f "delims=:" %%i in ('findstr /n .* "%~1"') do set /a Full + = 1 

for /f "usebackq" %%i in ("%~1") do set /a noempty + = 1 

::Klammerpruefung 

echo "%~2" | findstr "( )" 1>nul&&set umbenamsen=1 

echo "%~3" | findstr "( )" 1>nul&&set umbenamsen=1 

echo "%~4" | findstr "( )" 1>nul&&set umbenamsen=1 

echo "%~5" | findstr "( )" 1>nul&&set umbenamsen=1 

echo "%~6" | findstr "( )" 1>nul&&set umbenamsen=1 

if defined umbenamsen goto :bracket 

goto :next 

:help 

if defined b (echo. & echo gueltige Syntax:  %E% & goto :syntax) 

echo Listet Dateien ^(mit Nummerierung^) zeilenweise ohne Leerzeilen auf den 

echo Bildschirm oder in eine Datei. Oder Entfernt die Nummerierung. 

:syntax 

echo. & echo %~n0 ["][Pfad\]Quelldatei["] [["][Pfad\]Zieldatei["]] [/N:[WERT]] 

echo [/Q] [/E] [["]/Z:[Zeichen]["]]    [/?]  [/?en] credits and english short guide & if defined b exit /b 1 

echo.&echo Quelldatei muss erste Option sein sonst ist die Reihenfolge egal.   

echo  Zieldatei    Wird die Zieldatei nicht angegeben wird der Inhalt auf dem 

echo               Bildschirm ausgegeben. Wird ueberschrieben. Nicht Erlaubt: ^) ^( 

echo  " "          Vollstaendige Unterstuetzung von Umgebenden Anfuehrungszeichen  

echo               bei Leer- ^& Sonderzeichen im Pfad und Dateinamen.&echo. 

echo OHNE AusgabeART wird OHNE Leerzeilen mit Vornullen und Minimum Zweistellig  

echo Numeriert ^= [/l:2]. Wenn Quelldatei, Zieldatei und Pfad gleich: Werden in 

echo der Quelldatei OHNE AusgabeART NUR Leerzeilen entfernt. Sonst wie Syntax.&echo. 

echo   N:          Gibt die AusgabeART an.         OHNE      Leerzeilen! 

echo     WERT      Wird WERT NICHT angegeben wird NICHT Nummeriert! 

echo     -         Eine gefundene Durchgehende Nummerierung wird Entfernt und 

echo               gibt exitcode 5 wenn Durchgehende Nummerierung fehlt. 

echo     0         Es wird ohne Vornullen Nummeriert. 

echo     1         Ab der Zahl 1 wird Automatisch Vorgenullt (1-7, 0001-4702) 

echo               Mindestens Stellenanzahl inklusive Vornullen (3^= 001-054)&echo. 

echo   Z:          Leerzeichen hinter Nummerrierung wird zum Punkt oder wie Zeichen. 

echo     Zeichen   Angabe von ein oder mehr Trennzeichen zur de- oder Nummerierung.&echo. 

echo      Achtung! Fuer Enthaltene Leer-/Sonderzeichen Syntax mit / in " " setzen! 

echo               Bei Denummerierung gibt das erste Zeichen das Trennzeichen hinter 

echo               der Nummerrierung an, das zweite bzw letzte bis wohin gelöscht 

echo               wird -^> das letzte Zeichen NICHT doppelt verwenden!&echo. 

echo   Q           Meldungen werden NICHT Ausgegeben - Hilfe wird immer angezeigt! 

echo   E           Errormeldungen werden NICHT Ausgegeben. ODER 

echo   QE oder EQ  Unterdrueckung aller Meldungen in einer Option! 

echo Sonderzeichen: Im Dateiname -^> setze "" !; Falsche Ausgabe Nur auf Bildschirm! 

echo Die Anzahl Zeilen und Anzahl Leerzeilen der Quelldatei werden ausgegeben! 

:bracket 

echo   Klammern:      Werden im ZielDateinamen und Pfad nicht unterstuetzt! %E% 

if defined umbenamsen goto :end 

exit /b 0 

:next 

for %%i in ( "yes=0" "orig=" "pN=" "vpn=" "testprezero= " "Zeichen= " "noemptyLines=") do set %%i 

::Syntaxpruefung: Zieldatei De- oder Nummerierung 

for %%i in ( "con:" "/n:2" "%~2" "%~3" "%~4" "%~5" "%~6") do if not %%i == "" call :setting "%%~i" 

::ist Quelle gleich Ziel? gleich Numberme? 

if "%pOut%%put%" == "%~f0" set "orig=" & set "pOut=con:" & set "put=" 

if "%pOut%%put%" == "%~f1" set orig=%random% 

::Statusmeldung für Vorgang 

if defined orig ( 

	if %yes% equ 1 ( 

		if "%noempty%" lss "%Full%" ( 

			echo. %Q% 

			echo    Leerzeilen in "%~nx1" werden enfernt! %Q% 

			set pN=N 

		) else set noemptyLines=1 & goto :end 

	) else ( 

		if %pN% == D ( 

			echo. %Q% 

			echo    Nummerierung wird aus "%~nx1" enfernt! %Q% 

		) else ( 

			if not %pN% == N ( 

				echo. %Q% 

				echo    "%~nx1" wird Nummeriert! %Q% 

			) else ( 

				if "%noempty%" lss "%Full%" ( 

					echo. %Q% 

					echo    Leerzeilen in "%~nx1" werden enfernt! %Q% 

					set pN=N 

				) else set noemptyLines=1 & goto :end 

			) 

		) 

	) 

) 

::Loesche vorhandene Zieldatei 

if not ["%pOut%%orig%%put%"]==["con:"] if exist "%pOut%%orig%%put%" del "%pOut%%orig%%put%" 

::Erstelle extraDatei/Output fuer Leerzeilenentfernung oder Tempdatei für De- oder Nummerierung und Zaehle Zeilen 

if %pN% == N ( 

	For /F "usebackq delims=" %%i in ("%~1") do ( 

		echo.%%i>>"%pOut%%orig%%put%" 

		set /a LL + = 1 

	) 

	goto :end 

) else ( 

	(if exist %temp%\tmp del %temp%\tmp) && for /f "usebackq delims=" %%i in ("%~1") do ( 

		set /a LL + = 1 

		echo.%%i>>"%temp%\tmp" 

	) 

) 

set NL=9 

::mit oder ohne Vornull? 

if %pN% == D ( 

	set "D=1" 

	set "NN=0" 

	goto :noZero 

) else if %pN% lss 1 ( 

	set "NN=0" 

	goto :noZero 

) else set "NN=1" 

::Zaehlen der Automatischen oder Manuellen Vornullen 

:testZero 

if %NL% lss %LL% ( 

	set "NL=%NL%9" 

	set /a NN + = 1 

	goto :testZero 

) 

if %NN% gtr %pN% (set pN=%NN%) else set NN=%pN% 

set NL=9 

::Vornullen setzten  

:withZero 

if not %pN% == 1 ( 

	set "vpn=%vpN%0" 

	set /a pN - = 1 

	goto :withZero 

) 

::Spungziel bei keinen Vornullen oder nach Pruefung auf Nummerierung 

:noZero 

set /a pN = 0 

::Blockanfang De- oder Nummerierung  

:read 

::Keine Nummerierung gefunden? 

if defined nodel  goto :end 

::Schalter fuer Pruefung auf vorhandene Nummerierung oder Sprung zum Ende oder Einstellung Ziffernbreite 

if defined D ( 

	if %pN% == %LL% ( 

		if not defined delNR ( 

			set "delNR=1" 

			goto :noZero 

		) else goto :end 

	) else ( 

		set /a pN + = 1 , N = 0 

	) 

) else if %pN% == %LL% (goto :end) else set /a pN + = 1 , N = 0 

::Zaehler fuer Zeile und VorNullen Einstellung und Ruf Zeilenwahl 

set /a N + = 1 & set /a FN = %pN% & call :setline %pN% 

if %NN% gtr 0 if %NL% == %pN% ( 

	set "NL=%NL%9" 

	set /a NN - = 1 

	set "vpN=%vpN:~1%" 

) 

goto :read 

::Zeilenauswahl zum Ueberspung 

:setline 

if 1 == %1 set "skip=" & goto :write 

set /a skip = %1 - 1 

set skip=Skip=%skip% 

:write 

::Test auf oder Entfernung einer Vorhandenen Nummerierung  

if defined D ( 

	if not defined delNR ( 

		for /f "%skip% tokens=1,* delims=%Zeichen:~0,1%" %%i in (%temp%\tmp) do ( 

			if not "%%i" == "%FN%" ( 

				set "testprezero=%%i" 

				call :prezero 

			) 

			goto :eof 

		) 

	) else for /f "%skip% tokens=1,* delims=%Zeichen:~-1%" %%i in (%temp%\tmp) do ( 

		echo.%%j>>"%pOut%%orig%%put%" 

		goto :eof 

	) 

) 

::Schreibe: (Vornull)Nummer Trenner und Zeile 

for /f "%skip% delims=" %%i in (%temp%\tmp) do ( 

	echo.%vpN%%pN%%Zeichen%%%i>>"%pOut%%orig%%put%" 

	goto :eof 

) 

::Sprungziel Teste auf Vornullen zum Denummerieren 

:prezero 

if "%testprezero:~ 0, 1%" == "0" set "testprezero=%testprezero:~ 1%" & goto :prezero 

if not "%testprezero%" == "%FN%" set nodel=1 

goto :eof 

::Sprungziel Syntaxeinstellungen 

:setting 

set "pX=%~1" 

if /i "%pX:~0,3%" == "/z:" ( 

	if "%pX:~3%" == "" (set "Zeichen=.") else set "Zeichen=%pX:~3%" 

) else if /i "%pX%"=="/e" (set "E=>nul") else if /i "%pX%" == "/q" (set "Q=>nul") else if /i "%pX%" == "/eq" (set "E=>nul" & set "Q=>nul") else if /i "%pX%" == "/qe" (set "E=>nul" & set "Q=>nul") else if /i "%pX:~0,3%" == "/n:" ( 

	set /a yes + = 1 

	if "%pX:~3%" == "-" (set "pN=D") else ( 

		if "%pX:~3%" gtr "0" (set /a pN = %pX:~3%) else ( 

			if "%pX:~3%" == "0" (set "pN=0") else set "pN=N" 

		) 

	) 

) else if not "%pX:~0,1%" == "/" ( 

	if not defined pOut (set "pOut=%~1") else ( 

		set "pOut=%~dp1" 

		set "put=%~nx1" 

		if "%~n1" == "" (set "pout=con:" & set "put=") 

	) 

) else set "erropt=%pX:~1%" 

goto :eof 

:end 

if defined b2 ( 

	echo Fehler! Quelldatei "%~1" nicht gefunden! %E% 

	exit /b 2 

) 

if defined nodel echo "%~nx1" enthaelt keine Nummerierung! %E% 

if defined noemptyLines echo "%~nx1" enthaelt keine Leerzeilen %Q% 

if %noempty% equ 0 echo "%~nx1" ist leer! %E% 

if defined erropt echo ungueltige Option %erropt% %E% 

if not defined orig goto :noren 

if defined noemptyLines goto :noren 

if defined nodel goto :noren  

move /y "%pOut%%orig%%put%" "%~1" 

:noren 

set /a Lempty = Full - noempty 

echo AnzahlZeilen %Full% AnzahlLeerzeilen %Lempty% %Q% 

if exist %temp%\tmp del %temp%\tmp 

if defined umbenamsen exit /b 3 

if defined erropt exit /b 6 

if %noempty% equ 0 exit /b 4 

if defined noemptyLines exit /b 7 

if defined nodel exit /b 5 

exit /b 0 

:: -------------------schnapp------NumberMe.bat------------

:: -------------------schnipp------NumberMe.bat------------ 

::: ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 

::: #NumberMe.bat Version 1.4 .. put line numbers into Files or delete Numbering if 

::: #found or/and/only delete all emty lines; help and progress of batch in german; 

::: #[/?en] english short guide, bevor code in batch 1 line behind ::: [/?] Help ; 

::: #Version 0.03 Placed into the Public Domain by Biber3@hotmail.de 15.08.2004; 

::: #modified to Version 1.0 - 1.4 by pieh-ejdsch@o2online.de 13.06.-15.09.2009, 

::: #last Versions: 0.03, 1.0, 1.0b thanks to bastla, 1.1, 1.2, 1.3; 

::: #supportet by www.administrator.de ; Bugs or Updates? Please feedback! 

::: #---Put in this code to Editor, save as "all-filetype" named NumberMe.cmd 

::: #---For install on Win System: press [WIN]+[R] , then type: %windir%\system32 

::: #---press Enter and put in this File to ExplorerWindow which has opened up 

::: #---now this Application works in Batch; CMD or [WIN]+[R] by typing this 

::: #---BatchName(.cmd) with or without Extension.--------------------------------- 

::: #------------------------------------------------------------------------------ 

::: Suorcefilename must be the first Option. All other Options from second till 

::: sixth can be in much differrent array. Dubbel dot in Options can be lost. 

::: Options include no space to string together as /N-/Q/Z  -or Seperately or other 

::: [/?] Help german only, but here is an english short guide for You; 

::: sourcefilename for working batch always be needed, without target-path-filename only output on Screen; 

::: [/n:1] one-figure numbering with Automated PreZeroNumbering (1-7, 0001-4702) 

::: (for example: [/n:5] not less than five-figure numbering-> 00001-00120); 

::: [/n:0] setting for without PreZero (1-245); 

::: [/n:-] deletes a numbered consecutively before space or Piont if found it 

::: - or is it used to test for -> gives exitcode 5; 

::: without [/n:] Auto PreZeroNumbering with not less than two-figure number just   like [/n:2]; 

::: - only with [/n:] setting for without Numbering; 

::: if you substitute [/N:] by [/L:] NumberMe will not be delete all empty lines, 

::: syntax (behind dubble dot) takes effekt like than [/N:];  

::: [/l:-] only works like than [/n:-]; !!!! in Option L dubbeldots at Beginn be lost; 

::: [/Z:] change delimiter: space by point; or behind : Input other Delimiter(s) 

::: to include Spaces or additional characters after delimiter ->Syntax must insert 

::: between quotation marks for denumbering and incluce string to remove for, 

::: ->be sure in string the last sign exists once; 

::: [/Q] Quit modus: no Program message; been related works with E  

::: [/E] Quit modus: no Error message; been related works with Q 

::: > Spaces for Path- and Files-name or additional characters must insert between  quotation marks; 

::: > if source(path)name is equal to target(path)name NumberMe will be effect all 

::: > in sourcefile and without Options [/Z] [/N|/L] only deletes all empty lines;  

::: > additional characters only displayed  false on Screen;  

::: ::: output from sourcefile: number of all Lines and all empty Lines; 

::: exitcodes: [0] successful; [1] put in filename; [2] sourcefile not found; 

::: [3] input incorrect Syntax; [4] file is empty or empty lines only; 

::: [5] file is not numbered consecutively; [6] file is without empty lines only 

::; ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: 

@echo off & setlocal 

set "b=" &  set "E=" & set "Q=" & set "noempty=0" & set Full=0 

for %%i in ("" "\" "." ".." "..." "....") do if "%~1"=="%%~i" (echo Syntaxfehler! Bitte Quelldateinamen angeben! & set b=1 & goto :help ) 

for %%i in ("/" "/help" ) do if /i "%~1"=="%%~i" goto :help 

if "%~1"=="/?" goto :help 

if /i "%~1"=="/?en" for /f "usebackq tokens=1,*" %%i in ("%~f0") do if "%%i" == "::;" (echo %%j& exit /b 0) else if "%%i" == ":::" echo %%j 

if not exist "%~1" set b2=1 & goto :end 

for /f "delims=:" %%i in ('findstr /n .* "%~1"') do set /a Full + = 1 

for /f "usebackq" %%i in ("%~1") do set /a noempty + = 1 

goto :next 

:help 

if defined b (echo. & echo gueltige Syntax:  %E% & goto :syntax) 

echo Listet Dateien ^(mit Nummerierung^) zeilenweise ^(ohne Leerzeilen^) auf den 

echo Bildschirm oder in eine Datei. Oder Entfernt die Nummerierung. 

:syntax 

echo. & echo %~n0 ["][Pfad\]Quelldatei["] [["][Pfad\]Zieldatei["]] [/N^|/L[:][WERT]] 

echo  [["]/Z[:][Zeichen]["]] [/Q] [/E]   [/?] [/?en] credits and english short guide& if defined b (exit /b 1) else if defined erropt goto :end 

echo.&echo  Quelldatei   muss die erste Option sein sonst ist die Reihenfolge egal.&echo.   

echo  Zieldatei    Wird die Zieldatei nicht angegeben wird der Inhalt auf dem 

echo               Bildschirm ausgegeben. Zieldatei Wird ueberschrieben. 

echo  " "          Vollstaendige Unterstuetzung von Umgebenden Anfuehrungszeichen  

echo               bei Leer- ^& Sonderzeichen im Pfad und Dateinamen.&echo. 

echo  OHNE AusgabeART wird OHNE Leerzeilen mit Vornullen und Minimum Zweistellig 

echo  Numeriert ^= [/l:2]. Wenn Quelldatei, Zieldatei und Pfad gleich: Werden in 

echo  der Quelldatei OHNE AusgabeART und OHNE Option Z NUR Leerzeilen entfernt. 

echo  Sonst wie Syntax.&echo. 

echo   N           Gibt die AusgabeART an.         OHNE      Leerzeilen! 

echo   L           Gibt die AusgabeART an.   MIT             Leerzeilen! 

echo     WERT      Wird WERT NICHT angegeben wird NICHT Nummeriert! 

echo     -         Eine gefundene Durchgehende Nummerierung mit Punkt 

echo               oder mit LeerZeichen wird Entfernt und 

echo               gibt exitcode 5 wenn Durchgehende Nummerierung fehlt. 

echo     0         Es wird ohne Vornullen Nummeriert. 

echo     1         Ab der Zahl 1 wird Automatisch Vorgenullt (1-7, 0001-4702) 

echo               Oder Mindestene Stellenanzahl inklusive Vornullen (3^= 001-054) 

echo               Die Option N- und L- sind Identisch.&echo. 

echo   Z           Leerzeichen hinter Nummerrierung wird zum Punkt oder wie Zeichen. 

echo     Zeichen   Angabe von ein oder mehr Trennzeichen zur de- oder Nummerierung.&echo. 

echo      Achtung! Fuer Enthaltene Leer-/Sonderzeichen Syntax mit / in " " setzen! 

echo               Bei Denummerierung gibt das erste Zeichen das Trennzeichen hinter 

echo               der Nummerrierung an, das zweite bzw letzte bis wohin gelöscht 

echo               wird -^> das letzte Zeichen NICHT doppelt verwenden!&echo. 

echo   Q           Meldungen werden NICHT Ausgegeben - Hilfe wird immer angezeigt! 

echo   E           Errormeldungen werden NICHT Ausgegeben. ODER 

echo   QE oder EQ  Unterdrueckung aller Meldungen in einer Option!&echo. 

echo  Optionen koennen zusammenhaengend geschrieben werden zB: /N1/QE/Z wenn die 

echo  einzelne Option Z Keine Leerzeichen enthaelt. Doppelpunkte sind Optional.&echo. 

echo  Sonderzeichen: Falsche Ausgabe Nur auf Bildschirm! Im Dateiname:-^> setze " "  &echo. 

echo  Die Anzahl Zeilen und Anzahl Leerzeilen der Quelldatei werden ausgegeben!&echo. 

echo  Achtung! bei Der Option L gehen immer Doppelpunkte am Anfang verloren! 

echo  Dies gilt auch fuer das Trennzeichen Space bzw. Punkt bei Z bei Entfernung 

echo  der Nummerierung. Daher geht die Nummerierung mit N langsamer. 

exit /b 0 

:next 

for %%i in ( "yes=0" "orig=" "pN=" "vpn=" "testprezero= " "Zeichen= " "noemptyLines=" "LL=" "L=") do set %%i 

::Syntaxpruefung: Zieldatei De- oder Nummerierung 

for %%i in ( "con:" "/n:2" "%~2" "%~3" "%~4" "%~5" "%~6") do if not %%i == "" set "pX=%%~i" & call :setting 

if defined erropt (echo ungueltige Option: %erropt% %E% 

	goto :syntax) 

::ist Quelle gleich Ziel? gleich Numberme? 

if "%pOut%%put%" == "%~f0" set "orig=" & set "pOut=con:" & set "put=" 

if "%pOut%%put%" == "%~f1" set orig=%random% 

::Statusmeldung für Vorgang 

if defined orig ( 

	if %yes% equ 1 ( 

		if %noempty% lss %Full% ( 

			echo. %Q% 

			echo    Leerzeilen in "%~nx1" werden enfernt! %Q% 

			set pN=N 

		) else set noemptyLines=1 & goto :end 

	) else ( 

		if %pN% == D ( 

			echo. %Q% 

			echo    Nummerierung wird aus "%~nx1" enfernt! %Q% 

		) else ( 

			if not %pN% == N ( 

				echo. %Q% 

				echo    "%~nx1" wird Nummeriert! %Q% 

			) else ( 

				if not defined L if %noempty% lss %Full% ( 

					echo. %Q% 

					echo    Leerzeilen in "%~nx1" werden enfernt! %Q% 

					set pN=N 

				) else set noemptyLines=1 & goto :end 

)	)	)	) 

::Loesche vorhandene Zieldatei 

if not ["%pOut%%orig%%put%"]==["con:"] if exist "%pOut%%orig%%put%" del "%pOut%%orig%%put%" 

::Erstelle extraDatei/Output fuer Leerzeilenentfernung oder Tempdatei für De- oder Nummerierung und Zaehle Zeilen 

if %noempty% equ %Full% set "L=" 

if defined L if %pN% == N (for /f "tokens=1* delims=:" %%i in ('findstr /n .* "%~1"') do echo.%%j>>"%pOut%%orig%%put%" 

	goto :end 

) 

if %pN% == N (for /F "usebackq delims=" %%i in ("%~1") do echo.%%i>>"%pOut%%orig%%put%" 

	goto :end 

) 

if exist %temp%\tmp del %temp%\tmp 

if defined L if not %pN% == D for /f "tokens=1* delims=:" %%i in ('findstr /n .* "%~1"') do (echo.%%j>>"%temp%\tmp" 

	set /a LL + = 1 

) 

if not defined LL for /f "usebackq delims=" %%i in ("%~1") do set /a LL + = 1 & echo.%%i>>"%temp%\tmp" 

set NL=9 

::mit oder ohne Vornull? 

if %pN% == D (set "D=1" 

	set "NN=0"		 

	goto :noZero 

) else if %pN% lss 1 (set "NN=0" 

	goto :noZero 

) else set "NN=1" 

::Zaehlen der Automatischen oder Manuellen Vornullen 

:testZero 

if %NL% lss %LL% ( 

	set "NL=%NL%9" 

	set /a NN + = 1 

	goto :testZero 

) 

if %NN% gtr %pN% (set pN=%NN%) else set NN=%pN% 

set NL=9 

::Vornullen setzten  

:withZero 

if not %pN% == 1 ( 

	set "vpn=%vpN%0" 

	set /a pN - = 1 

	goto :withZero 

) 

::Spungziel bei keinen Vornullen oder nach Pruefung auf Nummerierung 

:noZero 

set /a pN = 0 , HNL = 0 , HL = 9 

::Blockanfang De- oder Nummerierung  

:read 

::Keine Nummerierung gefunden? 

if defined nodel if "%Zeichen%" == " " (set "nodel=" & set "Zeichen=." & goto :noZero) else goto :end 

::Schalter fuer Pruefung auf vorhandene Nummerierung oder Sprung zum Ende oder Einstellung Ziffernbreite 

if defined D ( 

	if %pN% == %LL% ( 

		if not defined delNR ( 

			set "delNR=1" 

			goto :noZero 

		) else goto :end 

	) else (set /a pN + = 1 

	) 

) else if %pN% == %LL% (goto :end) else set /a pN + = 1 

::Zaehler fuer Zeile und VorNullen Einstellung und Ruf Zeilenwahl 

call :setline %pN% 

if %HL% == %pN% (set "HNL=%NL%" 

	set "HL=%HL%9" 

) 

if %NN% gtr 0 (if %NL% == %pN% (set "NL=%NL%9"set /a NN - = 1 

		set "vpN=%vpN:~1%" 

)	) 

goto :read 

::Zeilenauswahl zum Ueberspung 

:setline 

if 1 == %1 set "skip=" & goto :write 

set /a skip = %1 - 1 

set skip=Skip=%skip% 

:write 

::Test auf oder Entfernung einer Vorhandenen Nummerierung  

if defined D ( 

	if not defined delNR ( 

		for /f "%skip% tokens=1,* delims=%Zeichen:~0,1%" %%i in (%temp%\tmp) do ( 

			if not "%%i" == "%pN%" ( 

				set "testprezero=%%i" 

				call :prezero 

			) 

			goto :eof 

		) 

	) else (for /f "tokens=1,* delims=%Zeichen:~-1%" %%i in (%temp%\tmp) do echo.%%j>>"%pOut%%orig%%put%" 

		set "pN=%LL%" & goto :eof	 

)	) 

::Schreibe: (Vornull)Nummer Trenner und Zeile 

if not defined L for /f "%skip% delims=" %%i in (%temp%\tmp) do ( 

	echo.%vpN%%pN%%Zeichen%%%i>>"%pOut%%orig%%put%" 

	goto :eof 

) 

for /f "tokens=1* delims=:" %%i in ('findstr /n .* "%temp%\tmp"') do ( 

	if %HL% lss %%i goto :eof 

	if %LL% lss %%i goto :eof 

	if %HNL% lss %%i (echo.%vpN%%%i%Zeichen%%%j>>"%pOut%%orig%%put%" 

		set /a pN=%%i 

)	) 

goto :eof 

::Sprungziel Teste auf Vornullen zum Denummerieren 

:prezero 

if "%testprezero:~ 0, 1%" == "0" set "testprezero=%testprezero:~ 1%" & goto :prezero 

if not "%testprezero%" == "%pN%" set nodel=1 

goto :eof 

::Sprungziel Syntaxeinstellungen 

:setting 

if not "%px:~ 0, 1%" =="/" goto :output  

for /f "tokens=1-4 delims=/" %%a in ("%px%") do for %%i in ("%%~a" "%%~b" "%%~c" "%%~d") do if not "%%~i" == "" set "px=%%~i" & call :option 

goto :eof 

:option 

if "%px:~1,1%" == ":" set "px=%px:~0,1%%px:~2%" 

if /i "%pX:~0,1%" == "Z" ( 

	set /a yes + = 1 

	if "%pX:~1%" == "" (set "Zeichen=.") else set "Zeichen=%pX:~1%" 

) else if /i "%pX:~0,1%" == "E" (set "E=>nul" if /i "%pX:~1%" == "Q" set "Q=>nul" 

) else if /i "%pX:~0,1%" == "Q" (set "Q=>nul" if /i "%pX:~1%" == "E" set "E=>nul" 

) else if /i "%pX:~0,1%" == "N" ( 

	set /a yes + = 1 

	if "%pX:~1%" == "-" (set "pN=D" 

	) else if "%pX:~1%" gtr "0" (set /a pN = %pX:~1% 

	) else if "%pX:~1%" == "0" (set "pN=0" 

	) else set "pN=N" 

) else if /i "%pX:~0,1%" == "L" ( 

	set /a yes + = 1 

	set L=1 

	if "%pX:~1%" == "-" (set "pN=D" 

	) else if "%pX:~1%" gtr "0" (set /a pN = %pX:~1% 

	) else if "%pX:~1%" == "0" (set "pN=0" 

	) else set "pN=N" 

) else set "erropt=%pX%" 

goto :eof 

:output 

if not defined pOut set "pOut=%px%" & goto :eof 

for %%i in ("%px%") do set "pOut=%%~dpi" & set "put=%%~nxi" 

if not defined put set "pout=con:" & set "put=" 

goto :eof 

:end 

if defined b2 ( 

	echo Fehler! Quelldatei "%~1" nicht gefunden! %E% 

	exit /b 2 

) 

if defined nodel echo "%~nx1" enthaelt keine Nummerierung! %E% 

if defined noemptyLines echo "%~nx1" enthaelt keine Leerzeilen %Q% 

if %noempty% equ 0 echo "%~nx1" ist leer! %E% 

if not defined orig goto :noren 

if defined noemptyLines goto :noren 

if defined nodel goto :noren  

move /y "%pOut%%orig%%put%" "%~1" 

:noren 

set /a Lempty = Full - noempty 

echo AnzahlZeilen %Full% AnzahlLeerzeilen %Lempty% %Q% 

if exist %temp%\tmp del %temp%\tmp 

if defined erropt exit /b 3 

if %noempty% equ 0 exit /b 4 

if defined noemptyLines exit /b 6 

if defined nodel exit /b 5 

exit /b 0 

:: -------------------schnapp------NumberMe.bat------------</