Batch - setlocal EnableDelayedExpansion - ersetzen von Text, der ein Ausrufezeichen enthält

@echo off & setlocal EnableDelayedExpansion

call :FncReplaseString "foo" "bar" "d:\tmp\test.txt"  
goto :EOF

:FncReplaseString  {{comment_single_line_remark:0}}
::Parameters:   <FromString> <ToString> <FileName>
::        or:   <VarNameToReturnReplasedText> <FromString> <ToString> <TextToReplase>
  if not "%~4" == "" ( ::String im übergebenen Text austauschen  
    set _FncReplaseString_Text=%~4
    set %~1=!_FncReplaseString_Text:%~2=%~3!
    rem Alternativ dazu: call set %~1=%%_FncReplaseString_Text:%~2=%~3%%
  ) else if exist "%~3" ( ::String in einer Text-Datei austauschen  
    set _FncReplaseString_TmpFile=%TMP%\%~n0_out%RANDOM%.tmp
    for /F "tokens=1* delims=:" %%a in ('findstr /n $ %3') do (  
      if not "%%b" == "" (  
        set _FncReplaseString_TextLine=%%b
        set _FncReplaseString_TextLine=!_FncReplaseString_TextLine:%~1=%~2!
        echo.!_FncReplaseString_TextLine!
      ) else (echo.)
    ) >>!_FncReplaseString_TmpFile!
    move "!_FncReplaseString_TmpFile!" "%~3"  
  )
 exit /b 0

@echo off & setlocal EnableDelayedExpansion
set _x=Hallo^^!
echo _x=!_x!
------------------
Ausgabe: _x=Hallo!

@echo off

call :FncReplaseString "foo" "bar" "d:\tmp\test.txt"  
goto :EOF

:FncReplaseString  {{comment_single_line_remark:0}}
::Parameters:   <FromString> <ToString> <FileName>
::        or:   <VarNameToReturnReplasedText> <FromString> <ToString> <TextToReplase>
::Note:         "="-Characters are not allowed in FromString 
::Example:      call :FncReplaseString _Var "foo" "bar" "the foo"     (_Var="the bar") 
::              call :FncReplaseString "foo" "bar" "d:\text.txt"      (replase string in text-File) 
  setlocal DisableDelayedExpansion &::damit bei der Wertzuweisung keine Ausrufezeichen verloren gehen
  if "%~4" == "" goto :LEB_FncReplaseString_File  
  ::String im uebergebenen Text austauschen und der Variablen (%1) zuweisen
    set "_FncReplaseString_Text=%~4"  
    setlocal EnableDelayedExpansion  &::ermoeglicht die folgende Syntax
    set _FncReplaseString_Text=!_FncReplaseString_Text:%~2=%~3!
      rem Alternativ dazu: call set %~1=%%_FncReplaseString_Text:%~2=%~3%%
    ::die beiden oben und hier geoeffneten setlocal-Instanzen schließen & Variable uebernehmen:
    endlocal & set "_FncReplaseString_Text=%_FncReplaseString_Text%"  
    endlocal & set "%~1=%_FncReplaseString_Text%"  
   exit /b 0
   
  :LEB_FncReplaseString_File
  set _FncReplaseString_TmpFile=%TMP%\%~n0_out%RANDOM%.tmp
  if exist "%~3" ( ::String in einer Text-Datei austauschen  
    for /F "tokens=1* delims=:" %%a in ('type %3 ^| findstr /n $') do (  
    ::type konvertiert UC nach ANSI; findstr verhindert, dass Leerzeilen verloren gehen
      if not "%%b" == "" (  
        set _FncReplaseString_TextLine=%%b
        setlocal EnableDelayedExpansion  &::ermoeglicht die folgende Syntax
        set _FncReplaseString_TextLine=!_FncReplaseString_TextLine:%~1=%~2!
        echo.!_FncReplaseString_TextLine!
        endlocal &rem schließt die hier geoeffnete setlocal-Instanz
      ) else (echo.)
    ) >>%_FncReplaseString_TmpFile%
    move %_FncReplaseString_TmpFile% "%~3"  
  )
  endlocal &rem schließt die oben geoeffnete setlocal-Instanz
 exit /b 0

c:\>type test.reg > test_ansi.reg
c:\>notepad test_ansi.reg
  Über „Datei / Speichern unter“ im Feld „Codierung: Unicode“ auswählen und die Datei speichern.
c:\>comp test.reg test_ansi.reg
  Die Dateien sollten identisch sein (andernfalls sind durch die Konvertierung Daten verloren gegangen).