borsti87
Dec 30, 2007, updated at 22:13:46 (UTC)
view15656
view1
0
Goto Top

Batch IF mit Prozent Variablen die Leerzeichen im Inhalt enthalten

GermanclosedsolvedQuestionBatch, ShellDevelopment
Hallo an alle Experten,

Ich hab ein Problem ich möchte Prozent Variablen (%Variable%) mit Leerzeichen im Inhalt übergeben und vergleichen. Siehe unten:

Code:
<code class="code">
REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music" | find "My Music" > %temp%\test.tmp

set /p test= <%temp%\test.tmp

set pfad=%test:~20%

set vergl="K:/Eigene Musik"

IF not %pfad% == %vergl% goto :pfadfalsch
IF %pfad% == %vergl% goto :pfadok

:pfadfalsch
echo Pfad ist falsch!

:pfadok
echo Pfad ist O.K.!


folgender Code funktioniert allerdings

Code:
<code class="code">
REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" | find "Personal" > %temp%\test.tmp

set /p test= <%temp%\test.tmp

set pfad=%test:~20,3%

set vergl="K:/"

IF not %pfad% == %vergl% goto :pfadfalsch
IF %pfad% == %vergl% goto :pfadok

:pfadfalsch
echo Pfad ist falsch!

:pfadok
echo Pfad ist O.K.!


Im vorraus schon danke!

Borsti87
ShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 76888

Url: https://administrator.de/contentid/76888

Printed on: April 16, 2024 at 06:04 o'clock

1 Comment
Goto Top
Member: bastla
bastla Dec 30, 2007 at 22:13:45 (UTC)
Goto Top
Hallo borsti87 und willkommen im Forum!

Versuch es einmal so:
REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music" | find "My Music" > %temp%\test.tmp  

set /p test= <%temp%\test.tmp 

set "pfad=%test:~20%"  

set "vergl=K:\Eigene Musik"  

if "%pfad%"=="%vergl%" goto :pfadok  

:pfadfalsch
echo Pfad ist falsch!
goto :eof

:pfadok
echo Pfad ist O.K.!
Die Schreibweise
set "variable=Wert mit Leerzeichen"
sorgt einerseits für das Beibehalten der Leerzeichen (sogar solche am Ende könnten "mitgenommen" werden), andererseits werden die Anführungszeichen nicht in der Variablen gespeichert, was uU zu mehr Flexibilität und / oder größerer Übersichtlichkeit führt (siehe "if"-Zeile).

Die beiden "IF"-Statements ließen sich zusammenfassen, da das zweite "IF" zwangsläufig "true" sein musste (ansonsten wäre beim ersten "IF" bereits der Sprung erfolgt).

Schließlich habe ich noch "K:/Eigene Musik" auf "K:\Eigene Musik" geändert.

Ein letzter Hinweis: Das Auslesen des Pfades und Schreiben in eine Variable ließe sich auch ohne "Temp"-Datei bewerkstelligen:
for /f "tokens=3*" %%i in ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music" ^| find "My Music"') do set "pfad=%%j"
Hier wird alles nach dem 3. Bestandteil ("token") der gelesenen Zeile (dieser wäre %%i) in die Variable %pfad% geschrieben. Die Trennung der einzelnen "tokens" erfolgt standardmäßig durch Leerzeichen (bzw auch Tabs), sodass also der Pfad ab Teil 4 (die Teile 1 bis 3 sind "My", "Music" und "REG_SZ") zu finden ist.

Grüße
bastla
GermanclosedsolvedQuestionBatch, ShellDevelopment