WSUS 3.0 Updates sehr groß

@echo off
setlocal
set WSUSPATH=C:\WSUS
set WSUSDEBUGPATH=C:\Programme\Update Services
call :GETINFO %WSUSPATH%
set DATEIENVORHER=%DATEIEN%
set VERZEICHNISSEVORHER=%VERZEICHNISSE%
set BELEGTVORHER=%BELEGT%
set FREIVORHER=%FREI%
set TSVORHER=%DATESTAMP%-%TIMESTAMP%

"%WSUSDEBUGPATH%\WsusDebugTool.exe" /Tool:PurgeUnneededFiles

call :GETINFO %WSUSPATH%
set DATEIENNACHHER=%DATEIEN%
set VERZEICHNISSENACHHER=%VERZEICHNISSE%
set BELEGTNACHHER=%BELEGT%
set FREINACHHER=%FREI%
set TSNACHHER=%DATESTAMP%-%TIMESTAMP%

echo *** Informationen ueber %WSUSPATH% ***
echo %TSVORHER% VORHER : Belegt %BELEGTVORHER% Bytes; Frei %FREIVORHER% Bytes; %DATEIENVORHER% Dateien; %VERZEICHNISSEVORHER% Verzeichnisse
echo %TSNACHHER% NACHHER: Belegt %BELEGTNACHHER% Bytes; Frei %FREINACHHER% Bytes; %DATEIENNACHHER% Dateien; %VERZEICHNISSENACHHER% Verzeichnisse

pause
endlocal
goto :EOF

:GETINFO
rem **************************************************************************
rem *** liefert Informationen des uebergebenen Ordners ***
rem **************************************************************************
set CHECKPATH=%1
call :GENTIMESTAMP
dir "%CHECKPATH%" /s > "%TEMP%\wsusfree.txt"
for /f "tokens=1,3" %%i in ('findstr /C:"Datei(en)" "%TEMP%\wsusfree.txt"') do set DATEIEN=%%i&set BELEGT=%%j
for /f "tokens=1,3" %%i in ('findstr /C:"Verzeichnis(se)" "%TEMP%\wsusfree.txt"') do set VERZEICHNISSE=%%i&set FREI=%%j
del "%TEMP%\wsusfree.txt"
goto :EOF

:GENTIMESTAMP
rem **************************************************************************
rem *** Generiert Datum und Uhrzeit in umgekehrter Notation ***
rem **************************************************************************
for /F "tokens=1,2 delims= " %%i in ('date /t') do call :BUILDDATESTAMP %%i %%j
for /F "tokens=1,2,3 delims=: " %%i in ('time /t') do call :BUILDTIMESTAMP=%%i %%j %%k
goto :EOF

:BUILDDATESTAMP
rem **************************************************************************
rem *** Baut das Datum zusammen (Fallunterschiedung Deutsch / Englisch) ***
rem **************************************************************************
if .%2==. (set ANLAYSEDATE=%1) else (set ANLAYSEDATE=%2)
if .%ANLAYSEDATE:~2,1%==./ for /F "tokens=1,2,3 delims=/" %%i in ("%ANLAYSEDATE%") do set DATESTAMP=%%k%%i%%j
if .%ANLAYSEDATE:~2,1%==.. for /F "tokens=1,2,3 delims=." %%i in ("%ANLAYSEDATE%") do set DATESTAMP=%%k%%j%%i
goto :EOF

:BUILDTIMESTAMP
rem **************************************************************************
rem *** Baut die Uhrzeit zusammen (Fallunterscheidung Deutsch / Englisch) ***
rem **************************************************************************
set TIMEHH=%1
set TIMEMM=%2
set TIMEAP=%3
if .%TIMEMM:~2,1% NEQ . set TIMEAP=%TIMEMM:~2,1%& set TIMEMM=%TIMEMM:~0,2%
if .%TIMEHH:~1,1%==. set TIMEHH=0%TIMEHH%
set TIMESTAMP=%TIMEAP%%TIMEHH%%TIMEMM%
set TIMESTAMP=%TIMESTAMP: =%
goto :EOF