Aus txt Dateien Texte auslesen und Absätze neu speichern

Hallo ,

ich habe hier mehrere tausend .txt Dateien in denen Texte sind.
Nun muss ich jede einzelne txt öffnen und den vorhanden Text möglichst Absatzweise in jeweils
einer eigenen neuen .txt speichern.

Wichtig wäre mir , wie man das anhand einer Datei ordentlich hinbekommt.

Beispiel:
beispiel.txt

Während die oben angeführte Definition eines Textes als „abgegrenzte schriftliche oder potentiell zu verschriftlichende Äußerung“ im Alltag meist ausreichend ist, führt eine genauere, wissenschaftliche Betrachtung zu komplexeren Definitions- und Beschreibungsversuchen.

Die Eigenschaft des „Text-Seins“ bezeichnet man als Textualität, die sprachwissenschaftliche Untersuchung von Texten ist die Textlinguistik. Diese Disziplin stellt verschiedene Textualitätskriterien zur Verfügung. Robert-Alain de Beaugrande und Wolfgang Ulrich Dressler stellten 1981 eine Reihe solcher Kriterien vor:


Ergebnis sollte sein:
beispiel1.txt
Während die oben angeführte Definition eines Textes als „abgegrenzte schriftliche oder potentiell zu verschriftlichende Äußerung“ im Alltag meist ausreichend ist, führt eine genauere, wissenschaftliche Betrachtung zu komplexeren Definitions- und Beschreibungsversuchen.

beispiel2.txt
Die Eigenschaft des „Text-Seins“ bezeichnet man als Textualität, die sprachwissenschaftliche Untersuchung von Texten ist die Textlinguistik. Diese Disziplin stellt verschiedene Textualitätskriterien zur Verfügung. Robert-Alain de Beaugrande und Wolfgang Ulrich Dressler stellten 1981 eine Reihe solcher Kriterien vor:


Die Länge Dateien ist stark unterschiedlich....
Hoffe mir kann da jemand helfen ... wäre dringend ^^

P.S. bin heute den ganzen Tag online und habe den Thread im Auge falls jemand Fragen zu der Problematik hat.

@echo off & setlocal
for /f "tokens=2 delims=:." %%i in ('chcp') do set "cp=%%i"  
chcp 1252 >nul

for %%i in ("D:\Ordner\Beispiel.txt") do (  
    set "Pfad=%%~dpni"  
    set "Typ=%%~xi"  
    set /a Nr=1001
    set neu=true
    for /f "tokens=1* delims=:" %%a in ('findstr /n "^" "%%i"') do set "Zeile=%%b" & call :ProcessLine  
)

chcp %cp% >nul
goto :eof
	
:ProcessLine
::Leerzeile?
if "%Zeile%"=="" goto :Next  
set "Zeile=%Zeile:&=^&%"  
set "Zeile=%Zeile:<=^<%"  
set "Zeile=%Zeile:>=^>%"  
set "Zeile=%Zeile:|=^|%"  
>>%Pfad%%Nr:~-3%%Typ% echo %Zeile%
set neu=
goto :eof

:Next
:: Nach Leerzeile beginnt neue Datei, aber nur,
:: wenn seit der letzten Leerzeile bereits wieder
:: eine Zeile geschrieben wurde (zu erkennen daran,
:: dass %neu% nicht mehr gesetzt ist).
if defined neu goto :eof
set /a Nr+=1
set neu=true	
goto :eof

for %%i in ("D:\Ordner\Beispiel.txt") do (

for %%i in ("D:\Ordner\*.txt") do (