Bestimmte Informationen aus einer Datei auslesen und mit der Information eine andere Datei umbenennen

@echo off & setlocal
set "Basis=D:\import\123456"  
set "Datei=info.txt"  
set "Neu=info.log"  
set "Log=D:\Fehler.txt"  

if exist "%Log%" del "%Log%"  
for /d %%i in ("%Basis%\???") do call :ProcessDir "%%i"  
if exist "%Log%" notepad "%Log%"  
goto :eof

:ProcessDir
pushd %1
if not exist "%Datei%" (>>"%Log%" echo %~nx1: Datei "%Datei%" fehlt & goto :Ende)  

set OBJID=
for /f "tokens=2" %%a in ('findstr /b "OBJ_ID" "%Datei%" 2^>nul') do set "OBJID=%%a"  
if not defined OBJID (>>"%Log%" echo %~nx1: Zeile OBJ_ID fehlt & goto :Ende)  

set COMPA=
for /f "tokens=2" %%a in ('findstr /b "COMPA" "%Datei%" 2^>nul') do set "COMPA=%%a"  
if not defined COMPA (>>"%Log%" echo %~nx1: Zeile COMPA fehlt & goto :Ende)  

if not exist "%COMPA%" (>>"%Log%" echo %~nx1: Datei "%COMPA%" fehlt & goto :Ende)  

move "%COMPA%" "%OBJID%.tif"  
if errorlevel 1 (
    >>"%Log%" echo %~nx1: Datei "%COMPA%" konnte nicht auf "%OBJID%.tif" umbenannt werden!  
) else (
    move "%Datei%" "%Neu%" || >>"%Log%" echo %~nx1: Datei "%Datei%" konnte nicht auf "%Neu%" umbenannt werden!  
)

:Ende
popd
goto :eof

"%Basis%\???"

set DOCTYPE=
for /f "tokens=2" %%a in ('findstr /b "DOCTYPE" "%Datei%" 2^>nul') do set "DOCTYPE=%%a"  
if not defined DOCTYPE (>>"%Log%" echo %~nx1: Zeile DOCTYPE fehlt & goto :Ende)  

set ARCHIVID =
for /f "tokens=2" %%a in ('findstr /b "ARCHIVID" "%Datei%" 2^>nul') do set "ARCHIVID=%%a"  
if not defined ARCHIVID (>>"%Log%" echo %~nx1: Zeile ARCHIVID fehlt & goto :Ende)  

>%OBJ_ID%.open echo %OBJ_ID%;%ARCHIVID%;%DOCTYPE%