Per batch herausfinden, ob das zu installierende programm x64 oder x86 lauffähig ist

@echo off &setlocal

call :get3264exe "%SystemRoot%\explorer.exe"  
echo Windows Explorer: %errorlevel% Bit

pause
goto :eof


:::::::::::::::::::
:get3264exe ExePath
setlocal DisableDelayedExpansion

REM Eingehender Parameter (*.exe Dateipfad)
set "infile=%~1"  

if not exist "%infile%" (endlocal &exit /b 0)  
if /i "%infile:~-4%" neq ".exe" (endlocal &exit /b 0)  

set "tmpf=%temp%\#.tmp~"  
set "dump=%temp%\##.tmp~"  

REM 1024 mal A in temporäre Datei schreiben.
>"%tmpf%" (for /l %%i in (1 1 1024) do <nul set /p "=A")  

REM HexDump der ersten 1024 Byte des Executables erstellen
setlocal EnableDelayedExpansion
set /a x=1
>"!dump!" (  
  for /f "skip=1 tokens=1,2 delims=: " %%i in ('fc /b "!infile!" "!tmpf!"^|findstr /vbic:"FC:"') do (  
    set /a y=0x%%i
    for /l %%k in (!x! 1 !y!) do echo 41
    echo %%j
    set /a x=y+2
  )
)
endlocal

REM Temporäre Datei löschen.
del "%tmpf%"  

REM Position der PE Signatur ermitteln.
<"%dump%" (  
  for /l %%i in (1 1 60) do set /p "="  
  set /p "PosPE1="  
  set /p "PosPE2="  
)
set /a "PosPE=0x%PosPE2%%PosPE1%"  

if %PosPE% gtr 1000 (
  REM Kein Executable.
  endlocal &exit /b 0
)

REM PE Signatur und Machine ermitteln
<"%dump%" (  
  for /l %%i in (1 1 %PosPE%) do set /p "="  
  set /p "PE1="  
  set /p "PE2="  
  set /p "PE3="  
  set /p "PE4="  
  set /p "Machine1="  
  set /p "Machine2="  
)


REM HexDump löschen.
del "%dump%"  

REM Prüfungen
set "Bit="  
if "%PE1%%PE2%%PE3%%PE4%"=="50450000" (  
  if "%Machine2%%Machine1%"=="8664" (  
    set "Bit=64"  
  ) else (
    set "Bit=32"      
  )
) else (
  REM PE Signatur nicht gefunden.
  endlocal &exit /b 0
)
REM Alles OK
endlocal &exit /b %Bit%

0x14d	Intel i860
0x14c	Intel I386 (same ID used for 486 and 586)
0x162	MIPS R3000
0x166	MIPS R4000
0x183	DEC Alpha AXP

IMAGE_NT_OPTIONAL_HDR32_MAGIC	0x10b 
IMAGE_NT_OPTIONAL_HDR64_MAGIC	0x20b.