darkwingduckk
Goto Top

Auflistung Rechner in Domäne

Hallo

Ich brauche einen Tipp, wie ich in 2 Batchdateien Rechner auflisten kann.
In der einen sollen alle Rechner aus der Domäne und in der 2. nur die, die bei der Onlineüberprüfung noch offline waren.
In meiner Hauptdatei soll dann durch eine Schleife immer wieder ein xcopy-Vorgang wiederholt werden, bis alle Rechner einmal das Packet bzw. die Datei bekommen haben.
Das xcopy-script habe ich schon. Nun brauch ich noch diesen Schleifenvorgang, der mit den 2 Listen "gefüttert" wird.
Danke im voraus für die Tipps

Lg dark

Content-Key: 116772

Url: https://administrator.de/contentid/116772

Ausgedruckt am: 29.03.2024 um 06:03 Uhr

Mitglied: 77559
77559 26.05.2009 um 09:54:51 Uhr
Goto Top
Hallo dark,

per Batch kann man viel einfacher Einträge einer Datei hinzufügen als wegnehmen, ich schlage also ein eListe aller und eine der erledigten Rechner vor.
Mit Findstr und einem Pingtest sollte das kein Problem sein.

:: Copy2Clients.cmd :::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off&CLS
Set ClientsALL="D:\Test\Workstations.txt"  
Set ClientsDone="D:\Test\WorkStDone.txt"  
If not Exist %ClientsDone% Echo #%Date%#>%ClientsDone%
For /f "Delims=" %%A in (  
  'Findstr /V /G:%ClientsDone% %ClientsALL%'  
    ) Do Call :PingTest %%A  
Goto :EOF
:PingTest
set Client=%1
if defined MS set "MS="  
for /F "tokens=3 delims==m^<" %%B in (  
  'ping -n 1 %Client% 2^>NUL ^|find "TTL" ') do Set "MS=%%B"  
if not defined MS @echo Client %Client% ist nicht erreichbar &goto :eof 
:: Mache dein Xcopy 
:: Call xcopybatch.cmd
(echo/%Client%)>>"%ClientsDone%"  
(echo/%Client% erledigt)
:: Copy2Clients.cmd :::::::::::::::::::::::::::::::::::::::::::::::::::

Gruß
LotPings

Bibers Wunsch ist mir Befehl face-wink Host durch Client ersetzt
Mitglied: Biber
Biber 26.05.2009 um 10:18:57 Uhr
Goto Top
... und ich würde zusätzlich alle Vorkommnisse von "Host" durch "Client" ersetzen.

Biber aka der Pingelige