Top-Themen

Aktuelle Themen (A bis Z)

Administrator.de FeedbackApache ServerAppleAssemblerAudioAusbildungAuslandBackupBasicBatch & ShellBenchmarksBibliotheken & ToolkitsBlogsCloud-DiensteClusterCMSCPU, RAM, MainboardsCSSC und C++DatenbankenDatenschutzDebianDigitiales FernsehenDNSDrucker und ScannerDSL, VDSLE-BooksE-BusinessE-MailEntwicklungErkennung und -AbwehrExchange ServerFestplatten, SSD, RaidFirewallFlatratesGoogle AndroidGrafikGrafikkarten & MonitoreGroupwareHardwareHosting & HousingHTMLHumor (lol)Hyper-VIconsIDE & EditorenInformationsdiensteInstallationInstant MessagingInternetInternet DomäneniOSISDN & AnaloganschlüsseiTunesJavaJavaScriptKiXtartKVMLAN, WAN, WirelessLinuxLinux DesktopLinux NetzwerkLinux ToolsLinux UserverwaltungLizenzierungMac OS XMicrosoftMicrosoft OfficeMikroTik RouterOSMonitoringMultimediaMultimedia & ZubehörNetzwerkeNetzwerkgrundlagenNetzwerkmanagementNetzwerkprotokolleNotebook & ZubehörNovell NetwareOff TopicOpenOffice, LibreOfficeOutlook & MailPapierkorbPascal und DelphiPeripheriegerätePerlPHPPythonRechtliche FragenRedHat, CentOS, FedoraRouter & RoutingSambaSAN, NAS, DASSchriftartenSchulung & TrainingSEOServerServer-HardwareSicherheitSicherheits-ToolsSicherheitsgrundlagenSolarisSonstige SystemeSoziale NetzwerkeSpeicherkartenStudentenjobs & PraktikumSuche ProjektpartnerSuseSwitche und HubsTipps & TricksTK-Netze & GeräteUbuntuUMTS, EDGE & GPRSUtilitiesVB for ApplicationsVerschlüsselung & ZertifikateVideo & StreamingViren und TrojanerVirtualisierungVisual StudioVmwareVoice over IPWebbrowserWebentwicklungWeiterbildungWindows 7Windows 8Windows 10Windows InstallationWindows MobileWindows NetzwerkWindows ServerWindows SystemdateienWindows ToolsWindows UpdateWindows UserverwaltungWindows VistaWindows XPXenserverXMLZusammenarbeit

gelöst Dateien nach Datum automatisch archivieren

Mitglied: pbelcl

pbelcl (Level 1) - Jetzt verbinden

21.11.2007, aktualisiert 18.10.2012, 10390 Aufrufe, 14 Kommentare

Dateien die älter wie 3 Monate sind moven und dann löschen

Hallo Leute,

Ich möchte Dateien mit bestimmten Endungen aus einem Verzeichnis die älter als 3 Monate sind in einen anderen Ordner moven (oder kopieren und danach am Ursprung löschen).

Ich hab jetz mal hier etwas rumgesucht und einige brauchbare "fetzen" Code gefunden, allerdings scheieert es am Zusammenbau dieser

am besten gefiele mir diese Routine:

@echo off

for /F "delims=. tokens=2" %%B in ("%date%") do Set "MON=%%B"
If [%MON%]==[01] SET "VMN=10"
If [%MON%]==[02] SET "VMN=11"
If [%MON%]==[03] SET "VMN=12"
If [%MON%]==[04] SET "VMN=01"
If [%MON%]==[05] SET "VMN=02"
If [%MON%]==[06] SET "VMN=03"
If [%MON%]==[07] SET "VMN=04"
If [%MON%]==[08] SET "VMN=05"
If [%MON%]==[09] SET "VMN=06"
If [%MON%]==[10] SET "VMN=07"
If [%MON%]==[11] SET "VMN=08"
If [%MON%]==[12] SET "VMN=09"

SET AJR=%DATE:~-4%
SET /A VJR=%AJR% -1

echo %mon% Monat
echo %vmn% Vormonat
echo %ajr% Jahr
echo %vjr% Vorjahr
echo.

REM Zum Ordner mit Vormonat anlegen, das REM in der nächsten Zeile entfernen:
REM md C:\Monat%vmn%

Ich habe die Funktionn auch schon auf meine 3 Monate angepaßt, allerdings habe ich nicht verstanden wie man damit den Jahressprung realisiert!

Beispiel: im Monat "01" sollte das Monat "10" gesichert werden, allerdings DES VORJAHRES!!

Weiters habe ich noch nicht rausgefunden wie man per Variable das Filedatum abprüft ?

Beispiel:

Im Ordner "C:\source" sind viele Dateien
ich möchte nun wenn das Batch im Monat 11 gestartet wird daß alle Dateien die älter wie 3 Monate sind in einen entsprechenden Zielordner kopiert werden

z.B.
Dateien vom Monat 09_2007 in "c:\2007_09
Dateien vom Monat 10_2007 in "c:\2007_10
u.s.w ...
Die Ordner sollten automatisch erstellt werden!

Geht das überhaupt per Batch???
Wenn ja, hat jemand einen Tip??
Mitglied: bastla
21.11.2007 um 13:25 Uhr
Hallo pbelcl!

Da Du ja schon %MON% und %VMN% sowie %AJR% und %VJR% hast, kann der Ordnername so bestimmt werden:
01.
if %MON% gtr %VMN% (set Ordner=C:\%AJR%_%VMN%) else set Ordner=C:\%VJR%_%VMN%
Vor dem Kopieren solltest Du natürlich den Ordner schon erstellt haben, daher:
01.
if not exist %Ordner% md %Ordner%
Das Dateidatum kannst Du so auslesen (Beispiele für Batch, an der Kommandozeile jeweils nur ein "%"):
01.
for %%i in (C:\source\*.*) do echo %%i vom %%~ti
Um nur das Monat zu erhalten:
01.
for %%i in (C:\source\*.*) do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do echo %%i aus Monat %%m
Nur Dateien aus dem Monat %VMN% zu kopieren ginge dann mit:
01.
for %%i in (C:\source\*.*) do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% @echo copy "%%i" %Ordner%\
Das "@echo" vor dem "copy" dient dazu, nur einmal das Kopieren zu simulieren - wenn Du es entfernst, wird tatsächlich kopiert.

Grüße
bastla
Bitte warten ..
Mitglied: Biber
21.11.2007 um 13:54 Uhr
@bastla
Um nur das Monat zu erhalten:
Das Monat?
Sind nicht die Monatsnamen auf ~i (Mai, Juni, Juli) weiblich?

Und April ist doch auch ein weiblicher Name, oder?

Grüße
Biber
Bitte warten ..
Mitglied: pbelcl
21.11.2007 um 14:01 Uhr
WOW!!!
Das ist ja super, werds gleich mal ausprobieren ....
Danke bastla!
Bitte warten ..
Mitglied: bastla
21.11.2007 um 14:03 Uhr
@Biber

Eben, eben - damit sich die anderen (mehrheitlich miese männliche Mimosen) durch das eigentlich korrekte "die" nicht benachteiligt fühlen, als Kompromisslösung "das" ...

Grüße
bastla
Bitte warten ..
Mitglied: pbelcl
21.11.2007 um 15:07 Uhr
Hallo bastla,

Hab nun alles mal getestet, sieht schon recht gut aus, allerdings hat der Befehl:

Nur Dateien aus dem Monat %VMN% zu kopieren ginge dann mit:
01.
for %%i in (C:\source\*.*) do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% @echo copy "%%i" %Ordner%\ 

in der Augabe mit Echo wird leider nur den Syntax angezeigt und keinen Kopierbefehl!?
Hab ich da was falsch verstanden?

Habe auch versucht den Befehl in ein Logfile umzuleiten, damit ich sehen kann was passieren würde, hat leider auch nicht wirklich geklappt...
Hast Du einen Tip?
Bitte warten ..
Mitglied: bastla
21.11.2007 um 15:32 Uhr
Hallo pbelcl!

Damit wir auf den gleichen Stand kommen:
01.
@echo off & setlocal 
02.
 
03.
set "Quelle=C:\source\*.*" 
04.
set "Ziel=C:" 
05.
 
06.
for /F "delims=. tokens=2" %%B in ("%date%") do set "MON=%%B" 
07.
If [%MON%]==[01] SET "VMN=10" 
08.
If [%MON%]==[02] SET "VMN=11" 
09.
If [%MON%]==[03] SET "VMN=12" 
10.
If [%MON%]==[04] SET "VMN=01" 
11.
If [%MON%]==[05] SET "VMN=02" 
12.
If [%MON%]==[06] SET "VMN=03" 
13.
If [%MON%]==[07] SET "VMN=04" 
14.
If [%MON%]==[08] SET "VMN=05" 
15.
If [%MON%]==[09] SET "VMN=06" 
16.
If [%MON%]==[10] SET "VMN=07" 
17.
If [%MON%]==[11] SET "VMN=08" 
18.
If [%MON%]==[12] SET "VMN=09" 
19.
 
20.
SET AJR=%DATE:~-4% 
21.
SET /A VJR=%AJR%-1 
22.
 
23.
if %MON% gtr %VMN% (set "Ordner=%Ziel%\%AJR%_%VMN%") else set "Ordner=%Ziel%\%VJR%_%VMN%" 
24.
 
25.
if not exist "%Ordner%" md "%Ordner%" 
26.
 
27.
for %%i in ("%Quelle%") do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% @echo copy "%%i" "%Ordner%\" >nul
Aus Gründen der Übersichtlichkeit habe ich Quelle und Zielordner (bitte ohne abschließenden "\" belassen) am Anfang in Variable gepackt und zur Sicherheit noch einige Anführungszeichen (an hoffentlich passenden Stellen ) hinzugefügt.

Das an den "copy"-Befehl angefügte ">nul" dient dem Unterdrücken der entbehrlichen Meldung "1 Datei(en) kopiert." und war für die unten dargestellte Ausgabe noch nicht vorhanden - daher bitte beim Testen noch weglassen.

Mit obigem Code erhalte ich eine Anzeige der Art
01.
copy "C:\source\CSV2XLS2.vbs" "C:\2007_08\" 
02.
copy "C:\source\CSV2XLS1.csv" "C:\2007_08\" 
03.
copy "C:\source\CSV2XLS1.vbs" "C:\2007_08\" 
04.
copy "C:\source\CSV2XLS.vbs" "C:\2007_08\" 
05.
copy "C:\source\CSV2XLS.csv" "C:\2007_08\"
bzw werden nach dem Entfernen des "@echo" die entsprechenden Kopiervorgänge vorgenommen.

Grüße
bastla

[Edit] Hinweis auf Verwendung von ">nul" hinzugefügt. [/Edit]
Bitte warten ..
Mitglied: pbelcl
22.11.2007 um 07:45 Uhr
Hallo bastla,

Danke für Deine tolle Unterstützung!!
Ich haben gestern abend mein batch weggeworfen und gleich Deines verwendet.
Die Variablen habe ich nun schon so eingetragen wie ich sie brauche.

Das ist das Ergebnis:
01.
rem @echo off  
02.
setlocal 
03.
 
04.
set "Quelle=set source=p:\arube\Nachrichten\Papierkorb.sys\*.*" 
05.
set "Ziel=L:\X_Mull" 
06.
 
07.
for /F "delims=. tokens=2" %%B in ("%date%") do set "MON=%%B" 
08.
If [%MON%]==[01] SET "VMN=10" 
09.
If [%MON%]==[02] SET "VMN=11" 
10.
If [%MON%]==[03] SET "VMN=12" 
11.
If [%MON%]==[04] SET "VMN=01" 
12.
If [%MON%]==[05] SET "VMN=02" 
13.
If [%MON%]==[06] SET "VMN=03" 
14.
If [%MON%]==[07] SET "VMN=04" 
15.
If [%MON%]==[08] SET "VMN=05" 
16.
If [%MON%]==[09] SET "VMN=06" 
17.
If [%MON%]==[10] SET "VMN=07" 
18.
If [%MON%]==[11] SET "VMN=08" 
19.
If [%MON%]==[12] SET "VMN=09" 
20.
 
21.
SET AJR=%DATE:~-4% 
22.
SET /A VJR=%AJR%-1 
23.
 
24.
if %MON% gtr %VMN% (set "Ordner=%Ziel%\%AJR%_%VMN%") else set "Ordner=%Ziel%\%VJR%_%VMN%" 
25.
 
26.
if not exist "%Ordner%" md "%Ordner%" 
27.
 
28.
for %%i in ("%Quelle%") do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% @echo copy "%%i" "%Ordner%\" 
Wenn ich das Echo off oben lasse und das Batch von der Commandline starte sehe ich gar nichts!?

Nachdem ich das Echo ausge"rem"t habe kommt folgende Anzeige:

C:\batch>ac
C:\batch>rem @echo off
C:\batch>setlocal
C:\batch>set "Quelle=set source=p:\arube\Nachrichten\Papierkorb.sys\*.*"
C:\batch>set "Ziel=L:\X_Mull"
C:\batch>for /F "delims=. tokens=2" %B in ("22.11.2007") do set "MON=%B"
C:\batch>set "MON=11"
C:\batch>If [11] == [01] SET "VMN=10"
C:\batch>If [11] == [02] SET "VMN=11"
C:\batch>If [11] == [03] SET "VMN=12"
C:\batch>If [11] == [04] SET "VMN=01"
C:\batch>If [11] == [05] SET "VMN=02"
C:\batch>If [11] == [06] SET "VMN=03"
C:\batch>If [11] == [07] SET "VMN=04"
C:\batch>If [11] == [08] SET "VMN=05"
C:\batch>If [11] == [09] SET "VMN=06"
C:\batch>If [11] == [10] SET "VMN=07"
C:\batch>If [11] == [11] SET "VMN=08"
C:\batch>If [11] == [12] SET "VMN=09"
C:\batch>SET AJR=2007
C:\batch>SET /A VJR=2007-1
C:\batch>if 11 GTR 08 (set "Ordner=L:\X_Mull\2007_08" ) else set "Ordner=L:\X_Mull\2006_08"
C:\batch>if not exist "L:\X_Mull\2007_08" md "L:\X_Mull\2007_08"
C:\batch>for %i in ("set source=p:\arube\Nachrichten\Papierkorb.sys\*.*") do for /F "tokens=2 delims=." %m in ('echo %~ti') do if %m == 08 copy "%i" L:\X_Mull\2007_08\"


Wie man sieht werden die Variablen richtig befüllt und ich habe schon einige mögliche "Fehler" gefunden:

Der Ordner "Papierkorb.sys" war hidden. Hat aber nichts geholfen den auf "normal" zu setzen. -> könnte der hidden bleiben?

Der Ziel-Ordner heißt bei mir "müll". Wenn ich den Umlaut verwende wird ein Ordner mit einem Sonderzeichen erstellt. Hab das zum Test mal umbenannt aber eine Anzeige mit dem schönen copy befehlen wie DU bekomme ich leider immer noch nicht.
Fehlen bei mir vielleicht irgendwelche Systemvariablen oder Routinen die bei Die vorhanden sind??
Bitte warten ..
Mitglied: bastla
22.11.2007, aktualisiert 18.10.2012
Hallo pbelcl!

Mit der von Dir verwendeten Quellenangabe
01.
set "Quelle=set source=p:\arube\Nachrichten\Papierkorb.sys\*.*"
kann das natürlich nicht klappen - versuch es mit
01.
set "Quelle=p:\arube\Nachrichten\Papierkorb.sys\*.*"
Ob aus dem Ordner "Papierkorb.sys" Dateien per Batch ausgelesen werden können, kannst Du mit einem einfachen
01.
dir p:\arube\Nachrichten\Papierkorb.sys\*.*
direkt an der Kommandozeile überprüfen - sollte auch gehen, wenn dieser Ordner tatsächlich "hidden" ist (und bleiben soll). Auf jeden Fall müsste aber ein
01.
dir /aa p:\arube\Nachrichten\Papierkorb.sys\*.*
dessen Inhalte zutage fördern.
Umlaute und Batch sind so eine Sache für sich - falls meine Standardempfehlung "Vermeiden!" für Dich nicht in Frage kommt, gäbe es immer noch die Möglichkeit, den Batch mit dem CMD-Editor zu bearbeiten - hatten wir kürzlich hier.

Grüße
bastla
Bitte warten ..
Mitglied: pbelcl
22.11.2007 um 18:09 Uhr
Hallo bastla,

Das mit dem falschen SET Befehlt ist fast schon peinlich!!
Habe ich voll übersehen, danke!!

Nach der Korrektur des Fehlers habe ich aml den DIR Befehl probiert. Klappt auch wenn das Verzeichnis Hidden ist, somit sollte es da kein Problem geben.

Nun funktioniert das Ding!!

Nun kommt gleich eine weitere Idee

Kann man das vollautomatisch auch machen?
Aufgrund des Filedatums die entsprechenden Dateien in den richtigen Monatsordner kopieren?

Dann würde das Batch IMMER wenn es läuft ALLE Dateien vom Monat 11 in den 2007_11 ALLE Dateien vom Monat 01 in den 2007_01 Ordner befördern.

Geht das überhauft?
Wenn ja würde man sich die ganze Variablen Schieberei ersparen ...
Bitte warten ..
Mitglied: bastla
22.11.2007 um 18:59 Uhr
Hallo pbelcl!

Machbar wäre das etwa so:
01.
@echo off & setlocal 
02.
 
03.
set "Quelle=p:\arube\Nachrichten\Papierkorb.sys\*.*" 
04.
set "Ziel=L:\X_Muell" 
05.
set "Log=L:\CopyLog.txt" 
06.
 
07.
if exist "%Log%" del "%Log%" 
08.
for %%i in ("%Quelle%") do for /f "tokens=2,3 delims=. " %%a in ('echo %%~ti') do ( 
09.
	if not exist "%Ziel%\%%b_%%a" md "%Ziel%\%%b_%%a" 
10.
	xcopy /d /h /r /c /y "%%i" "%Ziel%\%%b_%%a\">>"%Log%" 2>&1 
11.
)
In diesem Fall würde ich den "xcopy"-Befehl wegen seines Schalters "/d" bevorzugen - damit werden nur neuere Dateien kopiert, was aufgrund der Tatsache, dass jetzt ja immer alle Dateien des Quellverzeichnisses berücksichtigt werden, IMHO geboten scheint.

Der Kopiervorgang wird in einer (jedesmal neu erstellten) Protokolldatei "L:\CopyLog.txt" dokumentiert. Beim Kopieren eventuell auftretende Fehler werden ebenfalls in diese Logdatei geschrieben.

Grüße
bastla

P.S.: Mehr zu "xcopy" erfährst Du mit "xcopy /?" ...

[Edit] Um Fehler beim Kopieren in ihrem Kontext darzustellen, erfolgt jetzt die Protokollierung so, dass sämtliche Ausgaben in "L:\CopyLog.txt" geschrieben werden. [/Edit]
Bitte warten ..
Mitglied: pbelcl
01.12.2007 um 17:16 Uhr
Hallo Bastla,

Die Variante die ALLES kopiert funktioniert nun!
Somit habe ich jetzt mal die Basisdateien der letzten Jahre kopiert, hat mir viel Arbeit gespart!
Nochmal danke für Deine Hilfe!

Ich werde die batch nun noch ändern daß sie nicht kopiert sondern moved und dann in mein Monatsbackup einbauen.
Schon cool was alles möglich ist
Bitte warten ..
Mitglied: pbelcl
01.12.2007 um 18:09 Uhr
Hallo bastla,

Hab jetzt mal den copy befehl in einen move Befehl ersetzt
Ich bin leider ein verdammter Perfektionist und daher würde ich noch gerne zwei Dinge wissen:

1.) Egal ob ich es mit dem Parameter /Y

01.
rem for %%i in ("%Quelle%") do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% move /Y "%%i" "%Ordner%\" >>%~n0.log
oder ohne

01.
for %%i in ("%Quelle%") do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% move "%%i" "%Ordner%\">>%~n0.log
mache die Dateien werden immer wortlos überschrieben. Ich will das zwar so haben, doch würde mich interessieren wozu der Parameter da ist wenn er keine Wirkung hat

2.) habe ich am Ende meines MOVE Befehles eine Umleitung ins LOG File drinnen.
Hatte erwartet daß dort alle kopierten Files stehen. Leider wird da aber nix reingeschrieben.

Passiert das nur wenn ein Fehler auftritt?
Oder habe ich das mit der Umleitung ">>" falsch verstanden?

Wie bekomme ich eine Liste der verschobenen Dateien in mein Log ?
Hast Du einen Tip?

lg
Pauli
Bitte warten ..
Mitglied: bastla
01.12.2007 um 20:15 Uhr
Hallo pbelcl!

ad 1.)
Auch ich hatte den letzten Satz der Online-Hilfe zu "move" lange Zeit überlesen ...

Was übrigens auch in Batch beachtet wird, ist "/-Y" - dann wird auf jeden Fall die Bestätigung für das Überschreiben verlangt (was aber natürlich nur bei interaktivem Start des Batches sinnvoll sein kann). Im Fall des Falles kannst Du aber ein "if not exist Zieldatei move ..." verwenden, damit auch aus einem Batch heraus nicht überschrieben wird.

ad 2.)
Für die Anzeige/das Loggen der verschobenen Dateien musst Du selbst sorgen, etwa so:
01.
for %%i in ("%Quelle%") do for /f "tokens=2 delims=." %%m in ('echo %%~ti') do if %%m==%VMN% move "%%i" "%Ordner%\" && echo Verschoben: %%i >>%~n0.log
Durch die Verknüpfung mit "&&" wird der Logeintrag nur erstellt, wenn der "move"-Befehl ohne Fehler beendet wurde.

Passiert das nur wenn ein Fehler auftritt?
Oder habe ich das mit der Umleitung ">>" falsch verstanden?
Die Umleitung mit ">>" wäre schon OK, wenn, so wie beim "xcopy", der "move"-Befehl eine Ausgabe erzeugte. (BTW: Der "copy"-Befehl liefert zwar eine Ausgabe, aber da diese nur zB "1 Datei(en) kopiert" lautet, leite ich sie grundsätzlich nach "nul" um).

Um übrigens Fehlermeldungen umzuleiten, müsstest Du "2>>Umleitungsziel" verwenden, da diese Meldungen auf dem Kanal 2 (STDERROR) ausgegeben werden.

Sollen Fehlermeldungen und "normale" Meldungen aus Kanal 1 (STDOUT) in die selbe Datei geschrieben werden, wäre die Schreibweise ">>Umleitungsziel 2>>&1" zu verwenden, da bei einem ">>Umleitungsziel 2>>Umleitungsziel" die Zieldatei während der Ausführung des Befehles zweimal zum Schreiben geöffnet werden müsste, was nicht zulässig ist.

Grüße
bastla
Bitte warten ..
Mitglied: pbelcl
02.12.2007 um 11:41 Uhr
ad 1.)
Auch ich hatte den letzten Satz der Online-Hilfe zu "move" lange Zeit
überlesen ...
Tja, das habe ich wirklich überlesen da es erst vollständig angezeigt wird wenn man einmal ENTER drückt. Meißt habe ich das Fenster vorher schon geschlossen.
Damit ist alles klar, danke!

ad 2.)
Für die Anzeige/das Loggen der verschobenen Dateien musst Du selbst sorgen,

Das habe ich mir eh gedacht, wollte nur sicher gehen.
Werde die von Dir vorgeschlagene Zeile noch einbauen, dann ist das auch OK.
Danke auch hierfür, du bist wirklich Spitze!!
Bitte warten ..
Ähnliche Inhalte
Windows Netzwerk

Dateien älter als X Jahre archivieren

Frage von ahussainWindows Netzwerk2 Kommentare

Hallo, mit robocopy kann man ja recht simpel Dateien, die älter als X Tage sind, automatisch in ein Archiv ...

Batch & Shell

Dateien nach Datum verschieben

Frage von LKDNDK12Batch & Shell4 Kommentare

Hallo Community, ich habe folgendes Problem: ich muss Dateien mit dem Kriterium Speicherdatum verschieben. Die Ordnerstruktur: H:\Zaehlerdaten\Auslesung1\32.21.54\log\year\ (danach noch ...

Batch & Shell

Datei mit Datum im Namen erstellen

gelöst Frage von pbelclBatch & Shell6 Kommentare

Ich habe mir ein kleines Batch geschrieben, das mir eine Date erstellt, die im Namen das Datum und die ...

JavaScript

Zeit und Datum in Datei schreiben

Frage von MarcysJavaScript2 Kommentare

Hallo, mit Node-Red habe ich den Temperatursensor DHT22 ans Laufen bekommen. Ich habe zwei Node-Funktionen erstellt, die mir die ...

Neue Wissensbeiträge
SAN, NAS, DAS
QNAP NAS Datenschutz-Loop nach Firmware-Update
Tipp von vanTast vor 18 StundenSAN, NAS, DAS2 Kommentare

Moin, im allgemeinen Trend seine geänderten Datenschutzbedingungen den Kunden zukommen zu lassen kam die Firma QNAP auf die glorreiche ...

Datenschutz
DSGVO Datenschutzgesetz
Anleitung von 1Werner1 vor 20 StundenDatenschutz4 Kommentare

Moin, ja was ist das, da ist die DSGVO Datenschutzverordnung. Wie das Gesetz gibt es schon 2 Jahre? Nun ...

CPU, RAM, Mainboards

Neverending Story: Google und Microsoft melden neue Chip-Sicherheitslücke

Information von keine-ahnung vor 1 TagCPU, RAM, Mainboards1 Kommentar

Da kommt man mit dem fixen gar nicht mehr hinterher und die CPU erreichen wieder Rechenleistungen im Bereich des ...

Multimedia & Zubehör
AVM Fritz USB WLAN Sticks schneller einschalten
Tipp von NetzwerkDude vor 3 TagenMultimedia & Zubehör4 Kommentare

Die AVM Fritz WLAN Sticks haben in der Firmware 2 Modis: Einmal als Massenspeicher und einmal als WLAN Netzwerkkarte ...

Heiß diskutierte Inhalte
LAN, WAN, Wireless
Powerline über zwei Stockwerke optimieren
gelöst Frage von DultusLAN, WAN, Wireless42 Kommentare

Guten Morgen liebes Forum, ich hätte einmal eine Frage bezüglich Powerline Adapter: Mein Problem ist seit gestern präsent, da ...

PHP
Nach Umzug zu 1und1 bekomme ich beim Eintrag in die DB Tabelle folgenden Fehler
gelöst Frage von jensgebkenPHP35 Kommentare

INSERT command denied to user 'dbo45342345342231244'@'112.127.102.073' for table 'orders'

Windows Userverwaltung
Problem mit Benutzerprofil
Frage von lieferscheinWindows Userverwaltung24 Kommentare

Guten Tag liebe Community, folgendes Problem habe ich: User meldet sich auf Client A an - sein Homelaufwerk verbindet. ...

Off Topic
DISKUSSION: Was bringt der Disclaimer "Wenn Sie nicht der Empfänger sind."
Frage von N8DragonOff Topic21 Kommentare

So oder ähnlich, lese ich immer wieder Kleingedrucktes am Ende diverser Mails. Letzten Endes wollen sie mir alle sagen, ...