dschingis
Apr 25, 2013
view2042
view5
0
Goto Top

Favouriten im Internetexplorer automatisiert umschreiben

GermanQuestionWebbrowserInternet
Hallo zusammen. ich habe 100 PCs im unternehmen mit jeweils Favouriten im Internetexplorer (Der Zugriff aufs ERP-System erfolgt über den IE.)
Als Beispiel:
http://Servername/startseite
oder
http://Servername/seite1

Jetzt sollen die Favouriten umgeschrieben werden, da sich der servername verändern wird. Also z. B. in:

http://neuerserver/startseite
oder
http://neruerserver/seite1.

Dies soll automatisiert passieren, da ich nicht an 100 PCs alls Favourtien manuell umschreiben will.

Hat jemand eine Idee?

Vielen Dank schonmal!
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 205678

Url: https://administrator.de/contentid/205678

Printed on: April 25, 2024 at 08:04 o'clock

5 Comments
Latest comment
Goto Top
Member: DerWoWusste
DerWoWusste Apr 25, 2013 at 21:41:28 (UTC)
Goto Top
Hi.

Wo sind denn Deine Ideen?
Man kann GPOs nutzen, um neue Favoriten zu setzen und alte zu löschen.
Member: Pjordorf
Pjordorf Apr 25, 2013 at 21:57:56 (UTC)
Goto Top
Hallo,

Zitat von @Dschingis:
Dies soll automatisiert passieren, da ich nicht an 100 PCs alls Favourtien manuell umschreiben will.
Und warum dazu nicht einfach am DNS (Server) 2 Einträge setzen und fertig? Schau dir doch mal deine Einträge genauer an.
http://Servername/startseite
http://neuerserver/startseite

Dein DNS hat doch nunmal die Aufgabe Namen in IPs aufzulösenface-smile

Gruß,
Peter
Member: Patriot
Patriot Apr 26, 2013 at 05:36:37 (UTC)
Goto Top
Hallo,

ich persönlich würde mich auch DerWoWusste anschließen und das über GPOS setzen, die DNS umleitung empfinde ich als unsaubere Lösung.
Member: Joe2011
Joe2011 Apr 26, 2013 at 09:47:44 (UTC)
Goto Top
Hallo.

Solltest Du es über GPO nicht hinbekommen: per Login-Script die URL-Datei des angemeldeten Users aktualisieren lassen.

Gruß


Joe
Member: colinardo
colinardo Apr 26, 2013 at 09:58:41 (UTC)
Goto Top
Hallo Dschingis,

falls noch benötigt, könnte Dir mein VBS-Script weiterhelfen das ich mal geschrieben habe:
Einfach in Zeile 3 und 4 die Servernamen eingeben die in den URLs ersetzt werden sollen.
Das Script durchsucht alle Favoriten des Internet-Explorer, und auch alle eventuell angelegten Unterordner.
Set sh = WScript.CreateObject("Wscript.Shell")  
Set fso = WScript.CreateObject("Scripting.Filesystemobject")  
OLDSERVERNAME = "AlterServername"  
NEWSERVERNAME = "NeuerServername"  
FAVFOLDER = sh.RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\Favorites")  
Set folderFav = fso.GetFolder(FAVFOLDER)
parseFolders(folderFav)

Function parseFolders(fldr)
	dim found
	For each fav in fldr.Files
		If LCase(Right(fav.Name,3)) = "url" Then  
			Set objShortcut = sh.CreateShortcut(fav.Path)
			Set myRegExp = New RegExp
			myRegExp.IgnoreCase = True
			myRegExp.Pattern = ".*(" & OLDSERVERNAME & ").*"  
			Set myMatches = myRegExp.Execute(objShortcut.TargetPath)
			If myMatches.Count >= 1 Then
				objShortcut.TargetPath = Replace(objShortcut.TargetPath, OLDSERVERNAME, NEWSERVERNAME, 1, 1)
				objShortcut.Save
			End If
			Set objShortcut = Nothing
			Set myRegExp = Nothing
		End If	
	Next
	
	For Each subFolder in fldr.SubFolders
		parseFolders(subFolder)
	Next
End Function

Set sh = Nothing
Set fso = Nothing

Grüße Uwe
GermanQuestionWebbrowserInternet
Hotly discussed
gleixnerdCheck of ZFW Firewallgleixnerd - 5 CommentsjstrickerWireguard VPN on UDM Pro behind Fritzbox - Handshake did not completejstricker - 3 Comments