Dateien anhand einer Dateiliste kopieren

Hallo zusammen,
ich möchte mehrere in einer Textdatei enthaltenen Dateien anhand des Dateinamens in ein anderes Verzeichnis kopieren .

Folgende Batchdatei funktioniert , wenn die Dateinamen im Verzeichnis und die Namen in der Textdatei absolut identisch sind.

@echo off & setlocal

set "sourceRoot=j:\ichselber"
set "sourceList=j:\List.txt"
set "destFolder=e:\Ziel"

for /f "delims=" %%i in ('dir /a-d /b /s "%sourceRoot%\*.txt"^|findstr /ig:"%sourceList%"') do (
copy "%%~i" "%destFolder%\"
)


Jetzt haben aber die Namen in der Textdatei abgekürzte Namen.

Beispiel: der Name der Datei heisst 1234-hurra4567-89.txt
der Name in der Liste heisst hurra4567

Die Teile vor dem Bindestrich und hinter dem Bindestrich sind bei allen Dateien gleich.
Es sollen also anhand des "Mittelteils" die Dateien kopiert werden.

Ich vermute es lässt sich mit "token" und "delim" realisieren, bekomme es aber nicht hin.

Kann mir irgendwer vielleicht einen Tipp geben ?

@echo off & setlocal

set "sourceRoot=j:\ichselber"  
set "sourceList=j:\List.txt"  
set "destFolder=e:\Ziel"  

for /r "%sourceRoot%" %%a in ("*.txt") do (  
  for /f "tokens=2 delims=-" %%b in ("%%~nxa") do (  
    for /f "usebackq delims=" %%c in ("%sourceList%") do (  
      if /i "%%b" equ "%%~c" (  
        copy "%%~a" "%destFolder%\" > NUL  
      )
    )
  )
)