Batchprogramm unter WinXP

ich habe folgendes Problem: ich will Dateien, die in einem Quell-Ordner liegen per Batch in mehrere andere Ziel-Ordner kopieren. Die Zielordner sind Unterordner und entsprechen in den ersten 4 Stellen den ersten 4 Stellen der zu kopierenden Dateien. Bestehende, gleichnamige Dateien im Zielordner sollen überschrieben werden. Es soll ein kurzes Protokoll erstellt werden, damit klar ist, ob alle Quelldateien in den Zielordnern angekommen sind.

Bsp.:

Quellpfad ist c:\temp

Dateien darin lauten:
1000_a.pdf
1000_b.pdf
1000_a.png
1000_b.png
1010_a.png
2000_a.pdf
2000_a.png

Zielpfad ist d:\test
Die Unterordner dazu heissen (sie existieren schon):
d:\test\1000_x\
d:\test\1010_z\
d:\test\2000_y\

Am Ende sollte es so aussehen:

d:\test\1000_x enthält 1000_a.pdf, 1000_b.pdf, 1000_a.png, 1000_b.png
d:\test\1010_z\ enthält 1010_a.png
d:\test\2000_y enthält 2000_a.pdf, 2000_a.png

Das Ganze soll als Batchdatei unter Windows laufen.

Ich habe mit folgendem Batch leider nur einen Teilerfolg erreicht, da das Programm immer neue Pfade anlegt und nicht die bestehenden benutzt:

for %a in (c:\temp\*.*) do @for /f "delims=_ tokens=1" %i in ("%~nxa") do xcopy /I /Y %a c:\temp\%i\

Ein weiterer Versuch scheiterte auch, da ich das CD-Kommando nicht mit einem vernünftigen Wert versorgen kann:


for %%a in (c:\temp\*.*) do @for /f "delims=_ tokens=1" %%i in ("%%~nxa") do call :loop
:loop
cd %%i*
xcopy /I /Y c:\temp\%%a
cd ..

Kann mir jemand helfen???

Vielen Dank und viele Grüsse,
MAPL

@echo off & setlocal
set "Quelle=c:\temp"  
set "Ziel=d:test"  
set "Prot=%Quelle%\Protokoll_%date:~-4%-%date:~-7,2%-%date:~-10,2%_%time:~,2%%time:~3,2%%time:~6,2%.txt"  
set "Prot=%Prot: =0%"  

del "%Prot%" 2>nul  
pushd "%Quelle%"  
for /f "tokens=1* delims=_" %%i in ('dir /b /a-d *_*.* 2^>nul') do (  
    set "Done="  
    for /d %%a in ("%Ziel%\%%i_?") do if not defined Done (  
        copy "%%i_%%j" "%%a" >nul  
        set "Done=True"  
    )
)
popd

for /d %%a in ("%Ziel%\*_?") do call :ProcessDir "%%a"  
goto :eof

:ProcessDir
set "Zeile=%~f1 enthaelt"  
for /f "delims=" %%i in ('dir /b /a-d %1 2^>nul') do call :ProcessFile "%%i"  
>>"%Prot%" echo %Zeile:~,-1%  
>>"%Prot%" echo\  
goto :eof

:ProcessFile
set "Zeile=%Zeile% %~1,"  
goto :eof

@echo off & setlocal
set "Quelle=c:\temp"  
set "Ziel=d:test"  
set "Prot=%Quelle%\Protokoll_%date:~-4%-%date:~-7,2%-%date:~-10,2%_%time:~,2%%time:~3,2%%time:~6,2%.txt"  
set "Prot=%Prot: =0%"  

del "%Prot%" 2>nul  
pushd "%Quelle%"  
for /f "tokens=1* delims=_" %%i in ('dir /b /a-d *_*.* 2^>nul') do (  
    set "Done="  
    for /d %%a in ("%Ziel%\%%i_?") do if not defined Done (  
        copy "%%i_%%j" "%%a" >nul  
        set "Done=True"  
    )
)
popd

for /d %%a in ("%Ziel%\*_?") do (  
    echo %%~fa
    dir /b /a-d %%a 2>nul
    echo\
)>>"%Prot%"  

dir /b /a-d "%%a" 2>nul

...
...
for /f "tokens=1* delims=_" %%i in ('dir /b /a-d *_*.* 2^>nul') do (  
for /d %%a in ("%Ziel%\%%i -*") do (   
echo %%~fa 
dir /b /a-d "%%a" 2>nul   
echo\ 
)
)>>"%Prot%"  
....

set "Liste=%temp%\Liste.txt"  
copy nul "%Liste%"  
for /f "tokens=1* delims=_" %%i in ('dir /b /a-d *_*.* 2^>nul') do findstr "%%i" "%Liste%" || (  
    >>"%Liste%" echo %%i  
    for /d %%a in ("%Ziel%\%%i -*") do (  
    echo %%~fa
    dir /b /a-d "%%a" 2>nul  
    echo\
    )>>"%Prot%"  
)