Apr 25, 2013

5484

Dateien mit Bedingung löschen

Ich möchte eine Batch-Datei erstellen mit der ich meinen Datenmüll entfernen kann.

Ich habe in meinen Foto-Ordnern Dateien mit den Endungen .jpg und .raw . wenn ich die Fotos aussortiere, lösche ich die jpg-Dateien. Nun sollte mein Skript die dazugehörigen raw-Dateien löschen.

Bedingung: Wenn die Datei mit dem gleichen Namen schon im gleichen Ordner vorhanden ist, darf sie bleiben.
Sonst: Löschen

Das Skript sollte nach Möglichkeit auch Unterordner einbeziehen.

Vielen Dank.
passa

Please also mark the comments that contributed to the solution of the article

Content-Key: 205652

Url: https://administrator.de/contentid/205652

Printed on: April 19, 2024 at 03:04 o'clock

14 Comments

Latest comment

Also um es noch mal zu verstehen...
Du hast einen Ordner, hast die beiden Dateiendungen .jpg und .raw . Ich nehme an die .raw Dateien sind Kopien vom .jpg und haben denselben Namen? Und du möchtest jetzt ein Skript haben, was dir raussucht, ob es die .raw Datei auch als .jpg gibt, die abgesehen von der Dateiendung den selben Namen hat, und wenn nicht, soll die .raw gelöscht werden?

Genau das meine ich.
(Die .raw Datei ist die Aufnahme ohne Komprimierung. Diese Dateien werden (bei gegebener Einstellung) beim Fotografieren erstellt und dienen zur Weiterbearbeitung.)

Hmm, also, ich kann dir den Denkweg schreiben, den Code bekomm ich aber nicht auf die Reihe :D
Du müsstest mittels for Schleife den Namen einer .raw Datei nehmen, und dann prüfen ob eine .jpg mit gleichem Namen da ist, wenn nicht löschen. Weiter weiß ich nicht, tut mir leid :/

Hallo Leute,

ich bin sicher, dass es hier in dem schicken Forum dazu schon Antworten gibt, auch wenn ich die jetzt nicht gesucht hab.

for %%i in (*.raw) do if exist "%%~ni.JPG" echo del "%%~fi"  

Gruss!

Hallo passa,

@echo off & setlocal ENABLEDELAYEDEXPANSION
set rootFolder=C:\DeinOrdner\
for /f "tokens=*" %%i IN ('dir /s /b /A-D "%rootFolder%*.raw"') DO @(  
	set file=%%i
	set jpgfile=!file:~0,-3!jpg
	if not exist "!jpgfile!" (  
	    set jpgfile=!file:~0,-3!jpeg
            if not exist "!jpgfile!" (  
               del "!file!" /q  
            )
	)
)

Grüße Uwe

@Endoro: Danke. Ich habe in diesem Forum und auch über Google intensive Nachforschungen angestellt und leider nichts gefunden. Dein Code funktioniert bei mir leider nicht.

@colinardo: Vielen Dank Uwe. Ich habe dein Code ausführlich getestet und einmal hat es geklappt. Dann sind mir plötzlich alle raw Dateien gelöscht worden und dann wieder keine. Keine Ahnung warum ich nicht immer das gleiche Resultat erhalte. Ich werde es nochmals ein wenig testen.

Zitat von @passa123:

Dein Code funktioniert bei mir leider nicht.

... und warum nicht? Gab's eine Fehlermeldung? Ein unerwartetes Resulat? Hier geht's nämlich.

Gruss!

Zitat von @passa123:
@colinardo: Vielen Dank Uwe. Ich habe dein Code ausführlich getestet und einmal hat es geklappt. Dann sind mir plötzlich
alle raw Dateien gelöscht worden und dann wieder keine. Keine Ahnung warum ich nicht immer das gleiche Resultat erhalte. Ich
werde es nochmals ein wenig testen.

vielleicht haben deine JPG's andere Endungen als in meinem Script (jpg,jpeg).
--edit: Hab das Script dazu noch oben ergänzt, jetzt können die Endungen "jpg" oder "jpeg" heißen.

@ Endoro
Vielleicht mit einem "not"?

Grüße
bastla

@ bastla

ich hab's mir schon gedacht: ich hab die Aufgabe nicht gepeilt. Wer darf bleiben- wer muss gehn

Gruss!

... und warum nicht? Gab's eine Fehlermeldung? Ein unerwartetes Resulat? Hier geht's nämlich.

Gruss!

...keine Ahnung. Es geschieht nichts. Keine Fehlermeldung, kein Resultat.

Zitat von @colinardo:
vielleicht haben deine JPG's andere Endungen als in meinem Script (jpg,jpeg).
--edit: Hab das Script dazu noch oben ergänzt, jetzt können die Endungen "jpg" oder "jpeg"
heißen.

Super, Danke! Obwohl meine Dateien die Endungen .jpg haben ist es am Donnerstag nicht gegangen und jetzt geht es problemlos. Ich habe das Skript nun noch um eine Benutzereingabe erweitert.

@echo off & setlocal ENABLEDELAYEDEXPANSION
echo Programm zum loeschen der unnoetigen RAW-Dateien.
set /P rootFolder=Bitte geben Sie den Pfad an:
for /f "tokens=*" %%i IN ('dir /s /b /A-D "%rootFolder%*.raw"') DO @(  
	set file=%%i
	set jpgfile=!file:~0,-3!jpg
	if not exist "!jpgfile!" (  
	    set jpgfile=!file:~0,-3!jpeg
            if not exist "!jpgfile!" (  
               del "!file!" /q  
            )
	)
)

Gibt es noch eine Möglichkeit, abschliessend noch eine Zusammenfassung anzeigen zu lassen? Ich denke da an: "Es wurden ... Dateien gelöscht."

Hallo passa123!

Zusammen mit einer etwas eleganteren (siehe oben bei Endoro) Handhabung des "Typ"-Problems etwa so:

@echo off & setlocal
echo Programm zum loeschen der unnoetigen RAW-Dateien.
set /P rootFolder=Bitte geben Sie den Pfad (mit \ am Ende)an:
set Anzahl=0
for /f "tokens=*" %%i IN ('dir /s /b /A-D "%rootFolder%*.raw"') DO (  
    if not exist "%%~dpni.jpg" if not exist "%%~dpni.jpeg" (  
        del /q "%%i"  
        set /a Anzahl+=1
    )
)
echo Es wurden %Anzahl% Dateien gelöscht.

Grüße
bastla

Danke bastla, jetzt habe ich mein finales Skript. Ich habe noch eine Pause an den Schluss gestellt (sonst sieht man das Resultat nicht).
Das Problem ist gelöst. Danke an alle Beteiligten.

@echo off & setlocal
echo Programm zum loeschen der unnoetigen RAW-Dateien.
set /P rootFolder=Bitte geben Sie den Pfad (mit \ am Ende)an:
set Anzahl=0
for /f "tokens=*" %%i IN ('dir /s /b /A-D "%rootFolder%*.raw"') DO (  
    if not exist "%%~dpni.jpg" if not exist "%%~dpni.jpeg" (  
        del /q "%%i"  
        set /a Anzahl+=1
    )
)
echo Es wurden %Anzahl% Dateien geloescht.
pause

German solved Question Batch, Shell Development

Hotly discussed

How to set up and configure a Linux GRE tunnelAlexWisha - 3 Comments

WIREGUARD VPN ON UDM PRO BEHIND FRITZBOX - HANDSHAKE DID NOT COMPLETEjstricker - 1 Comment

End of Support dates for Office 2016, 2019 Apps und Productivity ServersDani - 1 Comment