Text zwischen zwei Zeichenketten ausgeben

Hallo liebe Leute,

ich habe derzeitig mir zur Aufgabe gemacht aus einer HTML Seite, die ich per wget runterlade, einen bestimmten Bereich auszulesen.
Dieser Bereich wird durch zwei Wörter Abgegrenzt die sich nicht verändern, der Bereich dazwischen jedoch schon.

Beispiel:
<p><strong>Obst</strong></p>Apfel,Birne,Erdbeere<p><strong>Gemüse</strong></p>Apfel, Melone, Gurke, Salat

Ich möchte nun alles in eine neue txt Datei bekommen, was zwischen Obst und Gemüse liegt, wenn es ein paar Zeichen mehr oder weniger sind ist das nicht so schlimm, hauptsache "Apfel,Birne,Erdbeere" sind vollkommen erhalten.

Das ganze würde ich gerne mit einer Batch Datei verwirklichen. Natürlich habe ich schon vorher gesucht und geschaut ob ich es selber hinkriege und bin auf Teile wie "for /F" gekommen, habe aber nicht so wirklich begriffen, wie das verwendet wird.

Ich hoffe ihr könnt mir helfen

Mit freundlichen Grüßen

Zappdidappdi

Dim SuchAnfang, SuchEnde

URLPfad = "http://de.wetter.yahoo.com/"  

SuchAnfang = Chr(34) & "day-temp-current temp-c " & Chr(34) & ">"  
SuchEnde = "&"  

Set Http=CreateObject("WinHttp.WinHttpRequest.5.1")  

Http.Open "GET",URLPfad,False  
Http.Send

temp = split(Http.ResponseText,SuchAnfang)
temp1 = split(temp(1),SuchEnde)
temp2 = temp1(0) & "°C"  

Wscript.Echo  temp2

Option Explicit

Const sURL = "http://www.ObstUndGemuese.de"  
Const sTxtFile = "C:\Test.txt"  

Dim oFso, oFile, oRE, oMatch, oSubMatch, sText
    
On Error Resume Next
    
With CreateObject("WinHttp.WinHttpRequest.5.1")  
   .Open "get", sURL, False  
   .send
   sText = .responseText
End With
       
If Err Then
    WScript.Echo "Webseite nicht verfügbar!":  WScript.Quit 1  
End If
    
On Error GoTo 0

Set oRE = New RegExp
Set oFso = CreateObject("Scripting.FileSystemObject")  

Set oFile = oFso.CreateTextFile(sTxtFile)

With oRE
    .Global = True
    .IgnoreCase = True
    .Pattern = "obst.*p>(.*)<p"  
End With
    
For Each oMatch In oRE.Execute(sText)
    For Each oSubMatch In oMatch.SubMatches
        oFile.WriteLine oSubMatch
    Next
Next

oFile.Close