Automatisierte Diashow

' ===========================================  
' Run this script with administrative rights!  
' ===========================================  



'/////////////////////////////// Configure script's job ///////////////////////////////  

'******************** Customize according to your specific needs **********************  

'------------------ Set event description and job related variables -------------------  

strEventDescription  = "New Picture File Creation"  
strMonitorFileSpec   = "C:\Users\Benutzer\Documents\Automatische Diashow\*.jpg"  
strPollingIntervall  = "1"  



'---------------- Prepare Monitor Filespec for WMI Event Filter query -----------------  

Set FSO              = CreateObject("Scripting.FileSystemObject")  

strDrive             = FSO.GetDriveName(strMonitorFileSpec)

strFileName          = FSO.GetFileName(strMonitorFileSpec)
intPathBegin         = Len(strDrive) + 1
intPathLen           = Len(strMonitorFileSpec) - Len(StrDrive) - Len(strFileName)
strPath              = Replace(Mid(strMonitorFileSpec, intPathBegin, intPathLen), "\", "\\")  

strExtension         = FSO.GetExtensionName(strMonitorFileSpec)

Set FSO              = Nothing



'----------------------------- Set WMI Event Filter query -----------------------------  

strEventFilterQuery  = "SELECT * FROM __InstanceCreationEvent" _  
                     & " WITHIN " & strPollingIntervall _  
                     & " WHERE TargetInstance ISA 'CIM_DataFile'" _  
                     & " AND TargetInstance.Drive='" & strDrive & "'" _  
                     & " AND TargetInstance.Path='" & strPath & "'" _  
                     & " AND TargetInstance.Extension='" & strExtension & "'"  



'-------------- Set WMI Namespace where the monitored event will occure ---------------  

strEventNamespace    = "root\Cimv2"  



'----------- Set parameters which should be passed to Event Handler script ------------  

strEventHandlerParam = """" _  
                     & "%TargetInstance.Drive%" _  
                     & "%TargetInstance.Path%" _  
                     & "%TargetInstance.FileName%" _  
                     & "." _  
                     & "%TargetInstance.Extension%" _  
                     & """"  

'**************************************************************************************  





'//////////////////////////////// Set script variables ////////////////////////////////  

'- Set Event Handler path, quote it and prepare it and its working directory for WMI --  

Set FSO           = CreateObject("Scripting.FileSystemObject")  

strEventHandlerWD = Replace(FSO.GetParentFolderName(WScript.ScriptFullName), "\", "\\")  

strEventHandler   = Replace(strEventDescription, " ", "") & "EventHandler.vbs"  
strEventHandler   = """" & strEventHandlerWD & "\\" & strEventHandler & """"  

Set FSO           = Nothing



'----------------------- Test for existing Event Handler script -----------------------  

Set FSO = CreateObject("Scripting.FileSystemObject")  

If Not FSO.FileExists(Replace(Replace(strEventHandler, "\\", "\"), """", "")) Then  
  MsgBox "The Event Handler script " & vbCRLF _  
          & Replace(strEventHandler, "\\", "\") & vbCRLF _  
          & "does not exist. Please create it.", _  
         vbExclamation, _
         "Missing Event Handler script"  
End If

Set FSO = Nothing



'-------------------------- Build parameters for CScript.exe --------------------------  

strCScriptParam = strEventHandler & " " & strEventHandlerParam  



'---------------- Get path of Windows Directory and prepare it for WMI ----------------  

Set WshShell    = WScript.CreateObject("WScript.Shell")  

strWinDir       = Replace(WshShell.ExpandEnvironmentStrings("%SystemRoot%"), "\", "\\")  

Set WshShell    = Nothing



'---------------------- Set path of CScript.exe prepared for WMI ----------------------  

setCScriptPath  = strWinDir & "\\System32\\cscript.exe"  





'////////////////////////// Install permanent Event Consumer //////////////////////////  

'------- Get WMI Scripting API object (SWbemServices), Namespace: Subscription --------  

strComputer                          = "."  
Set objWMIService                    = GetObject("winmgmts:" _  
                                                 & "{impersonationLevel=impersonate}!" _  
                                                 & "\\" & strComputer & "\root\Subscription")  



'------------------------------ Create the Event Filter -------------------------------  

Set objFilterClass                   = objWMIService.Get("__EventFilter")  
Set objFilter                        = objFilterClass.SpawnInstance_()

objFilter.Name                       = strEventDescription & " Event Filter"  
objFilter.EventNamespace             = strEventNamespace
objFilter.QueryLanguage              = "WQL"  
objFilter.Query                      = strEventFilterQuery

Set EventFilterPath                  = objFilter.Put_()



'----------------------- Create the Commandline Event Consumer ------------------------  

Set objEventConsumerClass            = objWMIService.Get("CommandLineEventConsumer")  
Set objEventConsumer                 = objEventConsumerClass.SpawnInstance_()

objEventConsumer.Name                = strEventDescription & " Commandline Event Consumer"  
objEventConsumer.CommandLineTemplate = setCScriptPath & " " & strCScriptParam  
objEventConsumer.ExecutablePath      = setCScriptPath
objEventConsumer.WorkingDirectory    = strEventHandlerWD
objEventConsumer.ShowWindowCommand   = 0

Set CommandlineEventConsumerPath     = objEventConsumer.Put_()



'------------------ Bind Event Filter to Commandline Event Consumer -------------------  

Set objBindingClass                  = objWMIService.Get("__FilterToConsumerBinding")  
Set objBinding                       = objBindingClass.SpawnInstance_()

objBinding.Filter                    = EventFilterPath
objBinding.Consumer                  = CommandlineEventConsumerPath

objBinding.Put_()

'***************************************************  
'Konfiguration  
'***************************************************  
scHost     = "Computername"  
scUser     = "Benutzername"  
scPassword = "Passwort"  
scDestDir  = "ZielverzeichnisZumVerschiebenAlterBilddateien"  



'***************************************************  
'Konstanten für Datei-IO  
'***************************************************  
icForReading               = 1
icForWriting               = 2
icAsUnicode                = -1


'***************************************************  
'Stringkonstanten  
'***************************************************  
'Zeitintervalle im Namen der zu verschiebenden Datei  
scMinute                   = "minute"  
scHour                     = "stunde"  
scDay                      = "tag"  

'Name der XML-Vorlagendatei für geplante Tasks  
scTaskXMLFile              = "MoveFile.xml"  


'***************************************************  
'Reguläre Ausdrücke zur Stringanalyse und -manipulation  
'***************************************************  
'Zur Analyse des Namens der neu erzeugten und später zu verschiebenden Datei  
scPictureFileNamePattern   = "([0-9]{1,})\s*(" & scMinute & "|" & scHour & "|" & scDay & ")"  

'Zur Manipulation der Author-Zeile  
'in der XML-Vorlagendatei für geplante Tasks  
scAuthorLinePattern        = "(\s*<Author>)[A-Z0-9_-]{1,}\\[A-Z0-9_-]{1,}(</Author>)"  

'Zur Manipulation der Date-, StartBoundary- und EndBoundary-Zeile  
'in der XML-Vorlagendatei für geplante Tasks  
scDatePattern              = "[0-9]{4}-[0-9]{2}-[0-9]{2}"  
scTimePattern              = "[0-9]{2}:[0-9]{2}:[0-9]{2}"  
scDateLinePattern          = "(\s*<Date>)"          & scDatePattern & "T" & scTimePattern & "\.[0-9]{1,}(</Date>)"  
scStartBoundaryLinePattern = "(\s*<StartBoundary>)" & scDatePattern & "T" & scTimePattern & "(</StartBoundary>)"  
scEndBoundaryLinePattern   = "(\s*<EndBoundary>)"   & scDatePattern & "T" & scTimePattern & "(</EndBoundary>)"  

'Zur Manipulation der Arguments-Zeile  
'in der XML-Vorlagendatei für geplante Tasks  
scArgumentsLinePattern     = "(\s*<Arguments>/c ""move "").{1,}("" "").{1,}(""""</Arguments>)"  


'***************************************************  
'Benötigte Objekte erzeugen, Variablen setzen  
'***************************************************  
'Shell- und FileSystemObject  
Set objFSO           = CreateObject("Scripting.FileSystemObject")  
Set objShell         = CreateObject("WScript.Shell")  

'Objekt für Reguläre Ausdrücke  
Set objRegExp        = New RegExp
objRegExp.Global     = False
objRegExp.IgnoreCase = True

'Pfad und Name der neu angelegten und später zu verschiebenden Datei  
'aus dem ersten übergebenen Parameter bestimmen  
strPictureFileName   = WScript.Arguments(0)

'Pfad, unter dem das Script gespeichert ist.  
'Hier muss auch die XML-Vorlagendatei für geplante Tasks abgelegt sein.  
'Die XML-Datei für den zu erzeugenden geplanten Task wird auch hier erstellt,  
'nach Verwendung aber sofort wieder gelöscht  
strActFolder         = objFSO.GetParentFolderName(WScript.ScriptFullName)

'Die aktuelle Zeit  
vntNow               = Now


'****************************************************  
'Aus dem Namen der neu erstellten Datei den Zeitpunkt  
'bestimmen, wann sie verschoben werden soll  
'****************************************************  
'Zahl und Intervall extrahieren  
objRegExp.Pattern = scPictureFileNamePattern
Set colMatches    = objRegExp.Execute(objFSO.GetBaseName(strPictureFileName))
intQuantity       = colMatches(0).SubMatches(0)
strInterval       = colMatches(0).SubMatches(1)

'Zeitpunkt zum Verschieben berechnen  
Select Case LCase(strInterval)
  Case scDay    strMoveDate = CStr(DateAdd("d", intQuantity, vntNow))  
  Case scHour   strMoveDate = CStr(DateAdd("h", intQuantity, vntNow))  
  Case scMinute strMoveDate = CStr(DateAdd("n", intQuantity, vntNow))  
End Select


'****************************************************  
'Pfad und Name der XML-Datei für den zu erzeugenden  
'geplanten Task zusammensetzen  
'****************************************************  
strNewTaskXMLFile = objFSO.BuildPath(strActFolder, objFSO.GetBaseName(scTaskXMLFile) & " " & objFSO.GetFileName(strPictureFileName) & " " & Replace(strMoveDate, ":", "-") & "." & objFSO.GetExtensionName(scTaskXMLFile))  


'***************************************************  
'Die XML-Vorlagendatei für geplante Tasks einlesen  
'***************************************************  
Set objXMLFile   = objFSO.OpenTextFile(objFSO.BuildPath(strActFolder, scTaskXMLFile), icForReading, False, icAsUnicode)
strScheduledTask = objXMLFile.ReadAll
objXMLFile.Close


'***************************************************  
'Die variabelen Zeilen mit konkreten Werten füllen  
'***************************************************  
'Die Author-Zeile (Ersteller des geplanten Tasks,  
'in diesem Fall immer das System-Konto)  
objRegExp.Pattern = scAuthorLinePattern
Set colSubMatches = objRegExp.Execute(strScheduledTask)(0).SubMatches
strScheduledTask  = objRegExp.Replace(strScheduledTask, colSubMatches(0) & scHost & "\System" & colSubMatches(1))  

'Die Date-Zeile (Zeitpunkt der Erstellung)  
objRegExp.Pattern = scDateLinePattern
Set colSubMatches = objRegExp.Execute(strScheduledTask)(0).SubMatches
strScheduledTask  = objRegExp.Replace(strScheduledTask, colSubMatches(0) & GetDateUS(vntNow) & "T" & GetTimeUS(vntNow) & ".0000000" & colSubMatches(1))  

'Die StartBoundary-Zeile (Zeitpunkt der Ausführung)  
objRegExp.Pattern = scStartBoundaryLinePattern
Set colSubMatches = objRegExp.Execute(strScheduledTask)(0).SubMatches
strScheduledTask  = objRegExp.Replace(strScheduledTask, colSubMatches(0) & GetDateUS(strMoveDate) & "T" & GetTimeUS(strMoveDate) & colSubMatches(1))  

'Die EndBoundary-Zeile (Zeitpunkt, zu dem der Task enden soll)  
'Wird auf den gleichen Wert wie die Start-Zeit gesetzt.  
'Dadurch wird der geplante Task sofort ungültig und wegen der  
'Einstellung "DeleteExpiredTaskAfter" mit dem Wert "PT0S"  
'(steht für "Sofort") direkt gelöscht.  
objRegExp.Pattern = scEndBoundaryLinePattern
Set colSubMatches = objRegExp.Execute(strScheduledTask)(0).SubMatches
strScheduledTask  = objRegExp.Replace(strScheduledTask, colSubMatches(0) & GetDateUS(strMoveDate) & "T" & GetTimeUS(strMoveDate) & colSubMatches(1))  

'Die Zeile mit den Argumenten für den CMD-Aufruf.  
'Es wird Pfad und Name der zu verschiebenden Datei  
'und das Zielverzeichnis eingetragen.  
objRegExp.Pattern = scArgumentsLinePattern
Set colSubMatches = objRegExp.Execute(strScheduledTask)(0).SubMatches
strScheduledTask  = objRegExp.Replace(strScheduledTask, colSubMatches(0) & strPictureFileName & colSubMatches(1) & scDestDir & colSubMatches(2))


'***************************************************  
'Die XML-Datei unter neuem Namen speichern  
'***************************************************  
Set objXMLFile = objFSO.OpenTextFile(strNewTaskXMLFile, icForWriting, True, icAsUnicode)
objXMLFile.Write strScheduledTask
objXMLFile.Close


'***************************************************  
'Unter Verwendung der erzeugten XML-Datei einen  
'geplanten Task anlegen. Der Benutzer, unter dessen  
'Kontext das aufgerufene Programm (CMD) ausgeführt  
'werden soll, und dessen Passwort MUSS hier über die  
'Parameter von SchTasks.exe gesetzt werden  
'***************************************************  
objShell.Run "schtasks /create /ru """ & scHost & "\" & scUser & """ /rp """ & scPassword & """ /tn """ & objFSO.GetBaseName(strNewTaskXMLFile) & """ /xml """ & strNewTaskXMLFile & """" , 0, True  


'***************************************************  
'Die XML-Datei wieder löschen  
'***************************************************  
objFSO.DeleteFile(strNewTaskXMLFile)


'-----------------------ENDE------------------------  




'***************************************************  
'Datumsstring im Format YYYY-MM-DD erzeugen  
'***************************************************  
Function GetDateUS(vntNow)
  GetDateUS = Year(vntNow) & "-" & Right("0" & Month(vntNow), 2) & "-" & Right("0" & Day(vntNow), 2)  
End Function


'***************************************************  
'Uhrzeitstring im Format HH:MM:SS erzeugen  
'***************************************************  
Function GetTimeUS(vntNow)
  GetTimeUS = Right("0" & Hour(vntNow), 2) & ":" & Right("0" & Minute(vntNow), 2) & ":" & Right("0" & Second(vntNow), 2)  
End Function

<?xml version="1.0" encoding="UTF-16"?>  
<Task version="1.3" xmlns="http://schemas.microsoft.com/windows/2004/02/mit/task">  
  <RegistrationInfo>
    <Date>0000-00-00T00:00:00.0000000</Date>
    <Author>Host\System</Author>
  </RegistrationInfo>
  <Triggers>
    <TimeTrigger>
      <StartBoundary>0000-00-00T00:00:00</StartBoundary>
      <EndBoundary>0000-00-00T00:00:00</EndBoundary>
      <Enabled>true</Enabled>
    </TimeTrigger>
  </Triggers>
  <Principals>
    <Principal id="Author">  
      <UserId>Host\User</UserId>
      <LogonType>S4U</LogonType>
      <RunLevel>HighestAvailable</RunLevel>
    </Principal>
  </Principals>
  <Settings>
    <MultipleInstancesPolicy>IgnoreNew</MultipleInstancesPolicy>
    <DisallowStartIfOnBatteries>false</DisallowStartIfOnBatteries>
    <StopIfGoingOnBatteries>false</StopIfGoingOnBatteries>
    <AllowHardTerminate>true</AllowHardTerminate>
    <StartWhenAvailable>true</StartWhenAvailable>
    <RunOnlyIfNetworkAvailable>false</RunOnlyIfNetworkAvailable>
    <IdleSettings>
      <StopOnIdleEnd>false</StopOnIdleEnd>
      <RestartOnIdle>false</RestartOnIdle>
    </IdleSettings>
    <AllowStartOnDemand>false</AllowStartOnDemand>
    <Enabled>true</Enabled>
    <Hidden>false</Hidden>
    <RunOnlyIfIdle>false</RunOnlyIfIdle>
    <DisallowStartOnRemoteAppSession>false</DisallowStartOnRemoteAppSession>
    <UseUnifiedSchedulingEngine>false</UseUnifiedSchedulingEngine>
    <WakeToRun>false</WakeToRun>
    <ExecutionTimeLimit>PT1H</ExecutionTimeLimit>
    <DeleteExpiredTaskAfter>PT0S</DeleteExpiredTaskAfter>
    <Priority>7</Priority>
    <RestartOnFailure>
      <Interval>PT1M</Interval>
      <Count>3</Count>
    </RestartOnFailure>
  </Settings>
  <Actions Context="Author">  
    <Exec>
      <Command>cmd</Command>
      <Arguments>/c "move "AAA.BBB" "CCC.DDD""</Arguments>  
    </Exec>
  </Actions>
</Task>

cscript /nologo Installer.vbs

scMonitoredFolder = "E:\Test"  
scDestFolder      = "E:\Ziel"  

Set objFSO = CreateObject("Scripting.FileSystemObject")  

Set objRegExp        = New RegExp
objRegExp.Global     = False
objRegExp.IgnoreCase = True
objRegExp.Pattern    = "([0-9]{4})-([0-9]{1,2})-([0-9]{1,2}).*\..*"  

intYearNow  = Year(Now)
intMonthNow = Month(Now)
intDayNow   = Day(Now)

For Each objFile In objFSO.GetFolder(scMonitoredFolder).Files
  Set colMatches = objRegExp.Execute(objFile.Name)

  If colMatches.Count > 0 Then
    intYearFile  = CInt(colMatches(0).SubMatches(0))
    intMonthFile = CInt(colMatches(0).SubMatches(1))
    intDayFile   = CInt(colMatches(0).SubMatches(2))

    If (intYearFile = intYearNow) And (intMonthFile = intMonthNow) And (intDayFile = intDayNow) Then
      objFile.Move(objFSO.BuildPath(scDestFolder, objFile.Name))
    End If
  End If
Next