Per Batch nach neuen Ordnern suchen

Ich möchte eine Batch schreiben mit der ich nach bestimmten Ordnern suchen kann, die eventuell neu angelegt worden sind.

Z.b.: Es existiert ein Ordner A. In diesem Ordner sind die Ordner A1, A2 und A3. Diese drei Ordner haben Unterordner, die aber nicht ausgwertet werden müssen.

Es soll nun mit der Batch überprüft werden ob eventuell ein Ordner A4, A5... angelegt worden ist. Wenn ja soll dies in einer txt gespeichert werden. In diesem Beispiel gehen wir davon aus das Ordner A4 und A5 neu angelegt worden sind. Diese stehen nun in der txt. Vielleicht sogar mit Pfandangabe?

Beim nächsten Scan soll nur noch nach den Ordner neuer als A5 gesucht werden und wiederrum das Ergebnis ist die txt überschrieben werden.

Es geht darum zu überprüfen wechle Ordner neu angelegt worden sind und vorallem wann.

Ich hoffe jemand kann mir helfen.

Habe einige Sachen gefunden, aber nicht das was ich leider benötige.

Gruß
Dorian

@echo off & setlocal
set "Ordner=D:\A"  
set "Liste=%Ordner%\Ordnerliste.txt"  
set "Neue=%Ordner%\Neu.txt"  

pushd "%Ordner%"  
del "%Neue%" 2>nul  
if not exist "%Liste%" type nul>"%Liste%"  
for /f "delims=" %%i in ('dir /b /ad^|findstr /i /v /g:"%Liste%"') do for /f "tokens=1-2" %%a in ('dir /tc "%%i"^|findstr /c:"\.\."') do (  
    >>"%Neue%" echo %%a %%b %%i  
    >>"%Liste%" echo %%i  
)
popd

>"%Liste%" dir /b /ad

@echo off & setlocal
> set "Ordner=D:\A"  
> set "Liste=%Ordner%\Ordnerliste.txt"  
> set "Neue=%Ordner%\Neu.txt"  
> 
> pushd "%Ordner%"  
> del "%Neue%" 2>nul  
> if not exist "%Liste%" type nul>"%Liste%"  
> for /f "delims=" %%i in ('dir /b /ad^|findstr /i /v /g:"%Liste%"') do for /f "tokens=1-2"  
> %%a in ('dir /tc "%%i"^|findstr /c:"\.\."') do (  
>     >>"%Neue%" echo %%a %%b %%i  
>     >>"%Liste%" echo %%i  
> )
> popd
> 

>"%Liste%" dir /b /ad
> 

@echo off & setlocal
set "Ordner=C:\A"  
set "Liste=%Ordner%\Ordnerliste.txt"  
set "Neue=%Ordner%\Neu.txt"  

pushd "%Ordner%"  
del "%Neue%" 2>nul  
if not exist "%Liste%" >"%Liste%" dir /b /ad  
for /f "delims=" %%i in ('dir /b /ad^|findstr /i /v /g:"%Liste%"') do for /f "tokens=1-2" %%a in ('dir /tc "%%i"^|findstr /c:"\.\."') do (  
    >>"%Neue%" echo %%a %%b %%i  
    >>"%Liste%" echo %%i  
)
popd
if exist "%Neue%" echo Neue Ordner: & type "%Neue%"