PDF Dateien nach Datum sortiert zusammenfügen

Hallo,

Ich bin schon seit Stunden auf der Suche, hab aber keine passende Lösung bzw. Batch für mein Problem gefunden.

Die Ausgangssituation ist folgende: Ich habe jeden Tag eine unterschiedliche Anzahl von PDF Dateien in einem Ordner, welche ich zu einem PDF Dokument zusammenfügen möchte.
Als Programm steht mir PDFTK zur Verfügung.
Die Schwierigkeit liegt bei mir darin, dass die Dateien chronologisch nach Datum sortiert werden müssen, desweiteren sind manche der PDF Dokumente bereits mehrseitig und dürfen wärend des Vorgangs nicht getrennt werden.
chronologisch sortiert bedeutet, dass die Dateien alle von einem Tag sind (meistens dem Vortag) und nach der Erstellungsuhrzeit sortiert werden müssen, wobei die erste Seite in der neuen PDF Datei auch die am frühesten erstellte einzel PDF Datei sein soll.

Tut mir Leid, ich hoffe ich habe mich nicht zu kompliziert ausgedrückt und ihr könnt mir bei meinem Problem helfen.

Vielen Dank im Voraus

MfG

Michele

@echo off & setlocal
set "quelle=C:\QuellVerzeichnis"  
set "ziel=C:\ZielVerzeichnis\Alle.pdf"  
set "skiped="  
FOR /F "delims=" %%i in ('Dir /B /OD "%quelle%\*.pdf"') do (  
if not exist "%ziel%" copy "%quelle%\%%~nxi" "%ziel%"  
set "skiped=skip=1 "  
)
FOR /F "%skiped%delims=" %%i in ('Dir /B /OD "%quelle%\*.pdf"') do (  
pdftk "%ziel%" "%quelle%\%%~nxi" cat output "%ziel%"  
)

@echo off & setlocal
set "quelle=C:\QuellVerzeichnis"  
set "ziel=C:\ZielVerzeichnis"  
set "gesamt=Alle.pdf"  
set "pdftk=C:\Programme\pdftk-1.12\pdftk.exe"  

set "t1=%temp%\Alle1.pdf"  
set "t2=%temp%\Alle2.pdf"  

FOR /F "delims=" %%i in ('Dir /B /O-D "%quelle%\*.pdf"') do set "erste=%%i"  
copy "%quelle%\%erste%" "%t1%">nul  
if exist "%t2%" del "%t2%"  
if not exist "%ziel%" md "%ziel%"  

FOR /F "skip=1 delims=" %%i in ('Dir /B /OD "%quelle%\*.pdf"') do (  
    if exist "%t1%" (  
        "%pdftk%" "%t1%" "%quelle%\%%~nxi" cat output "%t2%"  
        del "%t1%"  
    ) else (
        "%pdftk%" "%t2%" "%quelle%\%%~nxi" cat output "%t1%"  
        del "%t2%"  
    )
)

if exist "%t1%" copy "%t1%" "%ziel%\%gesamt%">nul  
if exist "%t2%" copy "%t2%" "%ziel%\%gesamt%">nul