matze-pe
Goto Top

Batch - Dateien verschieben, bis auf die von den letzten 3 Tagen

Hallo,
ich programmiere einen Batch, der mir alle Dateien (etwa 10 Tage alt ) in ein anderes Verzeichnis verschiebt, es müssen aber die Dateien von den letzten 3 Tagen im Quellverzeichnis erhalten bleiben.

Hier habe ich schonmal was erstellt, der mir alle Dateien in TXT umwandelt und die Dateien verschiebt.


move C:\Sicherung\*.* D:\Sicherung\

ren D:\Sicherung\*.* "*.txt"


Es müssen nur noch die letzten 3 Tage im Ordner erhalten bleiben.


LG
Matze

Content-Key: 74899

Url: https://administrator.de/contentid/74899

Ausgedruckt am: 29.03.2024 um 11:03 Uhr

Mitglied: 27234
27234 30.11.2007 um 13:48:35 Uhr
Goto Top
Hallo,

diese Thematik wurde hier schon des öfteren durchgekaut, suche mal nach "Dateien löschen" bzw. "DelAge32".
Ich würde das Programm "DelAge32" bevorzugen.

Gruß - René
Mitglied: bastla
bastla 30.11.2007 um 16:26:43 Uhr
Goto Top
Hallo matze-pe!

Beiden Empfehlungen von Bolle97 kann ich mich anschließen, vor allem, wenn das nicht hilft:
@echo off & setlocal
set /a MindestAlter=3
set "Quelle=C:\Sicherung\*.*"  
set "Ziel=D:\Sicherung"  

set "AG=%temp%\Age.vbs"  
echo A=DateDiff("d", CreateObject("Scripting.FileSystemObject").GetFile(WScript.Arguments(0)).DateLastModified, Now):WScript.Echo A>"%AG%"  
for %%i in ("%Quelle%") do for /f %%a in ('cscript //nologo "%AG%" "%%i"') do if %%a gtr %MindestAlter% echo move "%%i" "%Ziel%\%%~ni.txt"  
del "%AG%"  
Hinweis: Bei der Angabe des Zieles bitte keinen abschließenden "\" verwenden (auch nicht, falls das Ziel ein Rootverzeichnis, zB "E:\" wäre - in diesem Fall nur "E:" schreiben).

Kurze Erklärung zum Ablauf:
Das temporäre VBScript "%temp%\Age.vbs" wird für jede Datei im Quellordner aufgerufen, ermittelt deren heutiges Alter in Tagen und gibt dieses aus.
Die Ausgabe des Scripts wird über eine "for"-Schleife in die Variable "%%a" übernommen, was in weiterer Folge den Vergleich auf das Überschreiten des angegebenen Mindestalters ermöglicht.
Wenn das Mindestalter überschritten wurde, kann das Umbenennen auf "*.txt" vom dann auszuführenden "move"-Befehl gleich mit erledigt werden.

Abschließend noch die bei derartigen Verschiebeaktionen unvermeidliche Warnung: Falls im Zielordner bereits eine gleichnamige Datei vorhanden ist, wird diese kommentarlos überschrieben!

[Edit] Zur Sicherheit habe ich (so wie miniversum unten) auch noch vor das "move" ein "echo gesetzt, damit die Verschiebe-Befehle nur angezeigt werden und erst, wenn Du das "echo" herausnimmst, tatsächlich erfolgen. [/Edit]

Grüße
bastla
Mitglied: miniversum
miniversum 01.12.2007 um 12:36:56 Uhr
Goto Top
Hier mal ne Reine Batch Lösung. Zum wirklichen verschieben das ECHO entfernen. Bitte erst Testen!!
@echo off & setlocal enabledelayedexpansion
Set "Quelle=C:\Sicherung"  
Set "Quellfilter=*.*"  
Set "Ziel=D:\Sicherung"  
Set "Jahrrueck=0"  
Set "Monatrueck=0"  
Set "Tagrueck=3"  


FOR /F "tokens=1-3 delims=.: " %%A in ('echo %Date%') do (  
set /a JJJJ=%%C-%Jahrrueck%
set /a MM=%%B-%Monatrueck%
set /a TT=%%A-%Tagrueck%
)
Set NeusteDatei=%JJJJ%%MM%%TT%
FOR /R %Quelle% %%F in (%Quellfilter%) do (
set "FullFileName=%%~fF"  
FOR /F "tokens=1-3 delims=.: " %%A in ('echo %%~tF') do set FileTime=%%C%%B%%A  
if !FileTime! lss %NeusteDatei% (
ECHO move "!FullFileName!" "%Ziel%"  
)
)

miniversum
Mitglied: bastla
bastla 01.12.2007 um 13:00:45 Uhr
Goto Top
@miniversum

Vielleicht solltest Du noch ergänzen, dass Dateinamen mit "!" in Namen oder Pfad nicht verschoben werden können, weil in der Verarbeitung das "!" weg fällt.

Einer der Gründe, warum ich in diesem Fall lieber VBScript einsetze, wird gerade heute ganz deutlich: Das von Deinem Batch berechnete Vergleichsdatum "Heute - 3 Tage" (%NeusteDatei%) wird mit "200712-2" ermittelt, was sich zwar auch per Batch in den Griff kriegen lässt, aber eben zusätzlichen Aufwand erfordert.
@matze-pe
miniversums's Hinweis hinsichtlich des Testens möchte ich auch nochmals betonen - insbesondere wegen des automatischen Überschreibens im Zielordner! (Zur Sicherheit setze ich bei meinem Entwurf auch noch ein entsprechendes "echo" zum "Entschärfen" vor das "move".)

Grüße
bastla
Mitglied: matze-pe
matze-pe 01.12.2007 um 14:27:44 Uhr
Goto Top
wunderbar, vielen Dank das funktioniert schon richtig gut.

wo setzte ich denn im skript von miniversum den befehl

ren D:\Sicherung\*.* "*.txt"

zum umbennen der dateien in Textdateien ein?


Vielen Dank

LG
Matze
Mitglied: miniversum
miniversum 01.12.2007 um 17:09:19 Uhr
Goto Top
@bastla
Ja stimmt eine Fehlerbehandlung bzw. das Umrechnen beim überschreiten einer Monats-, Wochen- oder Tagengrenze Fehlt hier.
Die Dateinamen mit ! habe ich vergessen zu erwähnen. Sollten welche vorkomme könnte man die Klammer auch durch ein call ersetzen und so das ganze umbauen. Auch bei Dateiennamen mit Umlauten könnte es ja prinzipiell Probleme geben.
Außerdem sollte geprüft werden ob das Datum der Erstellung oder der letzten Änderung verwendet wird, sollte sich das unterscheiden.
Die Batch war auch nur exemplatisch gedacht und als Hinnweis wie es gehen könnte. Ich benutze die Batch ähnlich, nur das ich in meinem Fall den ersten Teil mit dem aktuelles Datum-Anzahl Tage nicht habe. Ich gebe in meiner Verwendung ein absolutes Datum an abdem Alles was älter ist verarbeitet wird. Diese absolute Datumsangabe landet dann direkt in der Variablen %NeusteDatei%. Daher habe ich den Anfangsteil auch zugegebenermaßen auf die schnelle und dadurch etwas vernachlässigt zusammengebastelt. Daher auch der dringende Hinnweis von mit es zu testen vorher!


@matze-pe
Jeder Verarbeitungsschritt der mit diesen Dateien durchgeführt werden soll die älter sind gommt in de Klammer vom If. Also da wo auch die Zeile mit dem move steht.

miniversum
Mitglied: bastla
bastla 01.12.2007 um 17:27:44 Uhr
Goto Top
@miniversum
Hinsichtlich des "!"-Problems hätte ich noch folgende Variante Deiner Schleife ohne "delayedexpansion":
FOR /R %Quelle% %%F in (%Quellfilter%) do (
	FOR /F "tokens=1-3 delims=.: " %%A in ('echo %%~tF') do if "%%C%%B%%A" lss "%NeusteDatei%" (  
		ECHO move "%%F" "%Ziel%\%%~nF.txt"  
	)
)
Damit wird auch gleich das Umbenennen erledigt. Wegen der Umlaute sollte es eigentlich keine Probleme geben.

@matze-pe
Mit der Idee, immer alle (zumeist ohnehin schon mit der Endung ".txt" versehenen) Dateien des Zielordners (nochmals) umzubenennen, kann ich mich nicht anfreunden - eigentlich sollte es genügen, den Typ beim Verschieben mit "move" anzupassen.

Wenn Du dennoch gesteigerten Wert auf das ren D:\Sicherung\*.* "*.txt" legst, dann brauchst Du es aber trotzdem nur einmal, und solltest es daher nach der Schleife in eine zusätzliche Zeile stellen.

Grüße
bastla
Mitglied: matze-pe
matze-pe 03.12.2007 um 15:55:58 Uhr
Goto Top
ok, vielen Dank.

Ich mache dann einen zusätzlichen Skript, der mir nach dem move die Dateien umbenennt.


LG
Matze
Mitglied: Biber
Biber 03.12.2007 um 18:23:58 Uhr
Goto Top
Moin matze-pe,

Nachfrage:
ok, vielen Dank.

Ich mache dann einen zusätzlichen Skript...

Darf ich das so interpretieren, dass die eigentliche Frage beantwortet ist und
  • einer von uns beiden einen grünen "Gelöst"-Haken setzen könnte und
  • der andere danach diesen Beitrag schließen darf?

Grüße
Biber
[Edit 2.1.2008] Tja, gab keine Antwort. Vielleicht war die Nachfrage zu komplex. Egal, dann schliesse ich den Thread "ohne Status". [/Edit]