CSV Werte jeweils in einzelne XML-exportieren

CSV = "Die.csv"  
Header = "Hier die Header-Daten eintragen"  
Dateiname = "D:\Beliebiger Name"  
Typ= ".xml"  
Nr = 100001 'für laufende Nummer im Dateinamen  
Stellen = 5 'Stellenanzahl der laufenden Nummer  
Delim = ";" 'Trennzeichen der CSV  

Set fso = CreateObject("Scripting.FileSystemObject")  
Zeilen = Split(fso.OpenTextFile(CSV).ReadAll, vbCrLf)

Feldnamen = Split(Zeilen(0), Delim) 'Feldnamen auslesen und in Array übertragen  
Felder = UBound(Feldnamen) 'Höchsten Arrayindex zwischenspeichern  

For i = 1 To UBound(Zeilen) 'alle Datenzeilen durchgehen  
    Werte = Split(Zeilen(i), Delim) 'Array mit einzelnen Werten erzeugen  
    If UBound(Werte) >= Felder Then 'nur, wenn genug Werte vorhanden (Vorbeugung gegen Leerzeilen)  
        'Datei mit Header erzeugen  
        Set Datei = fso.CreateTextFile(Dateiname & Right(Nr, Stellen) & Typ)
        Datei.WriteLine Header
        Nr = Nr + 1 'Zähler für Dateinummer erhöhen  
        For j = 0 To Felder 'für jedes Feld ...  
            '... eine Zeile in die Datei schreiben  
            Datei.WriteLine "<FELD NAME=""" & Feldnamen(j) & """>" & Werte(j) & "</FELD>"  
        Next
        Datei.Close 'Datei schließen  
    End If
Next