Dateien aus einem Quellverzeichnis in Backupverzeichnis kopieren und in zehn Zielverzeichnisse verschieben

@echo off & setlocal

::********** Config-Variablen **********
set "SrcDir=E:\Test\Quelle"  
set "BackupDir=E:\Test\Backup"  

set "NDestDirs=10"  
set "DestDir1=E:\Test\Verz1"  
set "DestDir2=E:\Test\Verz2"  
set "DestDir3=E:\Test\Verz3"  
set "DestDir4=E:\Test\Verz4"  
set "DestDir5=E:\Test\Verz5"  
set "DestDir6=E:\Test\Verz6"  
set "DestDir7=E:\Test\Verz7"  
set "DestDir8=E:\Test\Verz8"  
set "DestDir9=E:\Test\Verz9"  
set "DestDir10=E:\Test\Verz10"  
::**************************************

::Aus einer INI-Datei, die den gleichen Namen wie das Script hat,
::wird die Nummer des letzten Verzeichnisses ausgelesen, in das
::beim letzten Scriptlauf eine Datei kopiert wurde.
::In der INI-Datei können Einträge für verschiedene Quellverzeichnisse
::stehen. Ein Eintrag ist nach dem Muster
::      PfadZumQuellverzeichnis=Nummer
::aufgebaut.
set /a Offset=0

if exist "%~dpn0.ini" (  
  for /f "usebackq tokens=1* delims==" %%a in ("%~dpn0.ini") do (  
    if "%%a" equ "%SrcDir%" (  
      set /a Offset=%%b
    )
  )
)

::Aus der eingelesenen Nummer mit der Modulo-Funktion den Offset für
::den aktuellen Scriptlauf berechnen.
set /a Offset=Offset%%NDestDirs

::Dateien im Quellverzeichnis verarbeiten
for /f "tokens=1* delims=:" %%a in ('dir /b /a:-d-h-s /o:ne "%SrcDir%" 2^>NUL ^| findstr /n "^"') do (  
  call :ProcessFile %%a "%%b"  
)

::Die alte INI-Datei zeilenweise auslesen und dabei nach der Zeile
::suchen, die zum aktuellen Quellverzeichnis gehört. Diese Zeile
::wird mit aktualisiertem Wert in eine temporäre INI-Datei geschrieben.
::Alle anderen Zeilen werden unverändert in diese Datei geschrieben.
::Falls die INI-Datei noch nicht existiert, wird eine temporäre
::INI-Datei angelegt, die nur den Eintrag für das aktuelle Quell-
::verzeichnis enthält.
if exist "%~dpn0.ini" (  
  for /f "usebackq tokens=1* delims==" %%a in ("%~dpn0.ini") do (  
    if "%%a" neq "%SrcDir%" (  
      >>"%~dpn0_new.ini" echo %%a=%%b  
    ) else (
      >>"%~dpn0_new.ini" echo %%a=%i%  
    )
  )
) else (
  > "%~dpn0_new.ini" <NUL set /p "=%SrcDir%=%i%"  
  >>"%~dpn0_new.ini" echo.  
)

::Die temporäre INI-Datei umbenennen und dabei die ggf. schon existierende
::alte INI-Datei ohne Nachfrage überschreiben.
move /y "%~dpn0_new.ini" "%~dpn0.ini" > NUL  

::Script Ende
exit /b


::Unterprogramm
:ProcessFile
  set /a i=(%1-1+Offset)%%NDestDirs+1
  echo copy "%SrcDir%\%~2" "%BackupDir%"  
  call echo move "%SrcDir%\%~2" "%%DestDir%i%%%"  
exit /b