thomas1972
Goto Top

Datei auf Festplatte per VBA suchen und löschen ( access 2010)

Hallo,

ich weis leider nicht wie es am bestehn hinbekomme,

Ich möchte über Access per VBA bei Klick auf einem Button im Hintergrund nach einer Datei auf der Festplatte suchen lassen (am besten mit Platzhalter *test*.exe)
und sollte diese gefunden werden soll diese ohne nachfrage gelöscht (mir bekannt nur der Kill Befehl)

Welche möglichkeit habe ich dieses umzusetzen?

Würde mich über Hilfe freuen.

Content-Key: 240125

Url: https://administrator.de/contentid/240125

Ausgedruckt am: 29.03.2024 um 13:03 Uhr

Mitglied: colinardo
colinardo 05.06.2014 aktualisiert um 11:43:51 Uhr
Goto Top
Moin,
erster Link unter deinem Post ("Diese Inhalte könnten dich auch interessieren"):
Access 2010 VBA Prüfen ob bestimmte Dateien in einem Verzeichnis vorhanden sind , wenn ja dann x sonst nein dann y ...
Wenn man Ordner Rekursiv durchsuchen möchte kann man es über eine Rekursive Funktion machen, das kann ich aber nur über einen begrenzten Ordnerbaum empfehlen und nicht über eine ganze Festplatte. Siehe dazu: http://www.ammara.com/access_image_faq/recursive_folder_search.html

Für dein Vorhaben könnte dies so aussehen
Option Compare Text

Sub deleteFiles()
    Dim FILEFILTER As String, fso As Object, colFiles As New Collection
    '========Variablen für Anpassung =======  
    'Ordner in dem die Dateien liegen  
    Const STARTFOLDER = "C:\temp"  
    'DateiFilter mit Regular Expressions  
    FILEFILTER = "*test*.exe"  
    'Auch Dateien in Unterordnern bearbeiten  
    Const RECURSION = True
    '=======================================  
    Set fso = CreateObject("Scripting.Filesystemobject")  

    'Suche Dateien rekursiv in einem Ordner und lese sie in die Collection ein  
    SearchFiles colFiles, fso.GetFolder(STARTFOLDER), FILEFILTER, RECURSION

    ' lösche jede Datei die auf den Filter gepasst hat  
    For Each f In colFiles
        fso.DeleteFile f, True
        Debug.Print "Datei: '" & f & "' wurde gelöscht!"  
    Next
End Sub

Function SearchFiles(colFiles As Collection, ByVal strFldr As Object, ByVal strFilter As String, ByVal boolRecursion As Boolean)
    Dim file As Object
    For Each file In strFldr.files
        If file.Name Like strFilter Then
            colFiles.Add file.Path
        End If
    Next
    If boolRecursion Then
        For Each subFolder In strFldr.SubFolders
            SearchFiles colFiles, subFolder, strFilter, True
        Next
    End If
End Function

Hier eine alternative Variante bei der man mit Regular Expressions suchen kann:
Dim FILEFILTER,fso,regex,filesDeleted,file
'========Variablen für Anpassung =======  
'Startsuchordner  
Const STARTFOLDER = "C:\temp"  
'DateiFilter mit Regular Expressions  
FILEFILTER = "^Neues Textdokument.*\.txt"  
'Auch Dateien in Unterordnern bearbeiten  
Const RECURSION = True
'=======================================  
Set fso = CreateObject("Scripting.Filesystemobject")  
Set regex = CreateObject("vbscript.regexp")  
regex.Pattern = FILEFILTER
regex.IgnoreCase= True
parseFolders fso.GetFolder(STARTFOLDER), RECURSION

MsgBox "Folgende Dateien wurden gelöscht: " & filesDeleted  
Set regex = Nothing
Set fso = Nothing

Function parseFolders(strFldr,boolRecursion)
	For each file in strFldr.Files
		If regex.Test(file.Name) Then
			fso.DeleteFile file.Path, True
			filesDeleted = filesDeleted & file.Path & vbNewLine
		End If
	Next
	
	If boolRecursion Then
		For Each subFolder in strFldr.SubFolders
			parseFolders subFolder, True
		Next
	End If
End Function
Grüße Uwe
Mitglied: 116301
116301 05.06.2014 um 10:15:12 Uhr
Goto Top
Hallo Uwe!

Wobei man dann auch den Like-Operator mit 'Option Compare Text' verwenden könnte, der auch Wildcards erlaubtface-wink

Grüße Dieter
Mitglied: colinardo
colinardo 05.06.2014 um 10:16:58 Uhr
Goto Top
Yip, danke für die Ergänzung war zu sehr auf VBS fixiert face-smile

Grüße Uwe
Mitglied: thomas1972
thomas1972 05.06.2014 aktualisiert um 12:33:07 Uhr
Goto Top
Hallo,

vielen dank für die Hilfestellung,
habe nur das Problem, das ich keine Rechte auf den C:\$Recycle.Bin habe und somit er auf einen Fehler Zugriff verweigert läuft.
Hab daher die Option On Error Resume Next eingebunden

Nun dauert es ewig bis er fertig ist,
Kann ich irgendwie den C:\$Recycle.Bin umgehen?
Mitglied: colinardo
colinardo 05.06.2014 aktualisiert um 14:36:36 Uhr
Goto Top
Wie bereits oben gesagt: die Prozedur ist eigentlich nicht dafür geeignet eine ganze Festplatte zu durchsuchen. Du solltest es auf ein paar Ordner einschränken, und für die jeweils einmal durchlaufen lassen.
Wie sich diese diversen Probleme die bei einer rekursiven Suche auftauchen können umgehen lassen habe ich hier mit einem C# Programm demonstriert:
CSharp Festplatte nach bestimmtem Ordnernamen durchsuchen

Vor allem wird die Suche im jetzigen Zustand bei Angabe eines ganzen Laufwerks ewig laufen, und vermutlich irgendwann bei sehr tief verschachtelten Ordnern die Rekursionstiefe überschreiten.

Es gibt noch eine Lösung über den indexdienst von Windows, aber dann müssen deine Files indiziert sein.

Eine zuverlässige Lösung via VBA müsste ich erst nochmal evaluieren. Ich persönlich würde mir die entsprechende Funktion via C# als COM-DLL kompilieren, die DLL in VBA einbinden und dann die Funktion aufrufen, aber das ist für dich vermutlich zu starker Tobak.

Grüße Uwe