Power Point 2007 - Sprache via VBA Makro auf US-Englisch umstellen

Sub Lingo()
    On Error Resume Next

    ' Declare variables.  
    Dim sld As Slide
    Dim shp As Shape
    Dim colShapes As New Collection
    Dim p As TextRange
    Dim r As TextRange

    ' Loop through all the slides in the presentation.  
    For Each sld In ActivePresentation.Slides
        ' Loop through each shape on each slide.  
        For Each shp In sld.Shapes
            colShapes.Add shp
            CheckGroups shp, colShapes
        Next

        For Each shp In sld.NotesPage.Shapes
            colShapes.Add shp
            If shp.HasTextFrame Then
                If shp.TextFrame.TextRange.Text = "" Then  
                    shp.TextFrame.TextRange.Text = "[PLACEHOLDER TEXT]"  
                End If
            End If
        Next
    Next

    For Each shp In ActivePresentation.SlideMaster.Shapes
        colShapes.Add shp
    Next

    For Each shp In ActivePresentation.TitleMaster.Shapes
        colShapes.Add shp
    Next

    For Each shp In ActivePresentation.NotesMaster.Shapes
        colShapes.Add shp
    Next

    MsgBox "There are [TOTAL]" & colShapes.Count & " shapes to be scanned."  

    For Each shp In colShapes
        If shp.TextFrame.TextRange.LanguageID = 1031 Then
            Debug.Print shp.Name
        End If
        shp.TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
        If shp.TextFrame.TextRange.Text = "[PLACEHOLDER TEXT]" Then  
            shp.TextFrame.TextRange.Text = ""  
        End If
    Next

    MsgBox "Done!"  

    ActivePresentation.DefaultLanguageID = msoLanguageIDEnglishUS
End Sub

Sub CheckGroups(shp As Shape, colShapes As Collection)
    On Error Resume Next

    If shp.GroupItems.Count > 0 Then
        For Each g In shp.GroupItems
            colShapes.Add g
        Next
    End If
End Sub

Sub Englisch()

   ' Declare variables.  
   Dim sld As Slide
   Dim shp As Shape

   ' Loop through all the slides in the presentation.  
   For Each sld In ActivePresentation.Slides
        
       ' Loop through each shape on each slide.  
       For Each shp In sld.Shapes
            
           ' If the Shape is a text box...  
           If shp.Type = msoTextBox Or msoPlaceholder Then
           If shp.HasTextFrame Then
                
               ' ...then change the language to US English.  
               ' NOTE: To change the language ID to another language,  
               ' change the msoLanguageID value here to a  
               ' different language.  
               shp.TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            
           End If
           End If
       Next
   Next
End Sub