Batch - Ordner nach aktuellen Dateien durchsuchen und kopieren

>>"%logfile%" xcopy "%Quelle%" "%Ziel%" /D /Y   

@echo off &setlocal
set "fname="  
set "ftd="  
call:GetInternational
for /f "tokens=1-3*" %%a in ('dir /a-d /tw ^| findstr /b [0-9]') do set "ftd=%%a %%b"&set "fname=%%d"&call:process  
goto:eof

:process
rem Get file time:
set "fdate=%ftd:~0,10%"  
set "ftime=%ftd:~11%%sTime%00%sDecimal%00"  

call :GetSecs "%fdate%" "%ftime%" fileSecs  
call :GetSecs "%date%" "%time%" curSecs  
set /a elapsed="(curSecs-fileSecs)/60"  
if %elapsed% lss 60 if not exist "C:\Daten\xls_temp\%fname%" copy "%fname%" C:\Daten\xls_temp  
goto :eof

:GetInternational
:: Sets a bundle of variables by reading the registry settings
for /f "tokens=1,2*" %%a in ('reg query "HKCU\Control Panel\International"') do set "%%a=%%c"  
goto :eof

:GetSecs "dateIn" "timeIn" secondsOut 
::  Output:  Seconds elapsed since 1th Jan. 1970 00:00:00
setlocal
set "dateIn=%~1"  
for /f "tokens=2" %%i in ("%dateIn%") do set "dateIn=%%i"  
for /f "tokens=1-3 delims=%sDate%" %%a in ("%dateIn%") do (  
  if %iDate%==0 set /a mm=100%%a%%100,dd=100%%b%%100,yy=10000%%c%%10000
  if %iDate%==1 set /a dd=100%%a%%100,mm=100%%b%%100,yy=10000%%c%%10000
  if %iDate%==2 set /a yy=10000%%a%%10000,mm=100%%b%%100,dd=100%%c%%100
)
for /f "tokens=1-3 delims=%sTime%%sDecimal% " %%a in ("%~2") do (  
  set "hh=%%a"  
  set "nn=%%b"  
  set "ss=%%c"  
)
if 1%hh% lss 20 set hh=0%hh%
if /i "%nn:~2,1%" equ "p" if "%hh%" neq "12" (set "hh=1%hh%" &set /a hh-=88)  
if /i "%nn:~2,1%" equ "a" if "%hh%" equ "12" set "hh=00"  
if /i "%nn:~2,1%" geq "a" set "nn=%nn:~0,2%"  
set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2,j=j/5+dd+y*365+y/4-y/100+y/400-2472633,j=j*86400+hh*3600+nn*60+ss
endlocal &set "%~3=%j%"  
goto :eof

endlocal