rubberman
Goto Top

Makros in Batch - Wie man Code in Umgebungsvariablen nutzen kann

back-to-topInhalt

  1. Vorwort
  2. Was ist ein Makro?
  3. Wozu dienen Makros?
  4. Anleitung und Beispiele
    1. Wie arbeitet man mit Makros?
    2. Mehrzeilige Makros
    3. Wie kann man Werte an ein Makro übergeben?
  5. Vor- und Nachteile


back-to-top1. Vorwort

Hallo Community.

Nachfolgend werde ich euch eine Technik vorstellen, die ich auf DosTips gefunden habe und dort insbesondere von den Usern Ed Dyreen, jeb und dbenham vorangetrieben wurde. Es ist nicht unbedingt eine Technik für Batch-Anfänger aber eine unkonventionelle Möglichkeit mit Batchcode zu arbeiten. Vielleicht ist es ja für den Einen oder Anderen interessant ...

Grüße
rubberman


back-to-top2. Was ist ein Makro?

Der Begriff "Makro" ist der Programmiersprache C entlehnt. Dort lassen sich Werte und Code einer Zeichenfolge zuweisen. Der C Präprozessor führt dann vor der Kompilierung eine simple Textersetzung durch. Das heißt, überall wo diese Zeichenfolge im Code vorkommt, wird diese durch den vorher definierten Wert ersetzt.
Ähnliches kann man auch in Batch mittels normalen Umgebungsvariablen verwirklichen. Der Befehlsprozessor führt zu einem sehr frühen Zeitpunkt die Auflösung der Variable zum Wert aus (siehe Die Geheimnisse des Batch Zeilen Interpreters). Also, auch hier haben wir nichts anderes als eine Textersetzung, noch bevor die Kommandozeile ausgeführt wird.
Ich verwende den Begriff Makro also inoffiziell in diesem Sinne (eine Dokumentation von Microsoft wird man vergeblich suchen).


back-to-top3. Wozu dienen Makros?

Eigentlich nutzt sie bereits jeder, der mit Batch arbeitet. Wenn ein Wert mehrere Male im Code verwendet werden muss (z.B. der Pfad zu einer Datei) und dieser konstant bleibt, weist man ihn am Anfang des Codes einer Variablen zu und hat somit ein Makro definiert. Das vereinfacht die Wartung des Codes. Muss der Wert angepasst werden, so erfolgt das nur einmal im gesamten Code. Außerdem verbessert es die Lesbarkeit des Codes.
Aber zu diesem Zweck hätte ich diese Anleitung nicht schreiben brauchen face-wink Mir geht es im Folgenden darum, dass man eben auch Batchcode in eine Variable packen kann, der mehrere Male ausgeführt werden soll. Auch dabei hat man die selben Vorteile der Wart- und Lesbarkeit.


back-to-top4. Anleitung und Beispiele

back-to-top4.1. Wie arbeitet man mit Makros?
Im Grunde genauso wie mit jeder anderen Variablen. Man weist einer Variablen einen Wert mittels SET zu. Der Wert ist in diesem Fall allerdings Batchcode.
Simples Beispiel:
@echo off &setlocal

REM Makrodefinition:
set "alert=echo Ein Fehler ist aufgetreten!"  

REM Makroausführung:
%alert%

pause
Dieses Beispiel lässt das Potenzial erkennen. Immer dann, wenn in einem Code ein Fehler abgefangen wird und der Benutzer darüber benachrichtigt werden soll, wird die Variable in den Code gesetzt.

Man kann natürlich auch gleich mehrere Befehle hinein packen. Bspw. soll nach der Benachrichtigung auf Benutzereingabe gewartet und danach der Code abgebrochen werden:
set "alert2=echo Ein Fehler ist aufgetreten! & pause & goto :eof"  

%alert2%

back-to-top4.2. Mehrzeilige Makros
Das letzte Beispiel arbeitet mit "&" als Befehlsverknüpfung. Möchte man mehrere Kommandozeilen in ein Makro packen, dann müssen die Zeilenumbrüche mit in den Variablenwert. Ein Linefeed-Zeichen reicht zu diesem Zweck aus. Das muss allerdings vorher definiert werden (siehe hierzu Erzeugung von ESC,CR,LF und DEL mit reinem Batch).
set LF=^


set ^"\n=^^^%LF%%LF%^%LF%%LF%^^" &REM Zwei Leerzeilen erforderlich!  
Wir haben nun die Variable %\n% (wieder mal aus C entlehnt) zur Verfügung, die bei Verwendung mit dem SET Befehl dafür sorgt, dass ein Zeilenumbruch in der Variablen zu finden ist. Diese Definition ist natürlich nur einmalig durchzuführen und kann dann in mehreren Multiline-Makros verwendet werden.
Wie würde das alert2 Makro als Multiline aussehen?
set LF=^


set ^"\n=^^^%LF%%LF%^%LF%%LF%^^" &REM Zwei Leerzeilen erforderlich!  

set alert3=(%\n%
  echo Ein Fehler ist aufgetreten!%\n%
  pause%\n%
  goto :eof%\n%
)

%alert3%
Interessant wird das natürlich erst bei großen Codeblöcken.

back-to-top4.3. Wie kann man Werte an ein Makro übergeben?
Das ist tatsächlich etwas schwierig. Im Makro muss man eine Hilfsvariable definieren und der dazugehörige SET Befehl muss am Ende des Makros stehen. Das Problem dabei ist, dass die Verarbeitung dieser Variablen im Code davor passieren muss. Wie ist das möglich? Man kombiniert FOR /L mit 2 Schleifendurchläufen mit einem IF ELSE Statement. Dabei muss der ELSE Zweig zuerst abgearbeitet werden, in dem die Variablenzuweisung passiert.
Im folgenden Beispiel wird die auszugebende Meldung an das Makro alert4 übergeben:
set LF=^


set ^"\n=^^^%LF%%LF%^%LF%%LF%^^" &REM Zwei Leerzeilen erforderlich!  

set alert4=for /l %%i in (1 1 2) do if %%i==2 (%\n%
  setlocal EnableDelayedExpansion%\n%
  if defined var echo !var:~1!%\n%
  endlocal%\n%
  pause%\n%
  goto :eof%\n%
) else set var=

%alert4% Ein Fehler ist aufgetreten!
Das sieht zunächst komplizierter aus, als es tatsächlich ist. Verständlich wird es, wenn man die Variable in Zeile 14 auflöst. Der dort ausgeführte Code ist äquivalent zu folgendem Block:
for /l %%i in (1 1 2) do if %%i==2 (
  setlocal EnableDelayedExpansion
  if defined var echo !var:~1!
  endlocal
  pause
  goto :eof
) else set var= Ein Fehler ist aufgetreten!


back-to-top5. Vor- und Nachteile

Alles was man mit Hilfe solcher Code-Makros tun kann ist grundsätzlich auch über den Aufruf einer Subroutine möglich. Es gibt nur einen Vorteil gegenüber dieser Technik:
  • Makros sind schnell. Der Code ist bereits in den Speicher geladen und wird augenblicklich ausgeführt. Bei der Verwendung von Subroutinen muss der Befehlsinterpreter zunächst den gesamten Code parsen und nach der Einsprungmarke suchen. Je mehr Code, desto länger dauert das.
Es gibt aber eine ganze Reihe an Argumenten, die gegen die Verwendung von Makros sprechen. Die wichtigsten:
  • Die Lesbarkeit des Codes im Makro selbst leidet deutlich. Insbesondere durch Escapesequenzen, da das Einschließen von Variablenname und Wert in Anführungszeichen bei Multiline-Makros nicht möglich ist.
  • Zudem kommt, dass man etwas Übung braucht, um solche Makros zu schreiben.
  • Makros sind Umgebungsvariablen. 32767 Zeichen ist zwar die derzeitige Begrenzung für eine Umgebungsvariable, wobei du aber durch eine andere Einschränkung lediglich in der Lage bist 8191 Zeichen in eine Kommandozeile zu schreiben. Ist dein Makro zu groß, kannst du es entweder gar nicht erst definieren oder aber nicht ausführen. Unter XP gab es noch die Einschränkung von 32767 Zeichen für den gesamten Umgebungsblock. Gibt es nun nicht mehr, aber je größer dieser Block wird, umso langsamer wird erfahrungsgemäß die Verarbeitung.

Edit: Ergänzung in Punkt 4.3. vorgenommen.

Content-Key: 213296

Url: https://administrator.de/contentid/213296

Ausgedruckt am: 29.03.2024 um 13:03 Uhr