Nur bestimmte Dateien mit Batch Script verschieben

@for %i in ("D:\Ordner\*.pdf") do @for /f "delims=_" %a in ("%~ni") do @md "D:\Ordner\%a" 2>nul & move "%i" "D:\Ordner\%a\"  

@echo off
set "ordner=C:\Dateien"  
set lastfile=""  
set nr=0

FOR /F "delims=" %%i in ('dir /B "%ordner%\*.pdf"') do call:dofile "%%~i"  
goto:eof

:dofile
set name=%~n1
if "%name:~-1%" equ "%lastfile%" (  
set /a nr=%nr%+1
) else (
md "%ordner%\Teil %nr%" 2>NUL  
copy "%ordner%\%lastfile%*.pdf" "%ordner%\Teil %nr%"   
set nr=0
)

@echo off
set "ordner=C:\Dateien"  
set "lastfile="  
set nr=0

FOR /F "delims=" %%i in ('dir /B "%ordner%\*.pdf"') do call:dofile "%%~i"  
goto:eof

:dofile
FOR /F "tokens=1 delims=_" %%i in ('echo %~1')do set "name=%%i"  
if "%name%" equ "%lastfile%" (  
set /a nr=%nr%+1
) else (
md "%ordner%\Teil %nr%" 2>NUL  
copy "%ordner%\%lastfile%*.pdf" "%ordner%\Teil %nr%"   
set "lastfile=%name%"  
set nr=0
)

@for %i in ("D:\Ordner\*.pdf") do @for /f "delims=_" %a in ("%~ni") do @for /f %n in ('dir "D:\Ordner\%a*.pdf" 2^>nul^|findstr "Datei(en)" 2^>nul') do @if "%n" gtr "3" @move "D:\Ordner\%a*.pdf" "D:\5-Teiler\">nul  

@if "%n" gtr "3"  

@if "%n"=="5"  

@echo off & setlocal
rem ***************************************************
rem Variable fuer Pfade und Dateimuster hier festlegen;
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\5-Teiler"  

rem ***************************************************

rem Falls der Zielordner noch nicht existiert, diesen erzeugen.
if not exist "%Ziel%\" md "%Ziel%"  

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem ... und davon den ersten Bestandteil (bis zum
    rem ersten "_") nur des Dateinamens (%%~ni) betrachten.  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhaltsverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien - erkennbar
        rem am Bestandteil "Datei(en)" - verwenden und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir "%Quelle%\%%a%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Wenn die Anzahl mehr als 3 betraegt, alle Dateien mit
            rem dem gleichen Namensbeginn in den Zielordner ver-
            rem schieben. Damit die Namen der verschobenen Dateien
            rem nicht angezeigt werden, ">nul" verwenden.  
            if "%%n" gtr "3" @move "%Quelle%\%%a%Dateien%" "%Ziel%\">nul  
        )
    )
)

@echo off & setlocal
rem *********************************************
rem Variable fuer Pfade und Dateimuster hier festlegen;
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel5=D:\5-Teiler"  
set "Ziel7=D:\7-Teiler"  

rem *********************************************

rem Falls die Zielordner noch nicht existieren, diese erzeugen.
if not exist "%Ziel5%\" md "%Ziel5%"  
if not exist "%Ziel7%\" md "%Ziel7%"  

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem ... und davon den ersten Namensbestandteil
    rem (bis zum ersten "_") betrachten  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhaltsverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien verwenden - 
        rem erkennbar am Bestandteil "Datei(en)" - und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Wenn die Anzahl 5 bzw 7 betraegt, alle Dateien mit
            rem dem gleichen Namensbeginn in den jeweiligen Zielordner
            rem verschieben. Damit die Namen der verschobenen Dateien
            rem nicht angezeigt werden, die Ausgabe moch mit ">nul"  
            rem unterdruecken.
            if "%%n"=="5" move "%Quelle%\%%a_%Dateien%" "%Ziel5%\">nul  
            if "%%n"=="7" move "%Quelle%\%%a_%Dateien%" "%Ziel7%\">nul  
        )
    )
)

set "Ziel7=D:\7-Teiler"  
if not exist "%Ziel7%\" md "%Ziel7%"  

if "%%n" gtr "7" @move "%Quelle%\%%a_%Dateien%" "%Zielab8%\">nul  

@echo off & setlocal
rem **********************************************
rem Variable fuer Pfade und Dateimuster hier festlegen;
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  

rem **********************************************

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem ... und davon den ersten Namensbestandteil
    rem (bis zum ersten "_") betrachten  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhaltsverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien verwenden - 
        rem erkennbar am Bestandteil "Datei(en)" - und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Anhand der festgestellten Anzahl an zusammengehoerigen
            rem Dateien falls erforderlich den entsprechen Zielordner
            rem erstellen und die Dateien verschieben. Damit die Namen
            rem  der verschobenen Dateien nicht angezeigt werden,
            rem die Ausgabe noch mit ">nul" unterdruecken.  
			if not exist "%Ziel%\%%n-Teiler" md "%Ziel%\%%n-Teiler"  
            move "%Quelle%\%%a_%Dateien%" "%Ziel%\%%n-Teiler"\>nul  
        )
    )
)

@echo off & setlocal
rem **********************************************
rem Variable fuer Pfade und Dateimuster sowie die
rem zusammenzufassenden Anzahl-Gruppen festlegen;
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  
set "Anzahlen=,12,11,10,9,7,5,3,"  

rem **********************************************

rem Falls die Zielordner noch nicht existieren, diese erzeugen.
for %%n in (%Anzahlen%) do if not exist "%Ziel%\%%n-Teiler\" md "%Ziel%\%%n-Teiler"  

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem ... und davon den ersten Namensbestandteil
    rem (bis zum ersten "_") betrachten  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhaltsverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien verwenden - 
        rem erkennbar am Bestandteil "Datei(en)" - und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Wenn die Anzahl (%%n) in der Vorgabe (%Anzahlen%)
            rem enthalten ist (fuer den exakten Vergleich muss die
            rem ermittelte Anzahl zwischen Kommata gesetzt werden)
            rem alle Dateien mit dem gleichen Namensbeginn in den 
            rem entsprechenden Zielordner verschieben. Damit die
            rem Namen der verschobenen Dateien nicht angezeigt
            rem werden, die Ausgabe noch mit ">nul" unterdruecken.  
            echo %Anzahlen%|findstr /c:",%%n,">nul && move "%Quelle%\%%a_%Dateien%" "%Ziel%\%%n-Teiler\">nul  
        )
    )
)

@echo off & setlocal
rem **********************************************
rem Variable fuer Pfade, Dateimuster und Hilfs-
rem programm "APGetPageCount.exe" hier festlegen;  
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  
set "PgCt=C:\Appligent\APGetPageCount\APGetPageCount.exe"  

rem **********************************************

rem Basisordner erstellen, falls noch nicht vorhanden
if not exist "%Ziel%\" md "%Ziel%"  

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem und deren jeweilige Seitenzahl bestimmen (steht
    rem dann in %%n), wobei die Gesamtanzahl "Total Page  
    rem Count" der Seitenanzahl der untersuchten Datei  
    rem entspricht und daher unmittelbar verwendbar ist.
	for /f "tokens=4 delims=: " %%n in ('call "%PgCt%" "%%i"^|findstr /b /c:"Total Page Count:') do (  
	
	    rem Anhand der festgestellten Seitenanzahl falls
        rem erforderlich den entsprechen Zielordner erstellen
        rem die Datei verschieben. Damit der Name der
        rem verschobenen Datei nicht angezeigt wird,
        rem die Ausgabe moch mit ">nul" unterdruecken.  
        if not exist "%Ziel%\%%n-seitig" md "%Ziel%\%%n-seitig"  
        move "%%i" "%Ziel%\%%n-seitig"\>nul  
    )
)

@echo off & setlocal
rem *********************************************
rem Variable fuer Pfade, Dateimuster und Hilfs-
rem programm "APGetPageCount.exe" hier festlegen;  
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  
set "PgCt=C:\Appligent\APGetPageCount\APGetPageCount.exe"  

rem *********************************************

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem ... und davon den ersten Namensbestandteil
    rem (bis zum ersten "_") betrachten  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhaltsverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien verwenden - 
        rem erkennbar am Bestandteil "Datei(en)" - und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Anhand der festgestellten Anzahl an zusammengehoerigen
            rem Dateien falls erforderlich den entsprechen Zielordner
            rem erstellen und die Dateien verschieben. Damit die Namen
            rem  der verschobenen Dateien nicht angezeigt werden,
            rem die Ausgabe moch mit ">nul" unterdruecken.  
            if not exist "%Ziel%\%%n-Teiler" md "%Ziel%\%%n-Teiler"  
            move "%Quelle%\%%a_%Dateien%" "%Ziel%\%%n-Teiler"\>nul  
        )
    )
)

rem Nach dem Verteilen auf die "#-Teiler-Ordner"  
rem jetzt die weitere Verteilung nach Seitenzahlen

rem Dazu alle Unterordner des %Ziel%-Ordners
rem einzeln bearbeiten
for /d %%a in ("%Ziel%\*.*") do (  

    rem Fuer jede Datei des aktuellen Unterordners %%a ...
    for %%i in ("%%a\%Dateien%") do (  

        rem die Seitenanzahl (%%n) feststellen ...
        for /f "tokens=4 delims=: " %%n in ('call "%PgCt%" "%%i"^|findstr /b /c:"Total Page Count:') do (  

            rem ... und die Datei in den (ev erst zu
            rem erstellenden) Unter-Unterordner
            rem "#-Seiter" verschieben.  
            if not exist "%%a\%%n-Seiter" md "%%a\%%n-Seiter"  
            move "%%i" "%%a\%%n-Seiter\">nul  
        )
    )
)

@echo off & setlocal
rem *********************************************
rem Variable fuer Pfade, Dateimuster und Hilfs-
rem programm "APGetPageCount.exe" sowie Grenze  
rem fuer weitere Aufteilung nach Seitenzahlen
rem und dafuer zu erstellenden Unterordner festlegen;
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"   
set "PgCt=C:\Appligent\APGetPageCount\APGetPageCount.exe"  
set /a Grenze=2
set "MSeiter=Mehrseiter"  

rem *********************************************

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  
    
    rem ... und davon den ersten Namensbestandteil
    rem (bis zum ersten "_") betrachten  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhalteverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien verwenden - 
        rem erkennbar am Bestandteil "Datei(en)" - und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Anhand der festgestellten Anzahl an zusammengehoerigen
            rem Dateien in Unterprogramm  ":Auswertung" die Gruppe auf  
            rem auf Gesamtseitenzahl ueberpruefen und verschieben
			call :Auswertung "%Quelle%\%%a_%Dateien%" %%n  
        )
    )
)

rem Ende Hauptprogramm
goto :eof

rem Unterprogramm
:Auswertung

rem %1 = Suchmuster der Dateigruppe (unter Anfuehrungszeichen),
rem      also zB "D:\Ordner\64123_*.pdf"  
rem %2 = Anzahl der Dateien in der Gruppe

rem Grenzwert fuer Gesamtseitenzahl anhand der zulaessigen
rem Seiten je Datei und der Anzahl der Dateien ermitteln
set /a Grenzwert=%Grenze%*%2

rem Gesamtseitenanzahl der Gruppe auslesen
for /f "tokens=4 delims=: " %%n in ('call "%PgCt%" %~1') do set /a Gesamt=%%n  

rem Ein Unterordner wird nur benoetigt, wenn die Gesamtseitenzahl
rem den Grenzwert erreicht hat
set SeitenOrdner=
if %Gesamt% geq %Grenzwert% set "SeitenOrdner=%MSeiter%"  

rem Zielordner mit Dateianzahl (%2) und ev benoetigtem
rem Unterordner "%MSeiter%" erstellen ...  
if not exist "%Ziel%\%2-Teiler\%SeitenOrdner%" md "%Ziel%\%2-Teiler\%SeitenOrdner%"  

rem ... und Dateigruppe hinein verschieben
move %1 "%Ziel%\%2-Teiler\%SeitenOrdner%">nul  

rem Ende Unterprogramm - Ruecksprung
goto :eof

@echo off & setlocal

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  
set "PgCt=C:\Appligent\APGetPageCount\APGetPageCount.exe"  
set /a Grenze=2
set "MSeiter=Mehrseiter"  

for %%i in ("%Quelle%\%Dateien%") do (  
    for /f "delims=_" %%a in ("%%~ni") do (  
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  
			call :Auswertung "%Quelle%\%%a_%Dateien%" %%n  
        )
    )
)
goto :eof

:Auswertung
set /a Grenzwert=%Grenze%*%2
for /f "tokens=4 delims=: " %%n in ('call "%PgCt%" %~1') do set /a Gesamt=%%n  
set SeitenOrdner=
if %Gesamt% geq %Grenzwert% set "SeitenOrdner=%MSeiter%"  
if not exist "%Ziel%\%2-Teiler\%SeitenOrdner%" md "%Ziel%\%2-Teiler\%SeitenOrdner%"  
move %1 "%Ziel%\%2-Teiler\%SeitenOrdner%">nul  
goto :eof

PageCount: 4
PageCount: 4
PageCount: 2
Total Page Count: 10

C:\Appligent\APGetPageCount\APGetPageCount.exe D:\Ordner\34123_*.pdf

C:\Appligent\APGetPageCount\APGetPageCount.exe "D:\Ordner\34123_*.pdf"  

Total Page Count: 0

@echo off & setlocal enabledelayedexpansion
rem "enabledelayedexpansion" erlaubt das Auslesen   
rem von in einer Schleife veraenderten/gesetzten
rem Variablen noch in dieser Schleife - benoetigt
rem fuer die Ermittlung der max. Seitenzahl

rem *********************************************
rem Variable fuer Pfade, Dateimuster und Hilfs-
rem programm "APGetPageCount.exe" sowie Grenze  
rem fuer weitere Aufteilung nach Seitenzahlen
rem und dafuer zu erstellenden Unterordner festlegen;
rem damit wird es einfacher, den Batch anzupassen.

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  
set "PgCt=C:\Appligent\APGetPageCount\APGetPageCount.exe"  

rem Festlegung der Grenze fuer Seitenzahlen;
rem Wert um 1000 erhoehen (siehe unten)
set /a Grenze=1002

set "MSeiter=Mehrseiter"  
rem *********************************************

rem Alle passenden Dateien im Quellordner durchgehen ...
for %%i in ("%Quelle%\%Dateien%") do (  

    rem ... und davon den ersten Namensbestandteil
    rem (bis zum ersten "_") betrachten  
    for /f "delims=_" %%a in ("%%~ni") do (  

        rem Ein Inhalteverzeichnis aller Dateien mit gleichem ersten
        rem Teil des Namens (%%a) ausgeben, allerdings davon nur die
        rem Zeile mit der Anzahl der gefundenen Dateien verwenden - 
        rem erkennbar am Bestandteil "Datei(en)" - und noch dafuer  
        rem sorgen, dass fuer den Fall, dass es keine weiteren
        rem zugehoerigen Dateien gibt, mittels "2>nul" Fehler-  
        rem meldungen unterdrueckt werden.
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  

            rem Anhand der festgestellten Anzahl an zusammengehoerigen
            rem Dateien in Unterprogramm ":Auswertung" die Dateien der  
            rem Gruppe auf ihre Seitenzahl ueberpruefen und verschieben
            call :Auswertung "%Quelle%\%%a_%Dateien%" %%n  
        )
    )
)

rem Ende Hauptprogramm
goto :eof

rem Unterprogramm
:Auswertung

rem %1 = Suchmuster der Dateigruppe (unter Anfuehrungszeichen),
rem      also zB "D:\Ordner\64123_*.pdf"  
rem %2 = Anzahl der Dateien in der Gruppe

rem Variable fuer max Seitenanzahl der Gruppe initialisieren
set /a Max=0

rem Seitenanzahl jeder Datei bestimmen (dabei nur Zeilen be-
rem ruecksichtigen, welche "PageCount:" enthalten) und die  
rem hoechste Anzahl in %Max% (wegen der "delayedexpansion"  
rem !Max! geschrieben) speichern
for /f "tokens=2 delims=: " %%n in ('call "%PgCt%" %~1^|findstr /c:"PageCount:"') do set /a Seiten=%%n & if !Seiten! gtr !Max! set /a Max=!Seiten!  

rem Ein Unterordner wird nur benoetigt, wenn die hoechste
rem Seitenanzahl den Grenzwert ueberschritten hat, daher
rem zunaechst den Unterordnernamen loeschen
set SeitenOrdner=

rem Maximale Seitenanzahl um 1000 erhoehen, um (bei Bedarf)
rem leicht eine dreistellige Anzahl mit fuehrenden Nullen
rem erhalten zu koennen - zB wird aus "12" Seiten zunaechst  
rem "1012"; davon werden die letzten 3 Stellen verwendet,  
rem woraus sich "012" ergibt.  
set /a Max+=1000

rem Wenn (um 1000 erhoehter) %Max%-Wert den (ebenfalls um
rem 1000 erhoehten - siehe oben) Grenzwert uebersteigt,
rem Unterordnernamen festlegen; entweder nur allgemein
rem als "Mehrseiter" (siehe Variable %MSeiter%) ...  
if %Max% gtr %Grenze% set "SeitenOrdner=%MSeiter%"  

rem ... oder Benennung aufgrund der konkreten Seitenanzahl
rem if %Max% gtr %Grenze% set "SeitenOrdner=%Max:~-3%-Seiter"  

rem Zielordner mit Dateianzahl (%2) und ev benoetigtem
rem Unterordner "%MSeiter%" (oder 00#-Seiter) erstellen ...  
if not exist "%Ziel%\%2-Teiler\%SeitenOrdner%" md "%Ziel%\%2-Teiler\%SeitenOrdner%"  

rem ... und Dateigruppe hinein verschieben
move %1 "%Ziel%\%2-Teiler\%SeitenOrdner%">nul  

rem Ende Unterprogramm - Ruecksprung
goto :eof

@echo off & setlocal enabledelayedexpansion

set "Quelle=D:\Ordner"  
set "Dateien=*.pdf"  
set "Ziel=D:\Zielordner"  
set "PgCt=C:\Appligent\APGetPageCount\APGetPageCount.exe"  
set /a Grenze=1002
set "MSeiter=Mehrseiter"  

for %%i in ("%Quelle%\%Dateien%") do (  
    for /f "delims=_" %%a in ("%%~ni") do (  
        for /f %%n in ('dir /a-d "%Quelle%\%%a_%Dateien%" 2^>nul^|findstr "Datei(en)" 2^>nul') do (  
			call :Auswertung "%Quelle%\%%a_%Dateien%" %%n  
        )
    )
)
goto :eof

:Auswertung
set /a Max=0
for /f "tokens=2 delims=: " %%n in ('call "%PgCt%" %~1^|findstr /c:"PageCount:"') do set /a Seiten=%%n & if !Seiten! gtr !Max! set /a Max=!Seiten!  
set SeitenOrdner=
set /a Max+=1000
if %Max% gtr %Grenze% set "SeitenOrdner=%MSeiter%"  
rem if %Max% gtr %Grenze% set "SeitenOrdner=%Max:~-3%-Seiter"  
if not exist "%Ziel%\%2-Teiler\%SeitenOrdner%" md "%Ziel%\%2-Teiler\%SeitenOrdner%"  
move %1 "%Ziel%\%2-Teiler\%SeitenOrdner%">nul  
goto :eof