vbs - Eine ini Datei auslesen an dieser Stelle einen Pfad einfügen und wenn dieser Datei nicht existiert in der ini Pfad zusätzlich einfügen

Dim MeineIniDatei
dim Wert1 , Wert2

'On Error resume next  

Set FSO = CreateObject("Scripting.FileSystemObject")  
Set MyDB = FSO.OpenTextFile("C:\Test.ini", 1)  

Set MyNewDB = FSO.CreateTextFile("C:\TestIni.txt", TRUE)  
MyNewDB.close

Do Until MyDB.AtEndOfStream 
    
    MeineIniDatei = MyDB.ReadLine
    MeineIniDatei = Split(MeineIniDatei , "=")  
	Wert1 = MeineIniDatei(0)
	Wert2 = MeineIniDatei(1)
	
	select case Wert1
	case "names"  
	if not Wert2 = "C:\User\" then Wert2 = "C:\User\"  
	case "desktop6"  
	if not Wert2 = "desktop6" then Wert2 = "desktop6"  
	case "region"  
	if not Wert2 = "de" then Wert2 = "de"  
	end select
	
	Set FSO = CreateObject("Scripting.FileSystemObject")  
	Set MyNewDB = FSO.OpenTextFile("C:\TestIni.txt", 8)  
		MyNewDB.WriteLine (Wert1 & "=" & Wert2)  
	MyNewDB.close


Loop

MyDB.close

set MyDB = nothing
set MyNewDB = nothing
set FSO = nothing

Dim MeineIniDatei
dim WertA(7)
dim WertB(7)
dim i
i = 0
dim Nutzer

'On Error resume next  

'Usernamen auslesen (angemeldet am PC)  
Set objUsr = CreateObject("WScript.NetWork")   
Nutzer = objUsr.UserName


Set FSO = CreateObject("Scripting.FileSystemObject")  
Set MyDB = FSO.OpenTextFile("C:\Test.ini", 1)  


Do Until MyDB.AtEndOfStream 
    
    MeineIniDatei = MyDB.ReadLine
    MeineIniDatei = Split(MeineIniDatei , "=")  
	WertA(i) = MeineIniDatei(0)
	WertB(i) = MeineIniDatei(1)
	
	select case WertA(i)
	case "Directory"  
	if not WertB(i) = "C:\Programme\IBM\LN\Data" then WertB(i) = "C:\Programme\IBM\LN\Data"  
	case "Names"  
	if not WertB(i) = "H:\Documents\LN\Data\names.nsf" then WertB(i) = "H:\Documents\LN\Data\names.nsf"  
	case "Desktop6"  
	if not WertB(i) = "H:\Documents\LN\Data\Desktop6.ndk" then WertB(i) = "H:\Documents\LN\Data\Desktop6.ndk"  
	case "KeyFilename"  
	if not WertB(i) = "H:\Documents\LN\Data\" & Nutzer & ".id" then WertB(i) = "H:\Documents\LN\Data\" & Nutzer & ".id"  
	case "Region"  
	if not WertB(i) = "de" then WertB(i) = "de"  
	case "UserInterface"  
	if not WertB(i) = "de" then WertB(i) = "de"  
	case "ContentLanguage"  
	if not WertB(i) = "de" then WertB(i) = "de"  
	case "Cache"  
	if not WertB(i) = "C:\Temp\cache.ndk" then WertB(i) = "C:\Temp\cache.ndk"  
	end select
	
	
	i = i + 1

Loop

MyDB.close

	if not WertA(4) = "Region" then  
		WertA(4) = "Region"  
		WertB(4) = "de"  
	end if
	if not WertA(5) = "UserInterface" then  
		WertA(5) = "UserInterface"  
		WertB(5) = "de"  
	end if
	if not WertA(6) = "ContentLanguage" then  
		WertA(6) = "ContentLanguage"  
		WertB(6) = "de"  
	end if
	if not WertA(7) = "Cache" then  
		WertA(7) = "Cache"  
		WertB(7) = "C:\Temp\cache.ndk"  
	end if

'jetzt Date überschreiben  
	Set MyNewDB = FSO.CreateTextFile("C:\Test.ini", TRUE)  
	MyNewDB.close

for i = 0 to 7
	Set FSO = CreateObject("Scripting.FileSystemObject")  
	Set MyNewDB = FSO.OpenTextFile("C:\Test.ini", 8)  
		MyNewDB.WriteLine (WertA(i) & "=" & WertB(i))  
	MyNewDB.close
next

set MyDB = nothing
set MyNewDB = nothing
set FSO = nothing
Set objUsr = nothing

	if not WertB(i) = "C:\Programme\IBM\LN\Data" then WertB(i) = "C:\Programme\IBM\LN\Data"

	WertB(i) = "C:\Programme\IBM\LN\Data"

'Usernamen auslesen (angemeldet am PC)  
Set objUsr = CreateObject("WScript.NetWork")   
Nutzer = objUsr.UserName

MeineIniDatei = "C:\Test.ini"  
'Alle benötigten Zeilen in einem Array zusammenfassen,  
'  um sie dann in einer Schleife einzeln bearbeiten zu können  
Ersetzungen = Array( _
    "Directory=C:\Programme\IBM\LN\Data", _  
    "Names=H:\Documents\LN\Data\names.nsf", _  
    "Desktop6=H:\Documents\LN\Data\Desktop6.ndk", _  
    "KeyFilename=H:\Documents\LN\Data\" & Nutzer & ".id", _  
    "Region=de", _  
    "UserInterface=de", _  
    "ContentLanguage=de", _  
    "Cache=C:\Temp\cache.ndk" _  
)

Set fso = CreateObject("Scripting.FileSystemObject")  
'Aktuellen Inhalt der .ini-Datei einlesen und zeilenweise  
'    in das Array Ini() schreiben  
Ini = Split(fso.OpenTextFile(MeineIniDatei, 1).ReadAll, vbCrLF)
'Höchsten Index zwischenspeichern (wird mehrmals benötigt)  
MaxZeile = UBound(Ini)

'Alle Zeilen der Ersetzungstabelle durchgehen  
For Each Eintrag In Ersetzungen
    Wert = Split(Eintrag, "=") 'Eintrag anhand des "=" aufteilen; Wert(0) = Schlüssel  
    Vorhanden = False 'Schalter, um festzuhalten, ob der Eintrag in der Ini vorhanden ist  
    For i = 0 To MaxZeile 'alle Zeilen der Ini durchgehen  
        'Ist Schlüssel + "=" in der Zeile enthalten?  
	    If InStr(1, Ini(i), Wert(0) & "=", vbTextCompare) > 0 Then  
            Ini(i) = Eintrag 'gesamte Zeile durch Eintrag ersetzen  
            Vorhanden = True 'merken, dass Eintrag in der Ini vorhanden ist  
            Exit For 'die weiteren Zeilen der Ini müssen nicht mehr geprüft werden  
        End If
    Next
    'Falls der Eintrag noch nicht vorhanden ist,  
    '  als "Zusatzzeile" zwischenspeichern (an bereits vorhandene  
    '    Zusatzzeilen mit einer Zeilenschaltung vorweg anfügen)  
    If Not Vorhanden Then Zusatz = Zusatz & vbCrLF & Eintrag
Next

'Neuen Inhalt der Ini durch Zusammenfügen der bisherigen Zeilen  
'  und Anfügen der zusätzlichen Zeilen erstellen ...  
InhaltNeu = Join(Ini, vbCrLF) & Zusatz

'... und damit die Originaldatei überschreiben  
fso.CreateTextFile(MeineIniDatei, True).Write InhaltNeu