ACL Datenbank erstellen

' **************************************************  
' * HINWEISE: Auslesen der Berechtigung von Dateien / Ordnern  
' **************************************************  
dim sec(32)
dim art(4)
' Array um Rechte Bits in Lesbare Form umzusetzen  
sec(0)="Lesen"  
sec(1)="Schreiben"  
sec(2)="Anfügen"  
sec(3)="Lesen (Extended)"  
sec(4)="Schreiben (Extended)"  
sec(5)="Ausführen"  
sec(6)="Löschen"  
sec(7)="Attribute Lesen"  
sec(8)="Attribute Schreiben"  
sec(9)="9"  
sec(10)="10"  
sec(11)="11"  
sec(12)="12"  
sec(13)="13"  
sec(14)="14"  
sec(15)="15"  
sec(16)="Löschen (Force)"  
sec(17)="Sicherheit lesen"  
sec(18)="ACL Schreiben"  
sec(19)="Besitz übernehmen"  
sec(20)="Synchronisieren"  
sec(21)="21"  
sec(22)="22"  
sec(23)="23"  
sec(24)="24"  
sec(25)="25"  
sec(26)="26"  
sec(27)="27"  
sec(28)="28"  
sec(29)="29"  
sec(30)="30"  
sec(31)="31"  
art(0)="Erlaubnis"  
art(1)="Verbot"  
art(2)="Audit"  
' Benötigte Objekte erstellen  
Set fso = CreateObject("Scripting.FileSystemObject")  
Set wshnet = CreateObject("WScript.Network")  
sDatei = InputBox("Name der Datei oder Verzeichnis?","Dateiauswahl","D:\temp8")  
wscript.echo Time()
If fso.FolderExists(sDatei) then
	Rechte sDatei
	VerzDurchgang(fso.getfolder(sDatei))
else
	wscript.echo Rechte(sDatei)
End If
wscript.echo Time()


' ***********************************  
' ***** Funktionen & Prozeduren *****  
' ***********************************  

Function Rechte(sDatei)
	' Verbindung zur Windows Managment Instrumentation herstellen und ACL Objekt erhalten  
	sConnect = "winmgmts:Win32_LogicalFileSecuritySetting='" & sDatei & "'"  
	Set oDatei = GetObject(sConnect)
	status = oDatei.getsecurityDescriptor(oDescriptor)
	oACL = oDescriptor.Properties_.Item("dacl").Value  
	list = sDatei & vbcrlf
	'  Alle Einträge durchgehen und Ausgabe zusammenbasteln  
	For each entry in oACL
		list = list & entry.Trustee.SIDString & vbcrlf & entry.Trustee.Name & ":" & entry.AccessMask & " - " & art(entry.ACEType) &  vbCrLf & secText(entry.AccessMask)  
	Next
	Wscript.echo list
	Wscript.echo "--------------------------------"  
End Function

Function SecText(binary)
	For x = 0 to 30
		If (binary And 2^x)<>0 then
			sTemp = sTemp & CStr(x) & ":" & CStr(sec(x)) & vbCrLf  
		End If
	Next
	SecText = sTemp
End Function

Sub VerzDurchgang(Verzeichnis)
 ' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen  
 On Error Resume Next
 FilesDurchgang Verzeichnis
 For each folder in Verzeichnis.Subfolders
  '***** Was jetzt tun? -> Rechte auslesen  
  call Rechte(folder.Path)
  VerzDurchgang folder
 Next
End Sub

Sub FilesDurchgang(Verzeichnis)
' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen  
On Error Resume Next
 For each file in Verzeichnis.files
 	' ***** Was jetzt tun? Rechte auslesen  
	Call Rechte(file.Path)
 Next
End Sub

' **************************************************  
' *  
' * VBScript Quelldatei -- erstellt mit Scripting Spy 3.0  
' *  
' *  
' *  
' * HINWEISE: Auslesen der Berechtigung von Dateien / Ordnern  
' *  
' **************************************************  

' Kommandozeilenparamter  
Set args = Wscript.Arguments
'***** Test ob richtige Anzahl an Kommandozeilenparametern angegeben wurde  
If args.Count <> 1 Then
    Wscript.echo "Bitte den Startpunkt (Datei oder Ordner) angeben!"  
    Wscript.Quit
End If
sDatei = args(0)
' Array, um die Art des Eintrags zu ermitteln  
dim art(4)
art(0)="Erlaubnis"  
art(1)="Verbot"  
art(2)="Audit"  
' Dictionary, um die Zahlen in Texte zu übersetzen  
' Es können beliebige weitere eingetragen werden  
Set dict = CreateObject("Scripting.Dictionary")  
call dict.add(2032127,"Full")  
call dict.add(1245631,"Change")  
call dict.add(1179817,"Read")  
' Sonstige benötigte Objekte erzeugen  
Set fso = CreateObject("Scripting.FileSystemObject")  
Set wshnet = CreateObject("WScript.Network")  
' Bei Eingabe einer Einzel-Datei werden nur die Rechte der Einzeldatei ausgegeben  
' Bei Angabe eines Verzeichnisses alle Unterverzeichnisse (inklusive des Startverzeichnisses  
If fso.FolderExists(sDatei) then
	Rechte sDatei
	VerzDurchgang(fso.getfolder(sDatei))
else
	wscript.echo Rechte(sDatei)
End If


' ***********************************  
' ***** Funktionen & Prozeduren *****  
' ***********************************  

Function Rechte(sDatei)
	sConnect = "winmgmts:Win32_LogicalFileSecuritySetting='" & sDatei & "'"  
	Set oDatei = GetObject(sConnect)
	status = oDatei.getsecurityDescriptor(oDescriptor)
	oACL = oDescriptor.Properties_.Item("dacl").Value  
	For each entry in oACL
		list = sDatei & ";" & entry.Trustee.Name & ";" & entry.Trustee.SIDString & ";" & art(entry.ACEType) & ";"  
		' Jetzt noch die Übersetzung der Accessmask, dabei Abfrage, falls unbekannte Zahlen auftauchen  
		If dict.Exists(entry.Accessmask) then
			list = list & dict.item(entry.Accessmask)
		Else
			list = list & "Spezielle Berechtigung: " & entry.Accessmask  
		End If
		Wscript.echo list
	Next
End Function

Sub VerzDurchgang(Verzeichnis)
 ' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen  
 On Error Resume Next
 ' Da wir keine Einzeldateien wollen, den Datei-Durchgang auskommentiert, daher werden nur Ordner gemacht	  
 ' FilesDurchgang Verzeichnis  
 For each folder in Verzeichnis.Subfolders
  '***** Was jetzt tun?  
  call Rechte(folder.Path)
  VerzDurchgang folder
 Next
End Sub

Sub FilesDurchgang(Verzeichnis)
' ***** Fehlerhandling abschalten, wegen Zugriffsverletzungen  
On Error Resume Next
 For each file in Verzeichnis.files
 	' ***** Was jetzt tun?  
	call Rechte(file.Path)
 Next
End Sub