text auslesen und Excel-Datei erstellen

Hallo zusammen,


ich habe mehrere Textdateien Z.B. 12345AB1.txt in einem Verzeichnis z.B. C:\Test Es handelt sich um Pläne und ich bräuchte eine Tabelle bzw. Übersicht über die Inhalte der Pläne.

innerhalb der Dateien gint es 2 Zeilen (nicht untereinander) die die Informationen enthalten die ich brauche

PlanInformations=EG Wand 3, Massiv
SelectedPaperName=A3

lautet.

Planinformations= ist in allen Dateien gleich. Dahinter kommen verschiedene Texte und Textlängen
SelectedPaperName=ist in allen Dateien gleich. Dahinter kommen verschiedene Texte und Textlängen

Der Dateiname, die ersten 5 Zahlen z.B. 12345 stehen für einen Index (Bauobjekt)
die letzten 3 Stellen bezeichnen die Plannummer

ich bräuchte nun eine Übersicht über die vorhandenen Plänen (ca: 200 - 300 pro Bauobjekt) am besten als Excel-Datei. Eine Textdatei tut es aber auch

in etwa so:

Bauobjekt: 12345

Plannummer ; Planinformation ; SelectedPaperName

AB1 ; EG Wand 3, Massiv ; A3

Hoffentlich ist es verständlich, und jemand kann mir helfen.

Danke.

Grüße Matthias

@echo off & setlocal
set "Basis=C:\Test"  
set "Ext=*.txt"  
set "CSV=C:\Test\CSV"  

set "M1=Planinformations="  
set "M2=SelectedPaperName="  

if not exist "%CSV%" md "%CSV%"  
::Dateien immer neu erstellen, da ansonsten Zeilen mehrfach eingetragen werden
del "%CSV%\*.csv"  

for /f "delims=" %%i in ('dir /b /on "%Basis%\%Ext%"') do call :ProcessFile "%Basis%\%%i"  
goto :eof

:ProcessFile
set "FName=%~n1"  
set "Index=%FName:~0,5%  
set "Plan=%FName:~5,3%  
set "PFile=%CSV%\%Index%.csv"  

if exist "%PFile%" goto :WriteLine  
::Datei neu erstellen
echo Bauobjekt: %Index%>"%PFile%"  
echo Plannummer;Planinformation;SelectedPaperName>>"%PFile%"  

:WriteLine
set "Line=%Plan%"  
for /f "tokens=2 delims==" %%a in ('findstr /i "%M1%" %1') do set "Line=%Line%;%%a"  
for /f "tokens=2 delims==" %%a in ('findstr /i "%M2%" %1') do set "Line=%Line%;%%a"  
echo %Line%>>"%PFile%"