Per batch oder script dateien über mehrere ordner zusammenführen.

@echo off & setlocal
set "Quelle=E:\"  
set "Ziel=D:\Videos\"  

for /f "delims=" %%i in ('dir /s /b /a-d "%Quelle%*.tpr" 2^>nul') do call :ProcessFile "%%i"  
pause
goto :eof

:ProcessFile
pushd "%~dp1"  

set "Name=%~n1"  
set "Name=%Name:&={%"  

for /f "delims=" %%d in ("%cd%") do set "Zielname=%Ziel%%%~nxd_%~nx1"  

set "Befehl=copy /b "%Name%%~x1%""  
for /f "delims=" %%d in ('dir /b /on "%~n1.0*"') do call :ProcessName "%%d"  
echo %Befehl:{=&% "%Zielname%"  

popd
goto :eof

:ProcessName
set "Befehl=%Befehl%+"%Name%%~x1""  
goto :eof

@echo off & setlocal

set "SrcDir=E:\Test"  
set "DestDir=E:\Ziel"  
set "FileExt=tpr"  

for /f "delims=" %%f in ('dir /s /b /a:-d "%SrcDir%\*.%FileExt%" 2^>NUL') do (  
  call :GetParentFolder "%%~dpf"  
  call :CopyMainPart "%%f"  
  call :AppendSubParts "%%f"  
)

exit /b



:GetParentFolder
  pushd "%~1"  
  for %%p in ("%CD%") do set "ParentFolder=%%~nxp"  
  popd
exit /b


:CopyMainPart
  echo copy "%~1" "%DestDir%\%ParentFolder% - %~nx1"  
exit /b


:AppendSubParts
  for /f "delims=" %%p in ('dir /b /a:-d /o:e "%~dpn1.*" 2^>NUL ^| findstr /v /e /c:"%~nx1"') do (  
    echo copy /b "%DestDir%\%ParentFolder% - %~nx1"+"%~dp1%%p" "%DestDir%\%ParentFolder% - %~nx1"  
  )
exit /b