xxmeikyxx
Jan 14, 2011
view2653
view1
0
Goto Top

Programm zum erkennen neuer Dateien

GermanQuestionMicrosoft
Hallo zusammen,

ich habe folgende Frage.

Wir sind eine Werbeagentur mit vielen Kunden von denen jeder einen eigenen Zugang auf unsere Website hat.
Die Kunden können auf dieser Website immer schauen was und welche Aufträge sie bei uns gemacht haben.

Damit diese Dateien auch immer aktuell sind und die neuesten Aufträge im Internet zusehen sind
muss ich immer hergehen und suchen welche Kunde einen Auftrag bei uns hatte, dann die jeweilige Datei suchen
und ins Internet hochladen...... aber leider dies ist oft sehr sehr zeitaufwendig.

Gibt es nun ein Programm dass z. B. einen Ordner überwacht und mir dan in irgendeiner Weise Bescheid
gibt das es eine neue Datei im besagten Ordner gibt.

Würde mir sehr helfen ! ;)

Danke im Vorraus....
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 158642

Url: https://administrator.de/contentid/158642

Printed on: April 16, 2024 at 21:04 o'clock

1 Comment
Goto Top
Mitglied: 76109
76109 Jan 14, 2011 at 10:43:53 (UTC)
Goto Top
Hallo XxMeikyxX!

Hierzu hat bastla hier mal ein VB-Skript geschrieben.

In diesem Beispiel-Skript (*.vbs) wird der Ordner "D:\Temp" im 10 Sekunden-Interval überwacht und gibt für jede Datei eine Meldung mit Dateipfad aus:
Option Explicit

Const strFolder = "D:\Temp"  

Const strComputer = "."  

Const intInterval = 10	'Zeit-Interval in Sekunden  

Const Msg1 = "Neue Datei eingetroffen: "  
Const Msg2 = "Die Überwachung des Ordners '%1' wurde beendet!"  

Dim objWMIService, colMonitoredEvents, objLatestEvent
Dim strUserFolder, strNewFile, strFileName

strUserFolder = Replace(strFolder, "\", "\\\\")  

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")  
Set colMonitoredEvents = objWMIService.ExecNotificationQuery _
    ("SELECT * FROM __InstanceCreationEvent WITHIN " & intInterval & " WHERE " _  
        & "Targetinstance ISA 'CIM_DirectoryContainsFile' and " _  
            & "TargetInstance.GroupComponent= " _  
                & "'Win32_Directory.Name=""" & strUserFolder & """'")  
Do
    Set objLatestEvent = colMonitoredEvents.NextEvent
    
    strNewFile = objLatestEvent.TargetInstance.PartComponent
    strFileName = LCase(Replace(Split(strNewFile, Chr(34))(1), "\\", "\"))  
    
    If strFileName <> LCase(strFolder & "\Stop.Txt") Then  
        MsgBox Msg1 & strFileName, vbInformation, "Ordner überwachen..."  
    End If
Loop While (strFileName <> LCase(strFolder & "\Stop.Txt"))  

MsgBox Replace(Msg2, "%1", strFolder), vbInformation, "Ordner überwachen..."
Das Skript wird beendet, sobald es im Überwachungs-Ordner eine neue Datei namens "Stop.txt" findet.

Gruß Dieter
GermanQuestionMicrosoft
Hotly discussed
DaniEnd of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment