pieh-ejdsch
Goto Top

Win 7 Energiesparplan - Direkter und Rotierender wechsel (in der Taskleiste)

Seit Windows 7 wurde dieses Symbol für PC aus der Taskleiste verbannt

Moin,
nun hat es mich doch ständig gestört in die Energieoptionen zu hangeln und dann weiter unten oder weiter oben draufzuklicken um ein anderes Schema auszuwählen.
Was es so an Tools und Tipps dazu gibt ist auch nicht so die Menge.

Vorangig ist der Batch in einen leeren Ordner zu Verfrachten, und über
einen Rechtsklick auf die Taskleiste -> Symbolleiste -> neue Symbolleiste... ->Ordner auswählen
einzufügen.

Über die CMD werden die Links der Energieschemata mit dem Parameter "Link" erzeugt.
Der Link des aktuellen Energieschema ist mit (x) gekenzeichnet.

Der Parameter "-" nimmt das aktuelle Energieschema aus der Rotation heraus.
Diese Einstellungen werden in den Batch hinterlegt.

Der Parameter "+" setzt die Rotation wieder züruck (alle Energieschemata sind wieder in der Rotation) und die Links werden erstellt.

Für den Wechsel von zwei Presets empfielt es sich die restlichen aus der Rotation zu nehmen, danach die Links zu löschen und nur den Batch anzuklicken.
Der Batchname erhält das aktuelle und das nächste Energieschema.

so genug der Worte.
:: -- schnipp ---- SwitchPowerSheme.cmd ----
@echo off
if "%~1" == "del.rename" del "%temp%\rename.cmd" & goto :eof  
if "%~1" == "Rotate" del "%temp%\Rename.cmd" & goto :Link  
if "%~1" == "del.Reset" del "%temp%\Reset.cmd" & goto :Link  
if "%~1" == "del.noSwitch" del "%temp%\noSwitch.cmd"  
if "%~1" == "/?" (  
echo Wechselt das Energieschema rotierend und/oder erstellt Links zum direkten wechsel
echo\
echo Syntax:
echo "%~n0" [-^|+^|Link]  
echo       ohne Parameter wird das Energieschema rotierend gewechselt
echo  -    das Aktuelle Schema wird aus der Rotation entfernt
echo  +    Pro Energieschema wird ein Link erstellt. Und Reset
echo        der Rotationsliste.
echo        der Aktive Link ist mit ^(x^) versehen.
echo Link  Pro Energieschema wird ein Link erstellt.
echo\
echo\      Wenn Keine Links zu den Energieschemata gefunden werden
echo\      wird der Batchname mit dem Aktiven und dem naechsten versehen.
goto :eof
)
setlocal
set "Link="  
set "OrigBatchname=SwitchPowerSheme"  
if /i "%~1" == "Link" goto :test  
for /f "tokens=1,5* delims=: " %%i in ('powercfg list^|findstr :^|findstr /n ^^^^') do (  
	set "Guid%%i=%%j"  
	for /f "delims=()" %%l in ("%%k") do (set "Name%%i=%%l"  
		if exist "%~dp0*%%l.lnk" set "Link=1"  
	)
	echo "%%k"|find "*" >nul&&set "NrAktiv=%%i"  
	set "MaxGuid=%%i"  
)
if not "%~1" == "-" goto :XnoSwitch  
:: Nichtvorhandenen Zeilenvorschub erfassen
for /f %%i in ('findstr /n /v /x /c:":::- %NrAktiv%" "%~0"^|find /c ":"') do for /f %%j in ('^(findstr /n /v /x /c:":::- %NrAktiv%" "%~0"^&echo :^)^|find /c ":"') do if %%i ==%%j (set "LineFeed=") else set "LineFeed=^>nul"  
findstr /x /c:":::- %NrAktiv%" "%~0" >nul 2>nul || (  
>&4 echo @echo off
>&4 echo ^(
>&4 echo ^>^&4 findstr /v /x /c:":::- %NrAktiv%" "%~f0"  
>&4 echo\^>^&4 echo\%LineFeed%
>&4 echo ^>^&4 echo :::- %NrAktiv%
>&4 echo ^)4^>"%~dp0noSwitch.me"  
>&4 echo del "%~f0"  
>&4 echo ren "%~dp0noSwitch.me" "%~nx0"  
>&4 echo "%~f0" "del.noSwitch"  
) 4>"%temp%\noSwitch.cmd"^  
 &&"%temp%\noSwitch.cmd" || "%~f0" noSwitch  
:XnoSwitch
if not "%~1" == "+" goto :XReset  
:Reset
(
>&4 echo @echo off
>&4 echo ^(
>&4 echo findstr /v /b /c:":::- " "%~f0"  
>&4 echo ^)^>"%~dp0Reset.me"  
>&4 echo del "%~f0"  
>&4 echo ren "%~dp0Reset.me" "%OrigBatchname%%~x0"  
>&4 echo "%~dp0%OrigBatchname%%~x0" "del.Reset"  
) 4>"%temp%\Reset.cmd"  
"%temp%\Reset.cmd"  
:XReset
:Rotate
set /a y=(NrAktiv+1)%%MaxGuid,x=MaxGuid/y >nul 2>nul && set /a NrAktiv=y || set /a NrAktiv=MaxGuid
set /a NextAktiv=NrAktiv
:Rotate2
set /a y=(NextAktiv+1)%%MaxGuid,x=MaxGuid/y >nul 2>nul && set /a NextAktiv=y || set /a NextAktiv=MaxGuid
findstr /x /c:":::- %NrAktiv%" "%~f0" >nul && goto :Rotate  
findstr /x /c:":::- %NextAktiv%" "%~f0" >nul && goto :Rotate2  
call set "GuidNew=%%Guid%NrAktiv%%%"  
call set "NewName=%%Name%NrAktiv%%% -nach- %%Name%NextAktiv%%%"  
if "%~1" == "" Powercfg -setactive %GuidNew%  
if not defined Link 4>"%temp%\rename.cmd" (  
>&4 echo ren "%~f0" "%NewName%%~x0"  
>&4 echo "%~dp0%NewName%" "del.rename"  
) && "%temp%\rename.cmd"  
:Test
if not "%~n0" == "%OrigBatchname%" 4>"%temp%\rename.cmd" (  
	>&4 echo ren "%~f0" "%OrigBatchname%%~x0"  
	>&4 echo "%~dp0%OrigBatchname%%~x0" Rotate  
) && "%temp%\rename.cmd"  
:Link
if not "%~1" == "" powercfg list|find ":"|find " %~1 " >nul 2>nul && Powercfg -setactive %~1  
set "LinkPfad=%~dp0"  
::set "LinkName=%~n0"  
set "ProgPfad=%~dp0"  
set "ProgFile=%~nx0"  
::set "Parameters=GUID"  
set "Beschreibung=Aktiv oder Inaktiv"  

for /f "tokens=1,5* delims=: " %%i in ('powercfg list^|findstr :^|findstr /n "^"') do (  
	4>"%temp%\MakeShortCut.vbs" (  
		>&4 echo Set objShell=WScript.CreateObject^("Wscript.Shell"^)  
		>&4 echo Set objShortcut=objShell.CreateShortcut^("%LinkPfad%Temp.lnk"^)  
		for /f "delims=()" %%l in ("%%k") do (  
			if exist "%LinkPfad%*%%l.lnk" del "%LinkPfad%*%%l.lnk"  
			findstr /x /c:":::- %%i" "%~f0" >nul&& >&4 echo objShortcut.Description="Nicht Automatisch"||echo "%%k"|find "*" >nul && (  
				>&4 echo objShortcut.Description="Aktiviertes Energieschema"  
			) || (
				>&4 echo objShortcut.Description="Nicht Aktiv"  
			)	)
		>&4 echo objShortcut.TargetPath="%ProgPfad%\%ProgFile%"  
		>&4 echo objShortcut.WorkingDirectory="%ProgPfad%"  
		>&4 echo objShortcut.Arguments = "%%j"  
		>&4 echo objShortcut.Save
	)
	cscript //nologo "%temp%\MakeShortCut.vbs"  
	for /f "delims=()" %%l in ("%%k") do echo "%%k"|find "*" >nul && ren "%LinkPfad%Temp.lnk" "%%i (x) %%l.lnk" || findstr /x /c:":::- %%i" "%~f0" >nul && ren "%LinkPfad%Temp.lnk" "%%i - %%l.lnk" || ren "%LinkPfad%Temp.lnk" "%%i %%l.lnk"  
)
del "%temp%\MakeShortCut.vbs"  
goto :eof
:: -- schnapp ---- SwitchPowerSheme.cmd ----

der Code ist so geschrieben, dass ein Eingeschaltenes Echo mit der Erstellung der Temporären .VBS und .CMD Dateien kompatibel ist.
Dadurch kann man(n) auch besser eventuelle Fehler im Code beim Debuggen ausmachen - das echo der Befehle ist auf den Promt und NUR die Ausgabe der Befehle dort wo sie hin soll.

Gruß Phil

Content-Key: 168151

Url: https://administrator.de/contentid/168151

Ausgedruckt am: 19.03.2024 um 07:03 Uhr