snowdream
Oct 11, 2011, updated at Oct 18, 2012 (UTC)
view8414
view18
0
Goto Top

Mit batch string suchen und danach text einfügen

GermansolvedQuestionBatch, ShellDevelopment

Hallo zusammen, ich hoffe es hat einer eine Idee. Ich bin leider nicht so fit in der Programmierung, um dieses Problem selber lösen zu können.

Ich habe eine .txt mit folgendem Inhalt:

text1
text2
text3
;zyklischer Aufruf
text...
text...

Mit einer Batch möchte ich jetzt in der Datei suchen, und nach dem Suchstring einen Textblock einfügen, hier im Beispiel erst mal nur eine Zeile.
@echo off & setlocal 
set "Datei=C:\meine.txt"   
set "Suchen=;zyklischer Aufruf"   
set "Einfügen=neue Zeile mit einem Text"   
 
set "Bak=%temp%\txt.bak"   
move "%Datei%" %Bak%   
for /f "tokens=1* delims=:" %%i in ('findstr /n "^" %Bak%') do (set "Zeile=%%j" & call :ProcessLine)   
goto :eof 
 
:ProcessLine 
if not defined Zeile (>>"%Datei%" echo\ & goto :eof)   
if "%Zeile%" neq "%Suchen%" (>>"%Datei%" echo %Zeile% & goto :eof)   

>>"%Datei%" echo %Zeile%  
>>"%Datei%" echo %Einfügen%  
goto :eof
Diesen Code hab ich hier aus dem Forum, er funktioniert auch soweit ganz gut.
Aber: beginnt die Zeile in meine.txt mit einem "&", dann wird in der Datei diese Zeile gelöscht und dafür "Echo ist off." rein geschrieben.

Beispiel:
&text1
&text2
text3
;zyklischer Aufruf
text...
text...
comment-contentCommentShareShare
Share on Facebook Share on Twitter Share on Reddit Share on Linkedin

Content-Key: 174475

Url: https://administrator.de/contentid/174475

Printed on: April 19, 2024 at 07:04 o'clock

18 Comments
Latest comment
Goto Top
Member: bastla
bastla Oct 11, 2011 at 19:41:06 (UTC)
Goto Top
Hallo snowdream!
Diesen Code hab ich hier aus dem Forum
... wo er aber sicher etwas schöner war (was sich aber noch nachholen lässt face-wink) ...

Ich würde das eher so schreiben:
@echo off & setlocal
set "Datei=C:\meine.txt"  
set "Suchen=;zyklischer Aufruf"  
set "Einfügen=neue Zeile mit einem Text"  

set "Bak=%temp%\txt.bak"  
move "%Datei%" %Bak%  
for /f "tokens=1* delims=:" %%i in ('findstr /n "^" %Bak%') do (set "Zeile=%%j" & call :ProcessLine)  
goto :eof

:ProcessLine
(
    setlocal enabledelayedexpansion
    echo\!Zeile!
    if "%Zeile%"=="%Suchen%" echo %Einfügen%  
    endlocal
)>>"%Datei%"  

goto :eof
Grüße
bastla

[Edit] Korrektur für Ausgabe von Leerzeilen vorgenommen [/Edit]
Member: snowdream
snowdream Oct 12, 2011 at 06:43:38 (UTC)
Goto Top
Hallo Bastla,

besten Dank für deine Hilfe, läuft fast super. Allerdings wird, wenn Leerzeilen im Text vorhanden sind, zusätzlich immer eine Zeile mit "ECHO ist ausgeschaltet (OFF)." eingefügt.
Beispspie meine.txt:

 
&text1
&text2

text3
;zyklischer Aufruf
text4

text5
Kann man das auch noch unterdrücken?
Vielen Dank schon mal.
Member: bastla
bastla Oct 12, 2011 at 08:38:05 (UTC)
Goto Top
Hallo snowdream!
... zusätzlich immer eine Zeile mit "ECHO ist ausgeschaltet (OFF)." eingefügt.
Sollte nach der oben vorgenommenen Korrektur nicht mehr passieren ...

Grüße
bastla

P.S.: Danke für's Formatieren ... face-smile
Member: jeb-the-batcher
jeb-the-batcher Oct 12, 2011 at 10:52:10 (UTC)
Goto Top
Aber jetzt habe ich mit meinen Textdateien ein Problem

Zeile1
..\..\..\windows\system32\calc.exe Zeile2
Zeile3

Irgendwie wird Zeile2 nie ausgegeben, dafür startet jetzt der Taschenrechner face-wink

Aber nach tausch der Zeile 
echo\!Zeile!
durch 
echo(!Zeile!
klappt auch das wuncerbar

jeb
Member: snowdream
snowdream Oct 12, 2011 at 12:05:48 (UTC)
Goto Top
Hallo Bastla,

läuft jetzt perfekt mit der Testdatei. Danke nochmal.
Allerdings scheint es nicht wirklich mit jeder beliebigen Textdatei zu funktionieren, die bat bricht bei einigen Text-Dateien einfach ab.
Wie ich drauf komme? Ich habe den Part mit der Tempdatei abgeändert
von
set "Bak=%temp%\txt.bak"
nach
set "Bak=C:\txt.bak"
Vor dem letzen "goto :eof" in Zeile 19 lösche ich dann die temporäre Datei mit "del %bak%" wieder. Mit der Testdatei, wie weiter oben beschrieben, funktioniert alles, die Temp-Datei wird angelegt und auch wieder gelöscht. Bei meiner wirklich zu bearbeitenden Datei bricht die Batch einfach ab (läuft nicht bis zum Ende durch), da die txt.bak nicht gelöscht wird. Ich muss mal noch ein wenig probieren ob ich raus finden kann, an was das genau liegt. Das kann allerdings etwas dauern, da ich momentan wenig Zeit dafür habe.

Gruß
snowdream
Member: bastla
bastla Oct 12, 2011 at 12:58:58 (UTC)
Goto Top
Hallo snowdream!

Das "letzte" (hinsichtlich des Ablaufs) "goto :eof" befindet sich in Zeile 9!

Grüße
bastla
Member: jeb-the-batcher
jeb-the-batcher Oct 12, 2011 at 13:09:45 (UTC)
Goto Top
Hallo snodream,

versuch es mal mit einer leicht abgeänderten Variante.
Die Probleme können unter anderem vorher in der Zeile
if "%Zeile%"=="%Suchen%" echo %Einfügen%
auftreten, wenn z.B. in Zeile etwas in der Art
"Meins&Deins" & seins   

@echo off
setlocal DisableDelayedExpansion
set "Datei=C:\meine.txt"  
set "Suchen=;zyklischer Aufruf"  
set "Einfügen=neue Zeile mit einem Text"  

set "Bak=%temp%\txt.bak"  
move "%Datei%" %Bak%  
(
  for /f "tokens=1* delims=:" %%i in ('findstr /n "^" %Bak%') do (  
      setlocal enabledelayedexpansion
      set "Zeile=%%j"  
      (echo(!Zeile!)
      if "!Zeile!"=="!Suchen!" echo(!Einfügen!  
      endlocal
  )
) > "%Datei%"

jeb
Member: snowdream
snowdream Oct 12, 2011 at 13:13:16 (UTC)
Goto Top
Hallo bastla,

ich meinte es so:
@echo off & setlocal 
set "Datei=C:\meine.txt"   
set "Suchen=;zyklischer Aufruf"   
 
set "Bak=C:\txt.bak"   
move "%Datei%" %Bak%   
for /f "tokens=1* delims=:" %%i in ('findstr /n "^" %Bak%') do (set "Zeile=%%j" & call :ProcessLine)   
goto :eof 
 .
:ProcessLine 
( 
    setlocal enabledelayedexpansion 
    echo\!Zeile! 
    if "%Zeile%"=="%Suchen%" type c:\einfügen.txt  
    endlocal 
)>>"%Datei%"   
 
del %bak%
goto :eof

Statt dem "Echo %Einfügen%" soll alles aus "c:\einfügen.txt" eingefügt werden. Funktioniert auch, halt aber nur mit bestimmten Text-Dateien.

Gruß
snowdream
Member: snowdream
snowdream Oct 12, 2011 at 13:57:25 (UTC)
Goto Top
Hallo jeb,

das funktioniert mit meiner "Problem-Datei", Weltklasse!
Kannst du mir vielleicht noch verraten, wie ich den statt dem "echo(!Einfügen!" in Zeile 14 eine type-befehl einbinden kann => type c:\einfügen.txt ?

Gruß
snowdream
Member: bastla
bastla Oct 12, 2011 at 14:45:59 (UTC)
Goto Top
Hallo snowdream!

Abgesehen von der Tatsache, dass "del %bak%" weiterhin vor dem falschen "goto :eof" steht - gibt es ev einen Anhaltspunkt, was die Dateien, für die es nicht funktioniert, gemeinsam haben?

Grüße
bastla
Member: jeb-the-batcher
jeb-the-batcher Oct 12, 2011 at 14:57:40 (UTC)
Goto Top
Hallo snowdream,

Zitat von @snowdream:
Hallo jeb,

das funktioniert mit meiner "Problem-Datei", Weltklasse!
Kannst du mir vielleicht noch verraten, wie ich den statt dem "echo(!Einfügen!" in Zeile 14 eine type-befehl
einbinden kann => type c:\einfügen.txt ?

Ja, sollte eigentlich direkt so klappen

if "!Zeile!"=="!Suchen!" type einfügen.txt

Weil alles was innerhalb des Block ausgegeben wird, in die Zieldatei umgeleitet wird.

jeb
Member: snowdream
snowdream Oct 12, 2011 at 14:59:16 (UTC)
Goto Top
so läuft es jetzt perfekt:
@echo off 
setlocal DisableDelayedExpansion 
set "Datei=C:\meine.txt"   
set "Suchen=;zyklischer Aufruf"   
set "Einfügen=C:\einfügen.txt "   

del %temp% /f /q
set "Bak=%temp%\txt.bak"   
move "%Datei%" %Bak%   
( 
  for /f "tokens=1* delims=:" %%i in ('findstr /n "^" %Bak%') do (   
      setlocal enabledelayedexpansion 
      set "Zeile=%%j"   
      (echo(!Zeile!) 
      if "!Zeile!"=="!Suchen!" type %Einfügen%  
      endlocal 
  ) 
) > "%Datei%"

Danke an bastla & jeb für die schnelle Hilfe!
Member: snowdream
snowdream Oct 12, 2011 at 15:03:04 (UTC)
Goto Top
Zitat von @bastla:
Hallo snowdream!

Abgesehen von der Tatsache, dass "del %bak%" weiterhin vor dem falschen "goto :eof" steht - gibt es ev
einen Anhaltspunkt, was die Dateien, für die es nicht funktioniert, gemeinsam haben?

Grüße
bastla

nein, leider nicht...
Member: snowdream
snowdream Oct 17, 2011 at 14:51:34 (UTC)
Goto Top
Hallo nochmal,

hat vielleicht einer noch eine Lösung, wie ich den einzufügenden Text z.B. 2 Zeilen unter dem eigentlichen Suchstring (";zyklischer Aufruf"") einfügen kann.
Ich hab schon einiges an Syntax ausprobiert, bekomme es aber nicht hin face-sad

Gruß
snowdream
Member: bastla
bastla Oct 17, 2011, updated at Oct 18, 2012 at 16:48:47 (UTC)
Goto Top
Hallo snowdream!

Kann eigentlich der Suchstring auch mehrfach in der Datei vorkommen? Falls nein, würde ich eine Anleihe bei den Kollegen diesem Thread) nehmen und das so versuchen:
@echo off & setlocal DisableDelayedExpansion
set "Datei=C:\meine.txt"  
set "Suchen=;zyklischer Aufruf"  
set /a Versatz=2
set "Einf=C:\einfügen.txt"  

set "ZeilenNr="  
for /f "delims=:" %%i in ('findstr /n /c:"%Suchen%" "%Datei%"') do set /a ZeilenNr=%%i  
if not defined ZeilenNr (
    echo "%Suchen%" in "%Datei%" nicht gefunden!  
    goto :eof
)
set /a ZeilenNr+=Versatz

set "Bak=%temp%\txt.bak"  
move "%Datei%" %Bak%  
(
    for /l %%i in (1,1,%ZeilenNr%) do (
        set "Zeile="  
        set /p "Zeile="  
        setlocal enabledelayedexpansion
        echo(!Zeile!
        endlocal
    )
)<%Bak% >"%Datei%"  

>>"%Datei%" type "%Einf%"  
>>"%Datei%" more +%ZeilenNr% %Bak%
Kurzer Hinweis zur Zeile 19: Falls es nach der Zeile mit dem Suchtext weniger als %Versatz% Zeilen gibt, wird dadurch nicht die letzte gefundene Zeile mehrfach in die Zieldatei geschrieben, sondern die fehlenden Quellzeilen werden durch Leerzeilen ersetzt ...

Grüße
bastla
Member: snowdream
snowdream Oct 18, 2011 at 05:42:46 (UTC)
Goto Top
Zitat von @bastla:

Kann eigentlich der Suchstring auch mehrfach in der Datei vorkommen?

Hallo bastla, genau da liegt das Problem, den Suchstring gibt es zum Teil mehrmals. Hier ein Beispiel:

Text1
gleicher_Text
Suchstring
Text2
gleicher_Text
Suchstring
Text3
Text4

Ich möchte jetzt nur nach dem 1. Suchstring einfügen, also vor Text3. Mein Ansatz ist gewesen, in diesem Fall nach Text1 zu suchen und dann einfach 2 Zeilen danach einzufügen.
Ja, das hätte ich etwas besser beschreiben sollen! Somit funktioniert dein Codebeispiel nicht, wenn ich das richtig verstanden habe.

Gruß
snowdream
Member: bastla
bastla Oct 18, 2011 at 10:32:25 (UTC)
Goto Top
Hallo snowdream!

Versuch es mit folgender Zeile 8:
for /f "delims=:" %%i in ('findstr /n /c:"%Suchen%" "%Datei%"') do if not defined ZeilenNr set /a ZeilenNr=%%i
Grüße
bastla
Member: snowdream
snowdream Oct 18, 2011 at 11:52:06 (UTC)
Goto Top
Hallo bastla,

was soll ich sagen... perfekt! Weltklase!

Gruß
snowdream
GermansolvedQuestionBatch, ShellDevelopment
Hotly discussed
AlexWishaHow to set up and configure a Linux GRE tunnelAlexWisha - 3 CommentsjstrickerWIREGUARD VPN ON UDM PRO BEHIND FRITZBOX - HANDSHAKE DID NOT COMPLETEjstricker - 2 CommentsDaniEnd of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 CommentgleixnerdCheck of ZFW Firewallgleixnerd