Dateien automatisch in gleichnamige Ordner verschieben

@echo off

setlocal enabledelayedexpansion

set SrcDir=%Userprofile%\Desktop\Bilder
set DestDir=%Userprofile%\Desktop\Bilder


for /f "delims=" %%i in ('dir "%SrcDir%" /b /a:-d /o:ne') do (  
  rem Dateiname extrahieren
  set FName=%%~ni
  
  rem Dateierweiterung extrahieren
  set FExt=%%~xi
  
  rem Dateiname umdrehen
  call :fnStrReverse "!FName!"  
  set FNameRev=!fnRes!
  
  rem Neuen Dateinamen extrahieren
  call :fnExtNewFilename "!FNameRev!"  
  set NewFNameRev=!fnRes!
  
  rem Neuen Dateinamen umdrehen; danach also wieder richtig herum
  call :fnStrReverse "!NewFNameRev!"  
  set NewFName=!fnRes!
  
  rem Neuen Dateinamen aus dem ursprünglichen Dateinamen löschen,
  rem ergibt den Ordnernamen
  call :fnStrDel "!FName!" "!NewFName!"  
  set DirName=!fnRes!
  
  rem Wenn der Ordner noch nicht existiert, anlegen
  if not exist "%DestDir%\!DirName!" md "%DestDir%\!DirName!"  
  
  rem Datei verschieben und umbenennen
  move "%SrcDir%\!FName!!FExt!" "%DestDir%\!DirName!\!NewFName!!FExt!"  
)

endlocal

exit /b



::Dreht den String in %1 um
:fnStrReverse
setlocal

set str=%~1
set fnRes=

:StrRevLoop
  ::Das letzte Zeichen vom Ausgangsstring holen
  set chr=%str:~-1%
  
  ::Zielstring in umgekehrter Reihenfolge wie Ausgangsstring zusammenbauen
  set fnRes=%fnRes%%chr%
  
  ::Letztes Zeichen vom Ausgangsstring löschen
  set str=%str:~0,-1%
  
::Wenn der Ausgangsstring noch Zeichen enthält, zum Schleifenanfang
if "%str%" neq "" goto StrRevLoop  

::Funktionsergebnis zurückgeben
::Sieht zwar unsinnig aus, nutzt aber ein undokumentiertes Feature des
::Skriptinterpreters aus, um aus einem mit setlocal/endlocal eingefassten
::Codeblock Variableninhalte an den Code ausserhalb des Blocks zu übermitteln
endlocal & set fnRes=%fnRes%

exit /b



::Extrahiert die ersten zwei Teilstrings aus %1
:fnExtNewFilename
setlocal

set str=%~1

::Die ersten zwei Teilstrings extrahieren,
::Trennzeichen ist Leerzeichen
for /f "usebackq tokens=1,2" %%i in ('%str%') do (  
  set fnRes=%%i %%j
)

endlocal & set fnRes=%fnRes%

exit /b



::Löscht String in Parameter %2 aus String in %1
:fnStrDel
setlocal

set str=%~1

::Nutzt auch wieder ein undokumentiertes Feature des Skiptinterpreters aus,
::damit der Ausdruck %str: %~2=% verstanden wird
call set "fnRes=%%str: %~2=%%"  

endlocal & set fnRes=%fnRes%

exit /b

"HSTAH Nds. 220 Acc. 2010_069 Nr. 1 Aufn 001", 
"HSTAH Nds. 220 Acc. 2010_069 Nr. 1 Aufn 002" usw., dann 
"HSTAH Nds. 220 Acc. 2010_069 Nr. 2 Aufn 001" , 
"HSTAH Nds. 220 Acc. 2010_069 Nr. 2 Aufn 002", die in Ordner 
"HSTAH Nds. 220 Acc. 2010_069 Nr. 1" bzw 
"HSTAH Nds. 220 Acc. 2010_069 Nr. 2"

:: OrdnerVonName.cmd ::::::::::::::::::::::::::::::::::::::::::::::::
@echo off & SetLocal
Set "SrcDir=%Userprofile%\Desktop\Bilder\"  
Set "DestDir=E:\Bilder_Neu\"  
:: Wechsele temporär ins SrcDir
Pushd "%SrcDir%"  
:: Nudle in der Schleife alle passenden Dateien durch und 
:: übergebe alle Namensbestandteile an die Subroutine :ProcFile
For /F "Delims=" %%A in (  
  'dir /b/a-d/one *.jpg *.bmp *.png *.psp'  
    ) do Call :ProcFile "%%~fA" "%%~dpA" "%%~nA" "%%~xA"  
:: zurück ins alte Verzeichnis
Popd
:: habe fertig
Goto :Eof

:ProcFile "LW:\Pfad\Datei.Erw" "LW:\Pfad" "Datei" ".Erw" ------------ 
set "FileName=%~3"  
:: Die nächste Zeile übernimmt in BildNr nur was hinter " Aufn " steht 
Set "BildNr=%FileName:* Aufn =%"  
:: Die nächste Zeile übernimmt in Ordner alles bis auf " Aufn "+BildNr 
Call Set "Ordner=%DestDir%%%FileName: Aufn %BildNr%=%%"  
:: Nur zum ausprobieren Anzeige aller ermittelten Daten
Echo Alte Datei  : %1
Echo      Pfad   : %2
Echo      Name   : %3
Echo      Erw.   : %4
Echo Bildnummer  : %BildNr%
Echo Neuer Ordner: %Ordner%
Pause
:: Wenn Ordner noch nicht vorhanden, erstellen!
If Not Exist "%Ordner%" MD "%Ordner%"  
:: MoveIt, MoveIt - MoveIt
Move %1 "%Ordner%"  

Set "BildNr=%FileName:* Aufn =%"