calzoncillos
Apr 18, 2013
view2209
view10
0
Goto Top

Ordnernamen per Batch umbenennen bzw. übersetzen

GermansolvedQuestionBatch, ShellDevelopment

Hallo,
ich fotografiere gern und suche eine Möglichkeit, eine Batch-Datei in meinem Fotobearbeitungs-Workflow zu verwenden, um Ordnernamen unter Windows 7 64 Bit umzubenennen.

Nach dem die Fotos auf den Computer übertragen worden sind, verschiebe ich sie mit IrfanView in eine Archiv-Struktur:

F:\Fotos 2012\2012-05 May\2012-05-12 Sat\20120512-15120810.jpg
F:\Fotos 2012\2012-09 Sep\2012-09-04 Tue\20120904-10560783.jpg
F:\Fotos 2013\2013-01 Jan\2013-01-25 Wed\20130125-07271289.jpg

Das macht IrfanView sehr gut, leider kann es nur englische Monatsnamen und Wochentage schreiben. Eine Umstellung auf deutsch ist nicht möglich, wie ich im IrfanView-Forum erfahren habe.

Nun ist meine Idee, künftig eine Batch-Datei über den Ordner F:\Fotos 2013\ laufen zu lassen, die "übersetzt", also in den Ordnern bestimmte Teile umbenennt,

Mar => Mrz
May => Mai
Oct => Okt
Dec => Dez

Mon => Mo
Tue => Di
Wed => Mi
Thu => Do
Fri => Fr
Sat => Sa
Sun => So

um das hier hinzubekommen:

F:\Fotos 2012\2012-05 Mai\2012-05-12 Sa\20120512-15120810.jpg
F:\Fotos 2012\2012-09 Sep\2012-09-04 Di\20120904-10560783.jpg
F:\Fotos 2013\2013-01 Jan\2013-01-25 Mi\20130125-07271289.jpg

Hier im Board habe ich mich schon einen Batch-Ansatz gefunden:

echo off
Setlocal EnableDelayedExpansion
FOR /F %%i in ('dir /b /a:D') do set Name=%%i && rename

Jedoch habe ich keine Ahnung, wie ich die Umbennennungsbedinungen in diese Schleife bekommen kann.

Vielen Dank für eure Hilfe,
beste Grüße, Calzoncillos
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 205224

Url: https://administrator.de/contentid/205224

Printed on: April 19, 2024 at 01:04 o'clock

10 Comments
Latest comment
Goto Top
Member: colinardo
colinardo Apr 18, 2013 updated at 10:52:42 (UTC)
Goto Top
Hi Calzoncillos,
in Zeile 2 noch den Root-Ordner angeben in dem umbenannt werden soll.
@echo off & setlocal ENABLEDELAYEDEXPANSION
set Ordner=F:\Fotos 2013
for /f "tokens=*" %%i in ('dir "%Ordner%" /b /a:D') DO @(  
	set origName=%%i
	set Name=!origName:Mar=Mrz!
	set Name=!Name:May=Mai!
	set Name=!Name:Oct=Okt!
	set Name=!Name:Dec=Dez!
	set Name=!Name:Mon=Mo!
	set Name=!Name:Tue=Di!
	set Name=!Name:Wed=Mi!
	set Name=!Name:Thu=Do!
	set Name=!Name:Fri=Fr!
	set Name=!Name:Sat=Sa!
	set Name=!Name:Sun=So!
	rename "!origName!" "!Name!"  
)

Grüße Uwe

p.s. für solche Aufgaben gibt es auch schöne Programme die das übernehmen, wie z.B. Ant Renamer
Member: andimue
andimue Apr 18, 2013 at 10:53:38 (UTC)
Goto Top
Servus Calzoncillos,

eine kleine Änderung sollte am Skript von colinardo noch gemacht werden, damit auch die Unterordner umbenannt werden. Beim dir-Befehl habe ich noch ein /s eingebaut und die Verzeichnisauswahl auf alles beschränkt, was mit 20* anfängt.

Sieht dann so aus:

@echo off & setlocal ENABLEDELAYEDEXPANSION
for /f "tokens=*" %%i in ('dir 20* /s /b /a:D') DO @(  
	set origName=%%i
	set Name=!origName:Mar=Mrz!
	set Name=!Name:May=Mai!
	set Name=!Name:Oct=Okt!
	set Name=!Name:Dec=Dez!
	set Name=!Name:Mon=Mo!
	set Name=!Name:Tue=Di!
	set Name=!Name:Wed=Mi!
	set Name=!Name:Thu=Do!
	set Name=!Name:Fri=Fr!
	set Name=!Name:Sat=Sa!
	set Name=!Name:Sun=So!
	rename "!origName!" "!Name!"  
)

Gruß
Andi
Member: Calzoncillos
Calzoncillos Apr 18, 2013 updated at 11:45:46 (UTC)
Goto Top
Hallo!

Vielen Dank, colinardo und Andi, das ist ja echt Raketengeschwindigkeit mit der hier geantwortet wird!

Die "foto.bat" liegt in "F:\Fotos 2013\" aber leider funktioniert es noch nicht ganz 100%ig.

Bei colinardos Version benennt er zwar den Monatsordner um, aber nicht die Wochentage.
Bei Andis Version bekomme ich einen Syntaxfehler.

Könnt ihr bitte noch einmal drüber sehen?

Vielen Dank, Calzoncillos
Member: colinardo
colinardo Apr 18, 2013 updated at 12:16:21 (UTC)
Goto Top
da fehlten Anführungszeichen für den Ordner im Dir-Befehl (Leerzeichen im Ordnernamen würden sonst probleme machen)
@echo off & setlocal ENABLEDELAYEDEXPANSION
set Ordner=F:\Fotos 2013
for /f "tokens=*" %%i in ('dir "%Ordner%" /b /a:D') DO @(  
	set origName=%%i
	set Name=!origName:Mar=Mrz!
	set Name=!Name:May=Mai!
	set Name=!Name:Oct=Okt!
	set Name=!Name:Dec=Dez!
	set Name=!Name:Mon=Mo!
	set Name=!Name:Tue=Di!
	set Name=!Name:Wed=Mi!
	set Name=!Name:Thu=Do!
	set Name=!Name:Fri=Fr!
	set Name=!Name:Sat=Sa!
	set Name=!Name:Sun=So!
	rename "!origName!" "!Name!"  
)
Member: Endoro
Endoro Apr 18, 2013 at 11:52:31 (UTC)
Goto Top
Hallo Calzoncillos,

mal mit einem anderen Ansatz:

@echo off &setlocal enabledelayedexpansion
for /d /r %%i in (*) do (
set "name=%%~nxi"  
for %%a in (Mar=Mrz May=Mai Oct=Okt Dec=Dez Mon=Mo Tue=Di Wed=Mi Thu=Do Fri=Fr Sat=Sa Sun=So) do (
if defined repl (
call set "nname=%%name:!repl!=%%a%%"  
echo ren "%%~fi" "!nname!")  
if "!name:* %%a=!"=="" (set "repl=%%a") else set "repl="))
Wenn es OK ist, lösch das "echo" vor ren.

Gruss!
Member: andimue
andimue Apr 18, 2013 at 12:10:17 (UTC)
Goto Top
Hi,

der Ansatz mit rename kann glaube ich so garnicht funktionieren. Es müsste mit move gearbeitet werden.
Und ich habe so langsam auch meine Zweifel, ob das mit dem for-Loop so funktioniert. Der Code würde ja zuerst das übergeordnete Verzeichnis umbenennen und dann erst die Unterverzeichnisse beearbeiten. Zu dem Zeitpunkt ist ja aber das übergeordnete Verzeichnis schon umbenannt. Ob das dann klappt ... ?

Hab leider gearde nicht die Zeit es auszuprobieren

Andi
Member: Calzoncillos
Calzoncillos Apr 18, 2013 at 12:32:13 (UTC)
Goto Top
Hallo!

Endoros Ansatz hat leider nicht funktioniert face-sad

Andi, was du sagst leuchtet ein, ich hab das jetzt erst mal so gelöst:

@echo off & setlocal ENABLEDELAYEDEXPANSION
for /f "tokens=*" %%i in ('dir /b /a:D') DO @(  
	set origName=%%i
	set Name=!origName:Mar=Mrz!
	set Name=!Name:May=Mai!
	set Name=!Name:Oct=Okt!
	set Name=!Name:Dec=Dez!
	set Name=!Name:Mon=Mo!
	set Name=!Name:Tue=Di!
	set Name=!Name:Wed=Mi!
	set Name=!Name:Thu=Do!
	set Name=!Name:Fri=Fr!
	set Name=!Name:Sat=Sa!
	set Name=!Name:Sun=So!
	rename "!origName!" "!Name!"  
)

Da liegt die foto.bat zuerst in "F:\Fotos 2013\" und benennt im ersten Umlauf die Monate um.
Dann schiebe ich sie händisch in den jeweiligen Monat, lasse sie dort laufen und dann benennt sie dort die Wochentage um.

Das funktioniert so und ist für mich gut handhabbar. Großer Dank an alle Beteiligten!
Viele Grüße, Calzoncillos
Member: colinardo
colinardo Apr 18, 2013 at 12:32:46 (UTC)
Goto Top
Warum machen wir uns dauernd das Leben so schwer mit Batch ?? Es gibt doch bessere Programmiersprachen wo man nicht dauernd irgendwie einen Umweg braucht... wenn man doch sowieso in Windows arbeitet nehme man als Beispiel VBS:
setze deinen Root-Ordner in Zeile 2 und feddich ...
set objFSO= createobject("Scripting.FileSystemObject")  
EnumFolders "F:\Fotos 2013"  

Sub EnumFolders(byval Folder)
	set objFolder = objFSO.GetFolder(Folder)
	set colSubfolders = objFolder.Subfolders

	for each objSubfolder in colSubfolders
		NewFolderName = Replace(objSubfolder.name, "Mar", "Mrz")  
		NewFolderName = Replace(NewFolderName, "May", "Mai")  
		NewFolderName = Replace(NewFolderName, "Oct", "Okt")  
		NewFolderName = Replace(NewFolderName, "Dec", "Dez")  
		NewFolderName = Replace(NewFolderName, "Mon", "Mo")  
		NewFolderName = Replace(NewFolderName, "Tue", "Di")  
		NewFolderName = Replace(NewFolderName, "Wed", "Mi")  
		NewFolderName = Replace(NewFolderName, "Thu", "Do")  
		NewFolderName = Replace(NewFolderName, "Fri", "Fr")  
		NewFolderName = Replace(NewFolderName, "Sat", "Sa")  
		NewFolderName = Replace(NewFolderName, "Sun", "So")  
		
		If NewFolderName <> objSubFolder.Name Then
			objSubFolder.Name = NewFolderName
		End If
		enumfolders objSubfolder.path
	next

End Sub

Thema gegessen
face-wink
Member: Endoro
Endoro Apr 18, 2013 at 12:43:50 (UTC)
Goto Top
Zitat von @andimue:
Hi,

der Ansatz mit rename kann glaube ich so garnicht funktionieren.

Stimmt, die müssen vorher sortiert werden:
@echo off &setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /ad /s /b ^| sort /r') do (  
set "name=%%~nxi"  
for %%a in (Mar=Mrz May=Mai Oct=Okt Dec=Dez Mon=Mo Tue=Di Wed=Mi Thu=Do Fri=Fr Sat=Sa Sun=So) do (
if defined repl (
call set "nname=%%name:!repl!=%%a%%"  
ren "%%~fi" "!nname!")  
if "!name:* %%a=!"=="" (set "repl=%%a") else set "repl="))

Gruss!
Member: Calzoncillos
Calzoncillos Apr 18, 2013 at 13:00:51 (UTC)
Goto Top
Wow, Endoro!

Das Dingen funktioniert über Unterordner hinweg. Ich bin glücklich!

Viele Grüße,
Calzoncillos
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
AlexWishaHow to set up and configure a Linux GRE tunnelAlexWisha - 3 CommentsjstrickerWIREGUARD VPN ON UDM PRO BEHIND FRITZBOX - HANDSHAKE DID NOT COMPLETEjstricker - 1 CommentDaniEnd of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment