Batch Passwortfeld VBS

@echo off & setlocal
set "Input=%temp%\Input.vbs"  
echo WScript.Echo InputBox("Bitte Passwort eingeben!","Passworteingabe")>%Input%  

set PW=
for /f "delims=" %%i in ('cscript //nologo %Input%') do set "PW=%%i"  

if not defined PW echo Kein Passwort eingegeben & goto :eof
echo Eingegebenes Passwort: %PW%

@echo off & setlocal
set "GetPW=%temp%\GetPW.vbs"  
echo WScript.Echo CreateObject("ScriptPW.Password").GetPassword()>"%GetPW%"  
echo Bitte Passwort eingeben: 
for /f "delims=" %%i in ('cscript //nologo "%GetPW%"') do set "Pass=%%i"  
del "%GetPW%"  
echo %Pass%
Pause

'  
' VB Script Document  
'  
Option explicit
'  
DIM objPopUp   'Das ja notwendige Objekt  
set objPopUp = WScript.CreateObject("WScript.Shell")  
'  
'  
objPopUp.popup fktGetStrPword
'  
function fktGetStrPword
' das verwendete Objekt beruht auf der SCRIPTPW.DLL  
' diese steht unter XP/VISTA/Server2003 zur Verfügung  
' hat nur eine Methode GetPassword().  
' kann nur unter Csript.exe verwendet werden  
' beispielhafter Aufruf C:\WINDOWS\system32\cscript.exe "C:\just4Test\pw.vbs"  
'  
  DIM objPW
  set objPW = CreateObject("ScriptPW.Password")  
'  
WScript.Echo "Bitte geben Sie Ihr Kennwort ein"  
WScript.Echo "Die Eingabe wird nicht angezeigt werden"  
WScript.Echo "Beenden Sie Ihre Eingabe mit Return"  
fktGetStrPword = objPW.getPassword()
END function  'fktGetStrPword  
'  

' VB Script Document  
'Erstellt als helptesk 4 Thread  
'[content:76826#296785]  
'ergänzende Treads  
'none  
'*********************************************************************  
' for               : WSH/cscript.exe  
' testet on    : XPP SP2 / WSH 5.7 für XP  
'  
' Name of File : C:\just4Test\GetPWV07.vbs  
' Last edit      : 06.01.2008 07:28:19  
' Last editor   : pacobay   
'  
'   TARGET  
' Sicherheit bei VBS durch verdeckte Kennworteingabe und Hash-Vergleichswerte  
' Jedoch ist das so zu erzielende Sicherheitsniveau relativ schwach  
' ------  
'  
' ==============================================================  
' Die Grundidee zur Verwendung der SCRIPTPW.DLL sowie von CAPICOM  
' geht zurück auf Windows Scripting, Kapitel 16, S.989ff.  
' vgl.: Windows Scripting, 5. Auflage / Addison-Wesley  
' Autor: Holger Schwichtenberg / http://www.Windows-Scripting.de  
' ==============================================================  
'  
'*********************************************************************  
'  
'  
Option Explicit
'---------------------------  
 Dim wshShell
 Set wshShell = Wscript.CreateObject("Wscript.Shell")  
'---------------------------  
'Dim fso  
'Set fso = CreateObject("Scripting.FileSystemObject")  
'--------------------------  
DIM objPopUp   'Das ja notwendige Objekt  
set objPopUp = WScript.CreateObject("WScript.Shell")  
'--------------------------  
'  
 DIM strPword        ' Sring Kennwort im Klartext  
 DIM strPWHash       ' Sring Kennwort als Hashwert  
'________________________  
' Alternative A  
' strPword = fktGetStrPword  
' strPWHash = fktHashedData(strPword)  
' fktCheckStrPword(strPWHash)  
'--------------------------  
' Alternative B  
' Aus 3 zeilen mache Eine      '@bastla Einst wird ...  ;-))  
 fktCheckStrPword(fktHashedData(fktGetStrPword))
'--------------------------  
'  
'Weiter Aktionen  
'  
objPopUp.popup "nun würden die weiteren Aktionen starten",0,"Yes GO on",64+4096  
'  
'________________________  
'  
'  
function fktGetStrPword
' das verwendete Objekt beruht auf der SCRIPTPW.DLL  
' diese steht unter XP/VISTA/Server2003 zur Verfügung  
' hat nur eine Methode GetPassword().  
' kann nur unter Csript.exe verwendet werden. Ein beispielhafter Aufruf wäre:  
' C:\WINDOWS\system32\cscript.exe "C:\just4Test\GetPWV07.vbs"  
'  
MustBeCsript ' sicherheitshalber noch wscript abfangender Aufruf des Hilfssubs  

  DIM objPW
  set objPW = CreateObject("ScriptPW.Password")  
'  
WScript.Echo "Bitte geben Sie Ihr Kennwort ein"  
WScript.Echo "Die Eingabe wird nicht angezeigt werden"  
WScript.Echo "Beenden Sie Ihre Eingabe mit Return"  
fktGetStrPword = objPW.getPassword()
END function  'fktGetStrPword  
'  
'________________________  
'  
'  Die Hilfsprozeduren  
' (sind nicht notwendigerweise unter csript.exe auszuführen)  
'________________________  
'  
Function fktCheckStrPword(strPword4check)
'in diesem Beispiel entspricht der Hashwert dem Kennwort = administrator.de  

  if strPword4check ="82701DE29C7E9BF57185DE360B9CB0F1068B6CED" then  
     objPopUp.popup "OK PW korrekt! Es kann weitergehen",5,"ERFOLG",64+4096  
    '  
  else
    objPopUp.popup "falsches PW!"&chr(13)& "Script wird abgebrochen",0,"GoHome",64+4096  
    Wscript.quit
end if
'  
END function'CheckStrPword  
'________________________  
'  
Function fktHashedData(str4Hash)
' Fkt zur Erstellung eines Hashwertes  
' m verschlüsseln und Entschlüsseln einer Zeichenkette  
' vgl.: CAPICOM Reference  
' http://msdn2.microsoft.com/en-us/library/aa375732.aspx  
'  
' der hier verwendete Algorithmus  
Const CAPICOM_HASH_ALGORITHM_SHA1 = 0
'  
    DIM objHashedData  'notwendige Objektdeklaration  
    Set objHashedData = CreateObject("CAPICOM.HashedData")  ' objektzuweisung  
        objHashedData.Algorithm = CAPICOM_HASH_ALGORITHM_SHA1 'vgl.: Const  
        objHashedData.Hash str4Hash     ' umwandeln  
'  
    fktHashedData = objHashedData.Value ' Zuweisen des Returnwertes der Fkt  
'  
End Function  'fktHashedData  
'________________________  
'  
 'DIM strClipBoard  'text 4 copy 2 clipboard.  
'  
Sub subCopy2Clipboard(str4ClipBoard)
' kopiert übergebebenes Textargumennt in die Zwischenablage  
' je nach Sicherheitseinstellungen muss IE-Zugriff auf Zwischenablage  
' händisch (bei entsprechenden Windows-popup) freigegeben werden.  
' Achtung: Dialog nicht zwangsläufig im Vordergrund!  
'  
DIM objC2CB
Set objC2CB = CreateObject("InternetExplorer.Application")  
objC2CB.Navigate("about:blank")  
objC2CB.document.parentwindow.clipboardData.SetData "text", str4ClipBoard  
objC2CB.Quit

END SUB 'subCopy2Clipboard(strClipBoard)  
'________________________  
'  
Function fktSesamOeffneDich(sesam)
'Mehr als Gag und um den BeispielHash zu erstellen  

sesam ="administrator.de"  

' Hilfsfunktion um bestimmte Hashwerte zu erstellen  
' um diese dann z.B. in fktCheckStrPword zu verwenden  
' steht danach als Inhalt der Variable strPWHash  
' und als Rückgabewert der Funktion sowie in der  
' Zwischenablage zur Verfügung  
' verwendet andere Prozeduren aus diesem  Helpscript  
' vgl. dahere insbesondere Ausführungen zu subCopy2Clipboard  
'  
    strPWHash = fktHashedData(sesam)
    subCopy2Clipboard(strPWHash)
    fktSesamOeffneDich=strPWHash
end Function  'fktSesamOeffneDich  
'________________________  
'  
SUB MustBeCsript
' -- Erzwingen des Starts mit CSCRIPT !  
If UCASE(right(wscript.fullname,11)) = "WSCRIPT.EXE" Then  
Msgbox "Start mit WSCRIPT.EXE nicht erlaubt. "&chr(13)&_  
"Starten Sie das Script mit csript.exe "&chr(13)&_  
"Script wird abgebrochen"  
Wscript.Quit
end if
END SUB 'MustBeCsript  
'________________________  
'  
'EOF  
'