Vergleiche den Inhalt von 3 Verzeichnisse anhand des geändert am Datums und lösche die nicht Übereinstimmungen

@echo off & setlocal
set "V1=D:\Ordner"  
set "V2=D:\Anderer Ordner"  
set "V3=D:\Ganz anderer Ordner"  
set /a Anz=3

for /L %%i in (1,1,%Anz%) do (
    for /f "tokens=1-2" %%a in ('call dir /a-d "%%V%%i%%"^|findstr /b "[0-3][0-9]\.[0-1][0-9]\."') do >>%temp%\%%i.txt echo %%a %%b  
)

for /L %%i in (1,1,%Anz%) do (
    call pushd "%%V%%i%%"  
    call echo Bearbeite "%%V%%i%%"  
    for /f "delims=" %%f in ('dir /b/a-d') do (  
        set OK=true
        for /L %%j in (1,1,%Anz%) do findstr /lc:"%%~tf" "%temp%\%%j.txt">nul||set "OK="  
        if not defined OK echo del %%f
    )
    popd
)

@echo off&setlocal
set "V1=Verzeichnis1"  
set "V2=Verzeichnis2"  
set "V3=Verzeichnis3"  

for %%i in ("%V1%" "%V2%" "%V3%") do (  
	pushd "%%~i"  
	for %%j in (*) do for /f "tokens=1,2delims=:" %%a in ("%%~tj") do set "$%%~i|%%~j=%%a%%b"&set "#%%~i%%a%%b=%%a%%b"  
	popd
)
for %%i in ("%V1%" "%V2%" "%V3%") do for %%j in ("%V1%" "%V2%" "%V3%") do if "%%~i" neq "%%~j" (  
	for /f "tokens=1-3delims=$|=" %%a in ('set "$%%~i" 2^>nul') do (  
		setlocal enabledelayedexpansion
		set "test=!#%%~j%%~c!"   
		if not defined test (
			endlocal
			echo del "%%a\%%b"  
			set "$%%~a|%%~b="  
		) else endlocal
	)
)