Word Dokument als Email senden

Habe ein Makro erstellt um das Dokument als Anhang zu senden. Nun sollte dies aber als PDF gesendet werden.


Sub EmailSenden()

Dim bStarted As Boolean
Dim oOutlookApp As Outlook.Application
Dim oItem As Outlook.MailItem
On Error Resume Next
If Len(ActiveDocument.Path) = 0 Then
MsgBox "Dokument muss erst gespeichert werden"
Exit Sub
End If
Set oOutlookApp = GetObject(, "Outlook.Application")
If Err <> 0 Then
Set oOutlookApp = CreateObject("Outlook.Application")
bStarted = True
End If
Set oItem = oOutlookApp.CreateItem(olMailItem)
With oItem
ActiveDocument.SendMail
.Subject = "Word Test Dokument als Anhang versenden, WGM"
.Attachments.Add Source:=ActiveDocument.FullName, _
Type:=olByValue, _
DisplayName:="Dokument als Attachment"
.Body = "Besten Dank für Ihren Auftrag." & Chr(13) & _
"Mit freundlichen Grüssen" & Chr(13) _

.Send
End With
If bStarted Then
oOutlookApp.Quit
End If
Set oItem = Nothing
Set oOutlookApp = Nothing
End Sub


Bin auf Hilfe angewiesen, da ich keine Ahnung von Makro seit Office2003 habe. Wir Benutzen Office 2007 und Ofice2013.
Dieses Makro habe ich mit verschiedenen Forenbeiträgen zusammen gezimmert! Und es funktioniert, aber als Word Datei.


Danke!

Sub SendMailasPDF()
    If ActiveDocument.Path = "" Then  
        MsgBox "Dokument muss erst gespeichert werden!", vbExclamation  
        Exit Sub
    End If
    Set objOL = CreateObject("Outlook.Application")  
    strTempPath = Environ("TEMP")  
    strFileNameNoExtension = Mid(ActiveDocument.Name, 1, InStrRev(ActiveDocument.Name, ".", -1, vbTextCompare) - 1)  
    strPDFPath = strTempPath & "\" & strFileNameNoExtension & ".pdf"  
    ActiveDocument.SaveAs2 FileName:=strPDFPath, FileFormat:=wdFormatPDF
    Set objMail = objOL.CreateItem(0)
    With objMail
        .Subject = "Dein Betreff"  
        .Body = "Mit freundlichen Grüßen"  
        .Attachments.Add strPDFPath
        .Display
    End With
    Set objOL = Nothing
End Sub