CRV-Datei auslesen und in Excel konvertieren?

Sub ImportiereCSVDateien()
    'Pfad zu den CSV-Dateien  
    Const CSVPFAD = "A:\csv"  
    'Ordner in den die ausgelesenen CSV-Dateien hinterher verschoben werden  
    Const VERARBEITET = "A:\csv\verarbeitet"  
    
    Dim wsTemp As Worksheet, wsTarget As Worksheet
    Set fso = CreateObject("Scripting.Filesystemobject")  
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    
    'Zielarbeitsblatt für die importierten Daten  
    Set wsTarget = Sheets("Rechnung")  
    'temporäres Arbeitsblatt für den Import der Daten erstellen  
    Set wsTemp = Worksheets.Add(After:=Worksheets(Worksheets.Count))
    
    ' Verarbeitet Ordner erstellen falls nicht vorhanden  
    If Not fso.FolderExists(VERARBEITET) Then MkDir VERARBEITET
    
    For Each f In fso.GetFolder(CSVPFAD).Files
        If LCase(fso.GetExtensionName(f.Name)) = "csv" Then  
            'Temporäres Sheet löschen  
            wsTemp.UsedRange.Clear
            'CSV-Daten in Temporäres Sheet importieren  
            With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & f.Path, Destination:=wsTemp.Range("$A$1"))  
                .Name = "import"  
                .FieldNames = True
                .AdjustColumnWidth = True
                .RefreshPeriod = 0
                .TextFilePlatform = 1252
                .TextFileStartRow = 8
                .TextFileParseType = xlDelimited
                .TextFileTextQualifier = xlTextQualifierDoubleQuote
                .TextFileCommaDelimiter = True
                .TextFileDecimalSeparator = "."  
                .TextFileThousandsSeparator = ","  
                .Refresh BackgroundQuery:=False
                .Delete
            End With
            
            With wsTemp
                'Maximalwert in Zielsheet in nächste leere Zelle in Spalte B kopieren  
                wsTarget.Cells(Rows.Count,"B").End(xlUp).Offset(1, 0).Value = WorksheetFunction.Max(.Columns(2))  
            End With
            
            'Datei in die Ablage verschieben  
            f.Move VERARBEITET & "\"  
        End If
    Next
    'Temporäres Sheet löschen  
    wsTemp.Delete
    
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    MsgBox "Vorgang beendet!", vbInformation  
    Set fso = Nothing
End Sub

Sub ImportiereCSVDateien()
    'Pfad zu den CSV-Dateien  
    Const CSVPFAD = "A:\csv"  
    'Ordner in den die ausgelesenen CSV-Dateien hinterher verschoben werden  
    Const VERARBEITET = "A:\csv\verarbeitet"  
    
    Dim wsTemp As Worksheet, wsTarget As Worksheet
    Set fso = CreateObject("Scripting.Filesystemobject")  
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    
    'Zielarbeitsblatt für die importierten Daten  
    Set wsTarget = Sheets("Rechnung")  
    'temporäres Arbeitsblatt für den Import der Daten erstellen  
    Set wsTemp = Worksheets.Add(After:=Worksheets(Worksheets.Count))
    
    ' Zielwert für Weg(mm) Zelle C7  
    dblTargetValue = wsTarget.range("C7").Value  

    ' Verarbeitet Ordner erstellen falls nicht vorhanden  
    If Not fso.FolderExists(VERARBEITET) Then MkDir VERARBEITET
    
    For Each f In fso.GetFolder(CSVPFAD).Files
        If LCase(fso.GetExtensionName(f.Name)) = "csv" Then  
            'Temporäres Sheet löschen  
            wsTemp.UsedRange.Clear
            'CSV-Daten in Temporäres Sheet importieren  
            With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & f.Path, Destination:=wsTemp.Range("$A$1"))  
                .Name = "import"  
                .FieldNames = True
                .AdjustColumnWidth = True
                .RefreshPeriod = 0
                .TextFilePlatform = 1252
                .TextFileStartRow = 8
                .TextFileParseType = xlDelimited
                .TextFileTextQualifier = xlTextQualifierDoubleQuote
                .TextFileCommaDelimiter = True
                .TextFileDecimalSeparator = "."  
                .TextFileThousandsSeparator = ","  
                .Refresh BackgroundQuery:=False
                .Delete
            End With
            
            With wsTemp
                'nächste freie Zelle in Spalte B ermitteln  
                Set cellNextFree = wsTarget.Cells(Rows.Count, "B").End(xlUp).Offset(1, 0)  
                'Werte filtern  
                .UsedRange.AutoFilter 1, ">=" & Replace(dblTargetValue, ",", ".")  
                ' gefilterten Wert in Zielzelle schreiben  
                cellNextFree.Value = .AutoFilter.Range.Offset(1, 0).SpecialCells(xlCellTypeVisible).Cells(1, 2).Value
                'Autofilter deaktivieren  
                .UsedRange.AutoFilter
            End With
            
            'Datei in die Ablage verschieben  
            f.Move VERARBEITET & "\"  
        End If
    Next
    'Temporäres Sheet löschen  
    wsTemp.Delete
    
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    MsgBox "Vorgang beendet!", vbInformation  
    Set fso = Nothing
End Sub