Zeile kopieren und in neues Tabellenblatt einfügen

'Also hier gehts weiter nachdem die Auswahl selektiert wurde  
Selection.Copy
Sheets("Name des Ziel Datenblattes").Select  
Range("A2").Select  
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

Option Explicit
Option Compare Text

Sub Test()
    Dim Wks1 As Worksheet, Wks2 As Worksheet, Found As Range, c As Range
    
    Set Wks1 = Sheets("Tabelle1"):  Set Wks2 = Sheets("Tabelle2")  
    
    Application.ScreenUpdating = False
    
    With Wks1
        For Each c In .Range("F2:F" & .Cells(.Rows.Count, "F").End(xlUp).Row)  
            If  Not IsEmpty(c) Then
                Set Found = Wks2.Columns("A").Find(c, LookIn:=xlValues, LookAt:=xlWhole)  
                If Not Found Is Nothing Then
                    .Rows(c.Row).Copy:  Wks2.Rows(Found.Row + 1).Insert Shift:=xlDown
                End If
            End If
        Next
    End With
    
    Application.CutCopyMode = False:  Application.ScreenUpdating = True
End Sub

Option Explicit
'Hiermit wird verlangt, dass alle benutzten Variablen definiert werden.  

Option Compare Text
'Hiermit wird festgelegt, dass bei Vergleichs-Operationen (Like, Find...)   
'NICHT zwischen Groß/Klein-Schreibung unterschieden wird.   

Sub Test()
    Dim Wks1 As Worksheet, Wks2 As Worksheet, Found As Range, c As Range
    
    Set Wks1 = Sheets("Tabelle1"):  Set Wks2 = Sheets("Tabelle2")  
   'Bei Abläufen in verschiedenen Tabs empfielt es sich, die Tabellenblätter explizit  
   'einer Variablen zuzuordnen und diese darüber anzusprechen.   
    
    Application.ScreenUpdating = False
   'Deaktiviert die Bildschirmaktualisierung während der Makro-Ausführung.  
   'Das Makro wird schneller ausgeführt und der Bildschirm flackert nicht.   
    
    With Wks1
       'Alle nachfolgenden Anweisungen, die mit einem Punkt beginnen, sind dem  
      'Tabellenblatt Wks1 zuzuordnen.    

        For Each c In .Range("F2:F" & .Cells(.Rows.Count, "F").End(xlUp).Row)  
       'c steht für jede einzelne Zelle im Bereich F2:F & Letzte Zeile mit Inhalt in Spalte F  

            If  Not IsEmpty(c) Then  'Keine leere Zellen  
                Set Found = Wks2.Columns("A").Find(c, LookIn:=xlValues, LookAt:=xlWhole)  
               'Found ist Zelle, in der der Wert gefunden wurde (xlWohle vergleicht ganzen Zellinhalt)    

                If Not Found Is Nothing Then  'Wenn gefunden dann  
 
                    .Rows(c.Row).Copy:  Wks2.Rows(Found.Row + 1).Insert Shift:=xlDown
                    'Zeile mit Suchwert kopieren und in einer neuen Zeile gefunden +1 einfügen  
                End If
            End If
        Next
    End With
    
    Application.CutCopyMode = False:  Application.ScreenUpdating = True
   'Die Kopiermarkierung aufheben und die Bildschirmaktualisierung wieder aktivieren  

End Sub

If Not Found Is Nothing Then
   Wks2.Rows(Found.Row + 1).Insert Shift:=xlDown 'Neue Zeile in Tab2 einfügen  
  .Range(c.Offset(0, -5), c.Offset(0, 0)).Copy Destination:=Wks2.Cells(Found.Row + 1, 6)
   Oder
  .Range(c.Offset(0, -5), c).Copy Destination:=Wks2.Cells(Found.Row + 1, 6)
  'In Tab1 Spalte A-F nach Tab2 in neue Zeile Spalte F-K kopieren   
End If

If Not Found Is Nothing Then
  .Range(c.Offset(0, -5), c.Offset(0, 0)).Copy Destination:=Wks2.Cells(Found.Row , 2)
   Oder
  .Range(c.Offset(0, -5), c).Copy Destination:=Wks2.Cells(Found.Row , 2)
  'In Tab1 Spalte A-F nach Tab2 gleiche Zeile Spalte B-G kopieren   
End If