Vmware Server 2 Backup Skript (Windows)

Hallo Forum!

Ich habe mir in den letzten Stunden ein Backup Skript für meinen VMware Server gebaut. Bevor ich das ganze jetzt Produktiv einsetze wäre es nett wenn mal jemand das ganze übefliegt und mir sagt ob ich irgendwas vergessen habe.

Ich mache ein Offline Backup, da die sechs betreffenden VM's ruhig Sonntags nachts mal für ne halbe Stunde Offline sein dürfen. Skript muss für die jeweiligen VM's nur oben im "set" bereich angepasst werden!
Geplant ist einfach die Skripts hintereinander zu hängen und so eine VM nach der anderen zu sichern! Habe mal einige Kommentare angefügt um zu erklären was ich mit dem jeweiligen Schnipsel bezwecke!

Vielleicht dient es dem einen oder anderen ja auch als Vorlage!

Hier mein batch:

@echo off
rem $$$$setzen der Variablen

set user=administrator
rem $$$$Benutzername

set pass=Passwort
rem $$$$Passwort

set vm=Mailserver
rem $$$$Name der VM

set vmfiles="[standard] Mailserver\Mail Server.vmx"
rem $$$$VM Pfad innerhalb VMWare ([Datastore] Ordner/VMX File)

set vmdir=E:\Virtual Machines\Mailserver
rem $$$$ VM Pfad im Dateisystem

set backupdir=E:\Backup\VM\
rem $$$$ Gewünschter Backup Pfad (Netzlaufwerk, Wechselmedium, Freigabe.. was auch immer


cd C:\Programme\VMware\VMware VIX\
rem $$$$ verzeichnis wechseln!

echo ===========================================================
echo ===========================================================
echo.
echo VMWare Server 2 Backup Script
echo Erstellt von mir
echo.
echo ===========================================================
echo ===========================================================
echo.
echo.
echo Sicherung von Server:%vm%

:check
if exist "%vmdir%\Mail Server.vmdk.lck" goto shutdown
goto sicherung
rem $$$$ prüfen ob VM läuft. Wenn ja :shutdown, wenn nicht :sicherung.


:shutdown
echo Server ist (noch) aktiv!
echo Shutdown befehl an %vm% Server senden...
echo Warten bis der Server heruntergefahren ist...
call vmrun -T server -h https://127.0.0.1:8333/sdk -u %user% -p %pass% stop %vmfiles% soft
if exist "%vmdir%\Mail Server.vmdk.lck" goto wait
goto sicherung
rem $$$$ Herunterfahren, danach prüfen ob VM nocht läuft (Falls Server hängt und VMware Tools nicht laufen)
rem $$$$ Wenn VM nicht läuft ab nach :Sicherung wenn doch ab nach :wait

:wait
wait 20
if exist "%vmdir%\Mail Server.vmdk.lck" goto stop
goto sicherung
rem $$$$ Festgelegte Zeit warten (in Sekunden). Danach Prüfen ob VM läuft. Wenn ja, ab nach :stop, wenn nicht :sicherung!

:stop
call vmrun -T server -h https://127.0.0.1:8333/sdk -u %user% -p %pass% stop %vmfiles% hard
wait 5
rem $$$$ VM ausschalten. Ich gehe davon aus das die VM nicht mehr reagiert wenn die Soft Methode nicht funktioniert.

:sicherung
echo Server ist heruntergefahren! Beginne mit Sicherung...
if exist %backupdir%\%vm%Backup_%date% goto copy
md "%backupdir%\%vm%Backup_%date%"
:copy
copy "%vmdir%\*.*" "%backupdir%\%vm%Backup_%date%\"
rem $$$$ Prüfen ob Backupverzeichnis vorhanden ist. Wenn nicht neues erstellen mit Aktuellem Datum.
rem $$$$ Kopieren vom VM Verzeichnis zu $Backupdir


:start
echo Startbefehl ausfuehren...
call vmrun -T server -h https://127.0.0.1:8333/sdk -u %user% -p %pass% start %vmfiles% nogui
echo Fertig...
pause

rem $$$$ VM wieder starten!