Batch Ordner aus Dateinamen (erste 8 Zeichen) erstellen und Dateien verschieben

Hallo

Ich muss eine Ordnerstruktur anpassen und Dateien verschieben.

Aktuell habe ich viele Ordner, in denen jeweils ca. 100 Dateien sind. Die Dateien haben beispielsweise folgende Namen und Endungen:

XYZ12345_abe.jpg
XYZ12345_1dfdf.pdf
XYZ12345-zy.xls
XYZ55555.doc
XYZ55555_abe.ppt
abcde_1.xls
abcde.doc

Nun sollen in allen Ordnern jeweils für die Dateien mit den Dateinamen XYZ* Unterordner erstellt werden, und die entsprechenden Dateien dahin verschoben werden. Die Ordnernamen sollen dabei nur die ersten 8 Zeichen der Dateinamen sein. Das Ergebnis sollte dann folgendermassen aussehen:

XYZ12345\XYZ12345_abe.jpg
XYZ12345\XYZ12345_1dfdf.pdf
XYZ12345\XYZ12345-zy.xls
XYZ55555\XYZ55555.doc
XYZ55555\XYZ55555_abe.ppt
abcde_1.xls
abcde.doc

Die Dateien, welche nicht mit XYZ beginnen, sollen nicht verschoben werden.

In folgenden Threads habe ich bereits einige Infos gefunden:
Batch Ordner aus Dateinamen erstellen und Dateien verschieben (Sonderzeichen)
Batch Ordner mit Dateinamen erstellen und verschieben

Da ich mich jedoch mit den Textfunktionen nicht auskenne, komme ich nicht mehr weiter.

Wäre super, wenn mir da jemand helfen könnte!

Gruss
Stefan

@echo off
setlocal ENABLEDELAYEDEXPANSION
set suchstring=XYZ*
for /f "tokens=1 delims=" %%i IN ('dir %suchstring% /A-D /b') DO @(  
	set filename=%%i
	set SHORT=!filename:~0,8!
	if not exist "!SHORT!" (md "!SHORT!")  
	move "%%i" .\!SHORT!  
)

@echo off
setlocal ENABLEDELAYEDEXPANSION
set SUCHSTRING=XYZ*
set STARTFOLDER=C:\DeinStartOrdnerOhneAnführungszeichen
cd "%STARTFOLDER%"  
for /f "tokens=1 delims=" %%F IN ('dir /b /s /AD') DO @(  
	cd "%%F"  
	call :STARTLOOP "%%F"  
)
goto :end

:STARTLOOP
cd %1
for /f "tokens=1 delims=" %%i IN ('dir %SUCHSTRING% /A-D /b') DO @(  
	set filename=%%i
	set SHORT=!filename:~0,8!
	if not exist "!SHORT!" (md "!SHORT!")  
	move "%%i" ".\!SHORT!"  
)
goto :eof

:end
exit